WorkerDomain  - AS3

WorkerDomain-instansen där koden för närvarande körs. Detta är den enda WorkerDomain-förekomsten i programmet.

Anger om det aktuella miljösammanhanget har stöd för objekten WorkerDomain och Worker vid samtidig kodkörning.

Om samtidighet är tillgänglig är detta egenskapsvärde true.

Skapar en ny Worker-instans från byte i en swf-fil.

Varje arbetare skapas från och körs som ett isolerat swf-program. Om du vill skapa en Worker-instans hämtar du byte från SWF-filen som en ByteArray-förekomst och skickar den till den här metoden. Det finns tre vanliga sätt att få åtkomst till byte i en swf-fil för detta ändamål:

• Använd metataggen [Embed] för att bädda in swf-filen i programmet som en ByteArray:

      // Embed the SWF file
      [Embed(source="../swfs/BgWorker.swf", mimeType="application/octet-stream")]
      private static var BgWorker_ByteClass:Class;
      
      private function createWorker():void
      {
        // create the background worker
        var workerBytes:ByteArray = new BgWorker_ByteClass();
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• Läs in en extern SWF-fil med en URLLoader:

      // load the SWF file
      var workerLoader:URLLoader = new URLLoader();
      workerLoader.dataFormat = URLLoaderDataFormat.BINARY;
      workerLoader.addEventListener(Event.COMPLETE, loadComplete);
      workerLoader.load(new URLRequest("BgWorker.swf"));
      
      private function loadComplete(event:Event):void
      {
        // create the background worker
        var workerBytes:ByteArray = event.target.data as ByteArray;
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• Använd en SWF-fil eftersom både den primitiva arbetaren och bakgrundsarbetaren:

      // The primordial worker's main class constructor
      public function PrimordialWorkerClass()
      {
        init();
      }
      
      private function init():void
      {
        var swfBytes:ByteArray = this.loaderInfo.bytes;
        
        // Check to see if this is the primordial worker
        if (Worker.current.isPrimordial)    
        {
          // create a background worker
          var bgWorker:Worker = WorkerDomain.current.createWorker(swfBytes);
          
          // listen for worker state changes to know when the worker is running
          bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
          
          // set up communication between workers using 
          // setSharedProperty(), createMessageChannel(), etc.
          // ... (not shown)
          
          bgWorker.start();
        }
        else // entry point for the background worker
        {
          // set up communication between workers using getSharedProperty()
          // ... (not shown)
          
          // start the background work
        }

Att skapa ett Worker-objekt med createWorker() innebär inte att körningen av arbetaren kommer att starta. Om du vill starta körnigen av kod för en arbetare anropar du Worker-objektets start()-metod.

Arbetare är värdefulla eftersom de minskar riskerna för bildrutebortfall på grund av att huvudåtergivningstråden blockerats av annan kod. Emellertid kräver arbetare mer systemminne och processorkapacitet vilket kan påverka programmets generella prestanda negativt. Eftersom varje arbetare använder egna instanser av den virtuella miljön kan även pålägget för en enkel arbetare vara stort. När du använder arbetare ska du testa koden på alla målplattformar för att försäkra dig om att inte belastningen på systemet blir för stor. Adobe rekommenderar att du använder mer än en eller två bakgrundsarbetare i vanliga situationer.

Parametrar

Ger åtkomst till en uppsättning arbetare i den WorkerDomain som körs för närvarande (Worker-instansens state-egenskap är WorkerState.RUNNING).