AIR.SWF tarayıcı içi API'si

Kesintisiz yükleme badge.swf dosyası özelleştirme

SDK'yle beraber sağlanan badge.swf dosyasını kullanmaya ek olarak, bir tarayıcı sayfasında kullanmak için kendi SWF dosyanızı oluşturabilirsiniz. Özel SWF dosyanız çalışma zamanıyla şu şekillerde etkileşimde bulunabilir:

Bu özelliklerin tümü, adobe.com adresinde bulunan bir SWF dosyasındaki API'ler çağrılarak sağlanır: air.swf. badge.swf dosyasını özelleştirebilir ve kendi SWF dosyanızdan air.swf API'lerini çağırabilirsiniz.

Buna ek olarak tarayıcıda çalışan bir SWF dosyası, LocalConnection sınıfını kullanarak, çalışan bir AIR uygulamasıyla iletişim kurabilir. Daha fazla bilgi için bkz. Diğer Flash Player ve AIR örnekleri ile iletişim (ActionScript geliştiricileri için) veya Diğer Flash Player ve AIR örnekleri ile iletişim (HTML geliştiricileri için).

Önemli: Bu bölümde açıklanan özellikler (ve air.swf dosyasındaki API'ler), son kullanıcının Windows veya Mac OS'deki web tarayıcısında Adobe® Flash® Player 9 güncellemesi 3 veya daha üstünün yüklemiş olmasını gerektirir. Kesintisiz yükleme özelliği Linux'ta Flash Player 10'u (10,0,12,36 veya daha yeni bir sürüm) gerektirir. Flash Player'ın yüklü sürümünü kontrol etmek için kod yazabilir ve Flash Player'ın gerekli sürümü yüklü değilse, kullanıcıya alternatif bir arabirim sağlayabilirsiniz. Örneğin Flash Player'ın daha eski bir sürümü yüklüyse, AIR dosyasının yükleme sürümüne bir bağlantı verebilirsiniz (bir uygulama yüklemek için badge.swf dosyasını veya air.swf API'sini kullanmak yerine).

AIR uygulamasını yüklemek için badge.swf dosyasını kullanma

AIR SDK ve Flex SDK'de bir badge.swf dosyası mevcuttur, bu dosya sayesinde kesintisiz yükleme özelliğini kolaylıkla kullanabilirsiniz. badge.swf dosyası, çalışma zamanını ve AIR uygulamasını web sayfasındaki bir bağdan yükleyebilir. badge.swf dosyası ve kaynak kodu, web sitenizde yayınlamanız için size sağlanır.

badge.swf dosyasını bir web sayfasına gömme

  1. AIR SDK ve Flex SDK'nin samples/badge dizininde sağlanan aşağıdaki dosyaları bulun veya web sunucunuza ekleyin.

    • badge.swf

    • default_badge.html

    • AC_RunActiveContent.js

  2. default_badge.html sayfasını metin düzenleyicisinde açın.

  3. default_badge.html sayfasında, AC_FL_RunContent() JavaScript işlevinde, aşağıdaki öğeler için FlashVars parametre tanımlarını ayarlayın:

    Parametre

    Açıklama

    appname

    Çalışma zamanı yüklü olmadığında SWF dosyası tarafından görüntülenen uygulama adı.

    appurl

    (Zorunlu). Yüklenecek AIR dosyasının URL'si. Göreceli değil, mutlak bir URL kullanmalısınız.

    airversion

    (Zorunlu). Çalışma zamanının 1.0 sürümü için bunu 1.0'a ayarlayın.

    imageurl

    Kimlik kartında görüntülenecek görüntünün (isteğe bağlı) URL'si.

    buttoncolor

    Yükleme düğmesinin rengi. ( FFCC00 gibi, onaltılık bir değer olarak belirtilir.)

    messagecolor

    Çalışma zamanı yüklü olmadığında düğmenin altında görüntülenen metin mesajının rengi. ( FFCC00 gibi, onaltılık bir değer olarak belirtilir.)

  4. badge.swf dosyasının minimum boyutu 217 piksel genişlik, 180 piksel yüksekliktir. AC_FL_RunContent() işlevinin width ve height parametrelerinin değerlerini ihtiyaçlarınızı karşılayacak şekilde ayarlayın.

  5. İhtiyaçlarınızı karşılayacak şekilde default_badge.html dosyasını yeniden adlandırın ve kodunu ayarlayın (veya başka bir HTML sayfasına dahil edin).

