| Paket | flash.ui |
| Klass | public final class MouseCursorData |
| Arv | MouseCursorData  Object |
| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10.2, AIR 2.6 |
Använd funktionen Mouse.registerCursor() för att visa markören. Anropa Mouse.unregisterCursor() för att återställa kontrollen över markörbilden till operativsystemet. Anropa Mouse.supportsNativeCursor för att testa om systemspecifika markörer stöds på den aktuella datorn.
Den maximala markörstorleken är 32 x 32 pixlar. Genomskinlighet stöds på de flesta operativsystem.
En systemspecifik musmarkör implementeras direkt via operativsystemets markörfunktion och är ett effektivare sätt att visa en anpassad markörbild än att använda ett visningsobjekt. Du kan animera markören genom att tillhandahålla fler än en bild i egenskapen data och ange bildrutefrekvensen.
Markören visas bara innanför scenens gränser. Utanför scenen återgår kontrollen över markörbilden till operativsystemet.
Lär dig mer
Relaterade API-element
Dölj ärvda publika egenskaper
Visa ärvda publika egenskaper| Egenskap | Definieras med | ||
|---|---|---|---|
 | constructor : Object
En referens till klassobjektet eller konstruktorfunktionen för en given objektinstans. | Object | |
| data : Vector.<BitmapData>
En vektor av BitmapData-objekt som innehåller markörbilden eller markörbilderna. | MouseCursorData | ||
| frameRate : Number
Bildrutefrekvensen för animering av markören. | MouseCursorData | ||
| hotSpot : Point
Markörens aktiva punkt i pixlar. | MouseCursorData | ||
| Metod | Definieras med | ||
|---|---|---|---|
Skapar ett MouseCursorData-objekt. | MouseCursorData | ||
|
Anger om det finns en egenskap angiven för ett objekt. | Object | |
|
Anger om en instans av klassen Object finns i prototypkedjan för objektet som anges som parameter. | Object | |
|
Anger om den angivna egenskapen finns och är uppräkningsbar. | Object | |
|
Anger tillgänglighet för en dynamisk egenskap för slingåtgärder. | Object | |
|
Returnerar det här objektets strängrepresentation, formaterad i enlighet med språkspecifika konventioner. | Object | |
|
Returnerar det angivna objektets strängbeteckning. | Object | |
|
Returnerar det angivna objektets primitiva värde. | Object | |
data | egenskap |
data:Vector.<BitmapData>| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10.2, AIR 2.6 |
En vektor av BitmapData-objekt som innehåller markörbilden eller markörbilderna.
Tillhandahåll fler än en bild och ange egenskapen framerate för att animera markören.
Den maximala markörstorleken är 32 x 32 pixlar.
Implementering
public function get data():Vector.<BitmapData> public function set data(value:Vector.<BitmapData>):voidframeRate | egenskap |
frameRate:Number| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10.2, AIR 2.6 |
Bildrutefrekvensen för animering av markören.
Tillhandahåll fler än en bild i egenskapen data och ange bildrutefrekvensen till ett värde som är större än 0 för att animera markören. Markörens bildrutefrekvens kan skilja sig från den aktuella SWF-bildrutefrekvensen.
Implementering
public function get frameRate():Number public function set frameRate(value:Number):voidhotSpot | egenskap |
hotSpot:Point| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10.2, AIR 2.6 |
Markörens aktiva punkt i pixlar.
Den aktiva punkten är den punkt i markören där musklickningar registreras. Som standard finns den aktiva punkten i det övre vänstra hörnet (0,0).
Implementering
public function get hotSpot():Point public function set hotSpot(value:Point):voidMouseCursorData | () | Konstruktor |
public function MouseCursorData()| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10.2, AIR 2.6 |
Skapar ett MouseCursorData-objekt.
Anropa funktionen Mouse.registerCursor() för att visa markören.
Relaterade API-element
I exemplet används de ritningskommandon som är tillgängliga via klassen Graphics för att skapa åtta roterade bilder av en pil. De här bilderna samlas i en vektor och tilldelas till egenskapen data för MouseCursorData-objektet. (Tänk på att du också kan använda redan återgivna bitmappsbilder för en markör.)
package {
import flash.display.Sprite;
import flash.display.Shape;
import flash.display.BitmapData;
import flash.display.GraphicsPath;
import flash.ui.MouseCursorData;
import flash.ui.Mouse;
import flash.geom.Matrix;
public class MouseCursorDataExample extends Sprite {
//Graphics path data for an arrow
private var cursorPoints:Vector.<Number> = new <Number>[0,8, 16,8, 16,0, 24,12, 16,24, 16,16, 0,16, 0,8];
private var cursorDrawCommands:Vector.<int> = new <int>[1,2,2,2,2,2,2,2];
public function MouseCursorDataExample() {
var mouseCursorData:MouseCursorData = new MouseCursorData();
mouseCursorData.data = makeCursorImages();
mouseCursorData.frameRate = 1;
Mouse.registerCursor( "spinningArrow", mouseCursorData );
Mouse.cursor = "spinningArrow";
}
//Returns a Vector containing 8 cursor images
private function makeCursorImages():Vector.<BitmapData>
{
var cursorData:Vector.<BitmapData> = new Vector.<BitmapData>();
var cursorShape:Shape = new Shape();
cursorShape.graphics.beginFill( 0xff5555, .75 );
cursorShape.graphics.lineStyle( 1 );
cursorShape.graphics.drawPath( cursorDrawCommands, cursorPoints );
cursorShape.graphics.endFill();
var transformer:Matrix = new Matrix();
//Rotate and draw the arrow shape to a BitmapData object for each of 8 frames
for( var i:int = 0; i < 8; i++ )
{
var cursorFrame:BitmapData = new BitmapData( 32, 32, true, 0 );
cursorFrame.draw( cursorShape, transformer );
cursorData.push( cursorFrame );
transformer.translate(-15,-15);
transformer.rotate( 0.785398163 );
transformer.translate(15,15);
}
return cursorData;
}
}
}
Tue Jun 12 2018, 01:40 PM Z