Not: badge.swf dosyasını yükleyen HTML embed etiketi için, wmode niteliğini ayarlamayın; onu "Window" varsayılanına ayarlı bırakın. Diğer wmode ayarları bazı sistemlerde yüklemeyi engeller. Ayrıca, diğer wmode ayarları bir hata oluşturur: “Hata #2044: İşlenmemiş ErrorEvent:. text=Hata #2074: Sahne alanı, indirme arabirimine sığamayacak kadar küçük.”

Ayrıca badge.swf dosyasını düzenleyebilir ve yeniden derleyebilirsiniz. Ayrıntılar için bkz. badge.swf dosyasını değiştirme .

AIR uygulamasını bir web sayfasındaki kesintisiz yükleme bağlantısından yükleyin

Kesintisiz yükleme bağını bir sayfaya ekledikten sonra kullanıcı, SWF dosyasındaki bağı tıklatarak AIR uygulamasını yükleyebilir.

  1. Flash Player'ın (Windows veya Mac OS X'te sürüm 9 güncelleme 3 veya daha yenisinin veya Linux'ta sürüm 10'un) yüklenmiş olduğu bir web tarayıcısında HTML sayfasına gidin.

  2. Web sayfasında, badge.swf dosyasındaki bağı tıklatın.

    • Çalışma zamanını yüklediyseniz, bir sonraki adıma geçin.

    • Çalışma zamanını yüklemediyseniz, yüklemek isteyip istemediğinizi soran bir iletişim kutusu görüntülenir. Çalışma zamanını yükleyin (bkz. Adobe AIR yüklemesi ) ve bir sonraki adımla devam edin.

  3. Yükleme penceresinde, varsayılan ayarları seçili halde bırakın ve ardından Devam düğmesini tıklatın.

    Windows kullanan bir bilgisayarda AIR otomatik olarak şunları gerçekleştirir:

    • Uygulamayı c:\Program Files\ konumuna yükler

    • Uygulama için bir masaüstü kısayolu oluşturur

    • Başlat Menüsü kısayolu oluşturur.

    • Program Ekle / Kaldır Denetim Masası'na uygulama için bir giriş ekler

    Mac OS'de yükleyici uygulamayı Uygulamalar dizinine ekler (örneğin Mac OS'de /Applications dizininde).

    Linux ile çalışan bir bilgisayarda AIR otomatik olarak şunu yapar:

    • Uygulamayı /opt hedefine yükler.

    • Uygulama için bir masaüstü kısayolu oluşturur

    • Başlat Menüsü kısayolu oluşturur.

    • Sistem paket yöneticisindeki uygulama için bir giriş ekler

  4. İstediğiniz seçenekleri belirleyin, ardından Yükle düğmesini tıklatın.

  5. Yükleme işlemi tamamlandığında, Son düğmesini tıklatın.

badge.swf dosyasını değiştirme

Flex SDK ve AIR SDK badge.swf dosyası için kaynak dosyaları sağlar. Bu dosyalar SDK'nin samples/badge klasöründe bulunur:

Kaynak dosyalar

Açıklama

badge.fla

badge.swf dosyasını derlemek için kullanılan kaynak Flash dosyası. badge.fla dosyası bir SWF 9 dosyasına (Flash Player'da yüklenebilir) derlenir.

AIRBadge.as

basdge.fla dosyasında kullanılan temel sınıfı tanımlayan bir ActionScript 3.0 sınıfı.

Flash Professional uygulamasını badge.fla dosyasının görsel arabirimini yeniden tasarlamak için kullanabilirsiniz.

AIRBadge sınıfında tanımlanan AIRBadge() yapıcı işlevi, http://airdownload.adobe.com/air/browserapi/air.swf adresinde barındırılan air.swf dosyasını yükler. air.swf dosyası, kesintisiz yükleme özelliğini kullanma için kod içerir.

air.swf dosyası başarıyla yüklendiğinde, onInit() yöntemi (AIRBadge sınıfında) çağrılır:

private function onInit(e:Event):void { 
    _air = e.target.content; 
    switch (_air.getStatus()) { 
        case "installed" : 
            root.statusMessage.text = ""; 
            break; 
        case "available" : 
            if (_appName && _appName.length > 0) { 
                root.statusMessage.htmlText = "<p align='center'><font color='#"  
                        + _messageColor + "'>In order to run " + _appName +  
                        ", this installer will also set up Adobe® AIR®.</font></p>"; 
            } else { 
                root.statusMessage.htmlText = "<p align='center'><font color='#"  
                        + _messageColor + "'>In order to run this application, " 
                        + "this installer will also set up Adobe® AIR®.</font></p>"; 
            } 
            break; 
        case "unavailable" : 
            root.statusMessage.htmlText = "<p align='center'><font color='#"  
                        + _messageColor  
                        + "'>Adobe® AIR® is not available for your system.</font></p>"; 
            root.buttonBg_mc.enabled = false; 
            break; 
    } 
}

Kod, global _air değişkenini yüklenen air.swf dosyasının ana sınıfına ayarlar. Bu sınıf, badge.swf dosyasının kesintisiz yükleme işlevini çağırmak için eriştiği aşağıdaki genel yöntemleri içerir:

Yöntem

Açıklama

getStatus()

Çalışma zamanının bilgisayara yüklenip yüklenmediğini (veya yüklenip yüklenemeyebileceğini) belirler. Ayrıntılar için bkz. Çalışma zamanının yüklenip yüklenmediğini kontrol etme .
  • runtimeVersion —Yüklenecek uygulamanın gerektirdiği çalışma zamanını ( "1.0.M6" gibi) belirten bir dize.

installApplication()

Kullanıcının bilgisayarında belirtilen uygulamayı yükler. Ayrıntılar için bkz. Tarayıcıdan AIR uygulaması yükleme .

  • url —URL'yi tanımlayan bir dize. Göreceli değil, mutlak bir URL yolu kullanmalısınız.

  • runtimeVersion —Yüklenecek uygulamanın gerektirdiği çalışma zamanını ( "2.5" gibi) belirten bir dize.

  • arguments — Yüklemenin ardından başlatılırsa uygulamaya iletilecek olan argümanlar. Uygulama tanımlayıcı dosyasında allowBrowserInvocation öğesi true olarak ayarlanmışsa, yüklemenin ardından uygulama başlatılır. (Uygulama tanımlayıcı dosyası hakkında daha fazla bilgi için bkz. AIR uygulama tanımlayıcı dosyaları ). Uygulama, tarayıcıdan kesintisiz yüklemenin bir sonucu olarak başlatılırsa (kullanıcının yüklemeden sonra başlatmayı seçmesiyle), yalnızca argümanlar iletilirse uygulamanın NativeApplication nesnesi bir BrowserInvokeEvent nesnesi gönderir. Uygulamaya ilettiğiniz verilerin güvenlik sonuçlarını göz önünde bulundurun. Ayrıntılar için bkz. Yüklenmiş bir AIR uygulamasını tarayıcıdan başlatma .

url ve runtimeVersion için ayarlar, kap HTML sayfasındaki FlashVars ayarları kullanılarak SWF dosyasına iletilir.

Uygulama, yüklemeden sonra otomatik olarak başlarsa, yüklenen uygulamanın başlatmadan sonra badge.swf dosyasına başvurması için LocalConnection iletişimini kullanabilirsiniz. Daha fazla bilgi için bkz. Diğer Flash Player ve AIR örnekleri ile iletişim (ActionScript geliştiricileri için) veya Diğer Flash Player ve AIR örnekleri ile iletişim (HTML geliştiricileri için).

Ayrıca, bir uygulamanın yüklenip yüklenmediğini kontrol etmek için air.swf dosyasının getApplicationVersion() yöntemini de çağırabilirsiniz. Bu yöntemi uygulama yükleme işleminden önce veya yükleme başladıktan sonra çağırabilirsiniz. Ayrıntılar için bkz. AIR uygulamasının yüklenip yüklenmediğini bir web sayfasından kontrol etme .

air.swf dosyasını yükleme

Bir tarayıcıdaki web sayfasından çalışma zamanı ve AIR uygulamalarıyla etkileşimde bulunmak için air.swf dosyasındaki API'leri kullanan kendi SWF dosyanızı oluşturabilirsiniz. air.swf dosyası http://airdownload.adobe.com/air/browserapi/air.swf adresinde bulunmaktadır. air.swf API'lerine SWF dosyanızdan başvurmak için, air.swf dosyasını SWF dosyanızla aynı uygulama etki alanına yükleyin. Aşağıdaki kod, yükleme SWF dosyasının uygulama etki alanına air.swf dosyasını yüklemeye dair bir örnek gösterir:

var airSWF:Object; // This is the reference to the main class of air.swf 
var airSWFLoader:Loader = new Loader(); // Used to load the SWF 
var loaderContext:LoaderContext = new LoaderContext();  
                                // Used to set the application domain  
 
loaderContext.applicationDomain = ApplicationDomain.currentDomain; 
 
airSWFLoader.contentLoaderInfo.addEventListener(Event.INIT, onInit); 
airSWFLoader.load(new URLRequest("http://airdownload.adobe.com/air/browserapi/air.swf"),  
                    loaderContext); 
 
function onInit(e:Event):void  
{ 
    airSWF = e.target.content; 
}

air.swf dosyası yüklendikten sonra (Loader nesnesinin contentLoaderInfo nesnesi init olayını gönderdiğinde), aşağıdaki bölümlerde anlatılan biçimde air.swf API'lerinden herhangi birini çağırabilirsiniz.

Not: AIR SDK ve Flex SDK'yle sağlanan badge.swf dosyası, air.swf dosyasını otomatik olarak yükler. Bkz. AIR uygulamasını yüklemek için badge.swf dosyasını kullanma . Bu bölümdeki talimatlar, air.swf dosyasını yükleyen kendi SWF dosyanızı oluşturmaya yöneliktir.

Çalışma zamanının yüklenip yüklenmediğini kontrol etme

SWF dosyası, http://airdownload.adobe.com/air/browserapi/air.swf adresinden yüklenen air.swf dosyasındaki getStatus( ) yöntemini çağırarak, çalışma zamanının yüklenip yüklenmediğini kontrol edebilir. Ayrıntılar için bkz. air.swf dosyasını yükleme .

air.swf dosyası yüklendikten sonra, SWF dosyası, aşağıda olduğu gibi air.swf dosyasının getStatus( ) yöntemini çağırabilir:

var status:String = airSWF.getStatus();

getStatus() yöntemi, bilgisayardaki çalışma zamanının durumuna bağlı olarak aşağıdaki dize değerlerinden birini döndürür:

Dize değeri

Açıklama

"available"

Bu bilgisayara çalışma zamanı yüklenebilir, ancak şu anda yüklü değil.

"unavailable"

Bu bilgisayara çalışma zamanı yüklenemez.

"installed"

Bu bilgisayarda çalışma zamanı yüklü.

Gerekli Flash Player sürümü (Windows ve Mac OS'de sürüm 9 güncelleme 3 veya Linux'ta sürüm 10) tarayıcıya yüklenmediğinde getStatus() yöntemi bir hata atar.

AIR uygulamasının yüklenip yüklenmediğini bir web sayfasından kontrol etme

SWF dosyası, http://airdownload.adobe.com/air/browserapi/air.swf adresinden yüklenen air.swf dosyasındaki getApplicationVersion( ) yöntemini çağırarak AIR uygulamasının (eşleşen bir uygulama kimliği ve yayıncı kimliğiyle) yüklenip yüklenmediğini kontrol edebilir. Ayrıntılar için bkz. air.swf dosyasını yükleme .

air.swf dosyası yüklendikten sonra, SWF dosyası, aşağıda olduğu gibi air.swf dosyasının getApplicationVersion( ) yöntemini çağırır:

var appID:String = "com.example.air.myTestApplication"; 
var pubID:String = "02D88EEED35F84C264A183921344EEA353A629FD.1"; 
airSWF.getApplicationVersion(appID, pubID, versionDetectCallback); 
 
function versionDetectCallback(version:String):void 
{ 
    if (version == null) 
    { 
        trace("Not installed."); 
        // Take appropriate actions. For instance, present the user with 
        // an option to install the application. 
    } 
    else 
    { 
        trace("Version", version, "installed."); 
        // Take appropriate actions. For instance, enable the 
        // user interface to launch the application. 
    } 
}

getApplicationVersion() yöntemi aşağıdaki parametreleri içerir:

Parametreler

Açıklama

appID

Uygulama için uygulama kimliği. Ayrıntılar için bkz. id .

pubID

Uygulama için yayıncı kimliği. Ayrıntılar için bkz. publisherID . Söz konusu uygulama bir yayıncı kimliğine sahip değilse, pubID parametresini boş bir dizeye (“”) ayarlayın.

callback

İşleyici işlevi olarak hizmet görecek bir geri çağırma işlevi. getApplicationVersion() yöntemi senkronize çalışmaz ve yüklü sürümü (veya yüklü sürüm olmadığını) saptadıktan sonra, bu geri çağırma yöntemi çağrılır. Geri çağırma yöntemi tanımı bir parametre, yüklenmiş uygulamanın sürüm dizesine ayarlı bir dize içermelidir. Uygulama yüklenmemişse, önceki kod örneğinde gösterildiği gibi işleve bir null değeri iletilir.

Gerekli Flash Player sürümü (Windows ve Mac OS'de sürüm 9 güncelleme 3 veya daha yenisi veya Linux'ta sürüm 10) tarayıcıda yüklü değilse getApplicationVersion() yöntemi hata verir.

Not: AIR 1.5.3'teki gibi, yayıncı kimliği uygun bulunmaz. Yayıncı kimlikleri artık otomatik olarak bir uygulamaya atanmamaktadır. Geriye doğru uyumluluk için, uygulamalar bir yayıncı kimliği belirlemeye devam edebilir.

Tarayıcıdan AIR uygulaması yükleme

SWF dosyası, http://airdownload.adobe.com/air/browserapi/air.swf adresinden yüklenen air.swf dosyasındaki installApplication( ) yöntemini çağırarak bir AIR uygulaması yükleyebilir. Ayrıntılar için bkz. air.swf dosyasını yükleme .

air.swf dosyası yüklendikten sonra, SWF dosyası, aşağıdaki kodda olduğu gibi air.swf dosyasının installApplication( ) yöntemini çağırabilir:

var url:String = "http://www.example.com/myApplication.air"; 
var runtimeVersion:String = "1.0"; 
var arguments:Array = ["launchFromBrowser"]; // Optional 
airSWF.installApplication(url, runtimeVersion, arguments); 

installApplication() yöntemi, kullanıcının bilgisayarında belirtilen uygulamayı yükler. Bu yöntem aşağıdaki parametrelere sahiptir:

Parametre

Açıklama

url

Yüklenecek AIR dosyasının URL'sini tanımlayan dize. Göreceli değil, mutlak bir URL yolu kullanmalısınız.

runtimeVersion

Uygulama tarafından yüklenmesi gerekli kılınan çalışma zamanının sürümünü ("1.0" gibi) gösteren bir dize.

arguments

Yüklemenin ardından başlatılırsa uygulamaya iletilecek olan argüman dizisi. Argümanlarda yalnızca alfasayısal karakterler tanınır. Diğer değerleri aktarmanız gerektiğinde bir kodlama şeması kullanmayı deneyin.

Uygulama tanımlayıcı dosyasında allowBrowserInvocation öğesi true olarak ayarlanmışsa, yüklemenin ardından uygulama başlatılır. (Uygulama tanımlayıcı dosyası hakkında daha fazla bilgi için bkz. AIR uygulama tanımlayıcı dosyaları ). Uygulama, tarayıcıdan kesintisiz yüklemenin bir sonucu olarak başlatılırsa (kullanıcının yüklemeden sonra başlatmayı seçmesiyle), yalnızca argümanlar iletilmişse uygulamanın NativeApplication nesnesi bir BrowserInvokeEvent nesnesi gönderir. Ayrıntılar için bkz. Yüklenmiş bir AIR uygulamasını tarayıcıdan başlatma .

installApplication() yöntemi yalnızca, fare tıklatması gibi bir kullanıcı olayına yönelik olay işleyicisinde çağrıldığında çalışabilir.

Gerekli Flash Player sürümü (Windows ve Mac OS'de sürüm 9 güncelleme 3 veya daha yenisi veya Linux'ta sürüm 10) tarayıcıda yüklü değilse installApplication() yöntemi hata verir.

Mac OS'de bir uygulamanın güncellenen sürümünü yüklemek için, kullanıcının uygulama dizinine yüklemek üzere yeterli sistem ayrıcalığına (ve uygulama çalışma zamanını güncelliyorsa yönetici ayrıcalıklarına) sahip olması gerekir. Windows'ta kullanıcı yönetici ayrıcalıklarına sahip olmalıdır.

Ayrıca, bir uygulamanın önceden yüklenip yüklenmediğini kontrol etmek için air.swf dosyasının getApplicationVersion() yöntemini de çağırabilirsiniz. Bu yöntemi uygulama yükleme işlemi başlamadan önce veya yükleme başladıktan sonra çağırabilirsiniz. Ayrıntılar için bkz. AIR uygulamasının yüklenip yüklenmediğini bir web sayfasından kontrol etme . Uygulama çalıştıktan sonra, LocalConnection sınıfını kullanarak tarayıcıdaki SWF içeriğiyle iletişim kurabilir. Daha fazla bilgi için bkz. Diğer Flash Player ve AIR örnekleri ile iletişim (ActionScript geliştiricileri için) veya Diğer Flash Player ve AIR örnekleri ile iletişim (HTML geliştiricileri için).

Yüklenmiş bir AIR uygulamasını tarayıcıdan başlatma

Tarayıcı başlatma özelliğini kullanmak için (tarayıcıdan başlatılmasına izin vererek), hedef uygulamanın uygulama tanımlayıcı dosyası aşağıdaki ayarı içermelidir:

<allowBrowserInvocation>true</allowBrowserInvocation>

Uygulama tanımlayıcı dosyası hakkında daha fazla bilgi için bkz. AIR uygulama tanımlayıcı dosyaları .

Tarayıcıdaki bir SWF dosyası, http://airdownload.adobe.com/air/browserapi/air.swf adresinden yüklenen air.swf dosyasındaki launchApplication( ) yöntemini çağırarak bir AIR uygulamasını başlatabilir. Ayrıntılar için bkz. air.swf dosyasını yükleme .

air.swf dosyası yüklendikten sonra, SWF dosyası, aşağıdaki kodda olduğu gibi air.swf dosyasının launchApplication( ) yöntemini çağırabilir:

var appID:String = "com.example.air.myTestApplication"; 
var pubID:String = "02D88EEED35F84C264A183921344EEA353A629FD.1"; 
var arguments:Array = ["launchFromBrowser"]; // Optional 
airSWF.launchApplication(appID, pubID, arguments);

launchApplication() yöntemi air.swf dosyasının (kullanıcı arabirimi SWF dosyasının uygulama etki alanında yüklüdür) üst düzeyinde tanımlanır. Bu yöntemi çağırmak AIR'in belirtilen uygulamayı başlatmasına neden olur (yüklüyse ve tarayıcı başlatması olanağı varsa, uygulama tanımlayıcı dosyasındaki allowBrowserInvocation ayarını kullanarak). Bu yöntem aşağıdaki parametrelere sahiptir:

Parametre

Açıklama

appID

Başlatılacak uygulamanın uygulama kimliği. Ayrıntılar için bkz. id .

pubID

Başlatılacak uygulamanın yayıncı kimliği. Ayrıntılar için bkz. publisherID . Söz konusu uygulama bir yayıncı kimliğine sahip değilse, pubID parametresini boş bir dizeye (“”) ayarlayın

arguments

Uygulamaya iletilecek bir argüman dizisi. Uygulamanın NativeApplication nesnesi, bu diziye ayarlanmış bir özellikler kümesine sahip olan BrowserInvokeEvent olayını gönderir. Argümanlarda yalnızca alfasayısal karakterler tanınır. Diğer değerleri aktarmanız gerektiğinde bir kodlama şeması kullanmayı deneyin.

launchApplication() yöntemi yalnızca, fare tıklatması gibi bir user olayı için olay işleyicisinde çağrıldığında çalışabilir.

Gerekli Flash Player sürümü (Windows ve Mac OS'de sürüm 9 güncelleme 3 veya daha yenisi veya Linux'ta sürüm 10) tarayıcıda yüklü değilse launchApplication() yöntemi hata verir.

Uygulama tanımlayıcı dosyasında allowBrowserInvocation öğesi false olarak ayarlıysa, launchApplication() yöntemini çağırmanın hiçbir etkisi yoktur.

Kullanıcı arabirimini uygulamayı başlatmak için sunmadan önce, air.swf dosyasında getApplicationVersion( ) yöntemini çağırmak isteyebilirsiniz. Ayrıntılar için bkz. AIR uygulamasının yüklenip yüklenmediğini bir web sayfasından kontrol etme .

Uygulama tarayıcı başlatma özelliği üzerinden çağrıldığında, uygulamanın NativeApplication nesnesi bir BrowserInvokeEvent nesnesi gönderir. Ayrıntılar için bkz. Tarayıcıdan AIR uygulaması başlatma (ActionScript geliştiricileri için) veya Tarayıcıdan AIR uygulaması başlatma (HTML geliştiricileri için).

Tarayıcı başlatma özelliğini kullanırsanız, güvenlik sonuçlarını dikkate aldığınızdan emin olun. Bu sonuçlar, Tarayıcıdan AIR uygulaması başlatma (ActionScript geliştiricileri için) ve Tarayıcıdan AIR uygulaması başlatma (HTML geliştiricileri için) başlıklarında açıklanmaktadır.

Uygulama çalıştıktan sonra, LocalConnection sınıfını kullanarak tarayıcıdaki SWF içeriğiyle iletişim kurabilir. Daha fazla bilgi için bkz. Diğer Flash Player ve AIR örnekleri ile iletişim (ActionScript geliştiricileri için) veya Diğer Flash Player ve AIR örnekleri ile iletişim (HTML geliştiricileri için).

Not: AIR 1.5.3'teki gibi, yayıncı kimliği uygun bulunmaz. Yayıncı kimlikleri artık otomatik olarak bir uygulamaya atanmamaktadır. Geriye doğru uyumluluk için, uygulamalar bir yayıncı kimliği belirlemeye devam edebilir.