SQLStatement  - AS3

Anger om satsen körs just nu.

Den här egenskapen är true om execute() har anropats och inte alla resultat har returnerats från databasen.

Relaterade API-element

Anger en klass (datatyp) som används för varje rad som returneras av satskörningen.

Av varje rad som returneras av en SELECT-sats skapas som standard en Object-instans, där resultatuppsättningens kolumnnamn är objektets egenskapsnamn, och varje kolumns värde utgörs av värdet på den associerade egenskapen.

Genom att ange en klass för egenskapen itemClass skapas en instans av den angivna klassen för varje rad som returneras av en SELECT-sats som körs av den här SQLStatement-instansen. Varje egenskap i itemClass-instansen tilldelas värdet från kolumnen med samma namn som egenskapen.

En klass som tilldelas den här egenskapen måste ha en konstruktor som inte kräver några parametrar. Klassen får dessutom bara ha en enda egenskap för varje kolumn som returneras av SELECT-satsen. Det ses som ett fel om en kolumn i SELECT-listan inte har något motsvarande egenskapsnamn i itemClass-klassen.

Relaterade API-element

// Employee class definition
package
{
    public class Employee
    {
        public var name:String;
        public var ssn:String;
        public var id:uint;
        public override function toString():String
        {
            return "id: "+ id.toString() + " name: " + name + " ssn: " + ssn;
        }
    }
}


// using the Employee class as SQLStatement.itemClass
var conn:SQLConnection;
var dbStatement:SQLStatement;

function init():void
{
    conn = new SQLConnection();
    conn.addEventListener(SQLEvent.OPEN, connOpenHandler);
    
    dbStatement = new SQLStatement();
    dbStatement.sqlConnection = conn;
    dbStatement.text = "SELECT id, name, ssn FROM employees";
    dbStatement.itemClass = Employee;
    
    var dbFile:File = new File(File.separator + "employee.db");
    conn.open(dbFile);
}

function connOpenHandler(event:SQLEvent):void
{
    dbStatement.addEventListener(SQLEvent.RESULT, resultHandler);
    dbStatement.execute();
}

function resultHandler(event:SQLEvent):void
{
    var result:SQLResult = dbStatement.getResult();
    if (result != null)
    {
        var emp:Employee;
        var numRows:int = result.data.length;
        for (var i:int = 0; i < numRows; i++)
        {
            emp = result.data[i];
            trace(emp.toString());
        }
    }
}

Fungerar som en associativ array där du lägger till värden för de parametrar som anges i SQL-satsens text-egenskap. Arraynycklarna är samma som parameternamnen. Om en parameter utan namn anges i satstexten är dess nyckel samma som parameterns index.

I SQL-satstexten anges en parameter med något av följande tecken: "?", ":" eller "@".

Toknen ":" och "@" indikerar en namngiven parameter och efterföljande tecken anger parameternamnet.

I följande SQL-satsexempel anges till exempel en parameter med namnet firstName med hjälp av tecknet ":":

SELECT FROM employees WHERE firstName = :firstName

"?" anger en indexerad (numrerad) parameter. Varje parameter tilldelas automatiskt ett index utifrån parametersekvensen i satstexten. Parameterindexvärdena är nollbaserade. Det betyder att den första parameterns index är 0.

Parametrar används för att det senare ska gå att skriva in ersättningsvärden som var okända när SQL-satsen skapades. Användning av parametrar är enda sättet att säkerställa lagringsklassen för ett värde som har skickats in i databasen. När parametrar inte används konverteras alla värden från textbeteckningen till en lagringsklass utifrån den associerade kolumnens typtillhörighet. Mer information om lagringsklass och kolumntillhörighet finns i avsnittet "Data type support" i bilagan ”SQL-stöd i lokala databaser”.

Parametrar används även som en säkerhetsåtgärd för att förebygga så kallade SQL-injektionsangrepp. Vid ett SQL-injektionsangrepp tar sig en användare in i SQL-koden via en plats som är tillgänglig för användare (till exempel ett datainskrivningsfält). Om programkoden konstruerar en SQL-sats genom att direkt sammanfoga användarens indata med SQL-texten, körs användarens inmatade SQL-kod mot databasen. Följande lista visar ett exempel på hur användares indata sammanfogas med SQL-texten. Använd inte den här tekniken:

     // assume the variables "username" and "password"
     // contain user-entered data
     var sql:String =
         "SELECT userId " +
         "FROM users " +
         "WHERE username = '" + username + "' " +
         "    AND password = '" + password + "'";
     var statement:SQLStatement = new SQLStatement();
     statement.text = sql;
     

SQL-injektionsangrepp förhindras om du använder satsparametrar istället för att sammanfoga användarens input i satstext, eftersom parametervärdena då uteslutande behandlas som ersättningsvärden i stället för att utgöra en del av den litterala satstexten. Följande alternativ rekommenderas istället för tidigare beskrivning:

     // assume the variables "username" and "password"
     // contain user-entered data
     var sql:String =
         "SELECT userId " +
         "FROM users " +
         "WHERE username = :username " +
         "    AND password = :password";
     var statement:SQLStatement = new SQLStatement();
     statement.text = sql;
     // set parameter values
     statement.parameters[":username"] = username;
     statement.parameters[":password"] = password;
     

Alla parametervärden måste anges innan satsen körs. Parametervärden som anges i parameters-arrayen är bundna (d.v.s. kombinerade med satstexten) när metoden execute() anropas. När execute() väl har anropats görs inga ytterligare värdeförändringar på satsen som körs. De ändrade värdena används däremot vid ett påföljande execute()-anrop. Ett fel inträffar om satstexten innehåller en parameter som inte har något värde angivet i parameters-egenskapen.

Parametervärden kan tas bort från egenskapen parameters med hjälp av metoden clearParameters().

Relaterade API-element

// employees is a SQLStatement instance
employees.text = "SELECT FROM employees WHERE first = :firstName";
employees.parameters[":firstName"] = "Sam";
employees.execute();

// employees is a SQLStatement instance
employees.text = "SELECT FROM employees WHERE first = ?";
employees.parameters[0] = "Sam";
employees.execute();

Det SQLConnection-objekt som hanterar anslutningen till databasen eller databaserna som satsen körs på.

Satsens faktiska SQL-text.

Valfri SQL-stödd text kan användas. En fullständig beskrivning av SQL-dialekten som stöds i lokala SQL-databaser finns i bilagan ”SQL support in local databases”.

Skapar en SQLStatement-instans.

Avbryter körningen av den här satsen. I likhet med SQLConnection.cancel() används den här metoden för att stoppa en fråga som har varit aktiv länge eller för att avbryta en fråga som inte har slutförts. Till skillnad från SQLConnection.cancel() avbryter den här metoden enbart den enskilda satsen. Om satsen inte håller på att köras händer ingenting när du anropar metoden.

Inga händelser skickas som direkt svar på att åtgärden cancel() har slutförts. När åtgärden cancel() väl har slutförts och satskörningen har avbrutits, skickar SQLStatement-instansen en error-händelse som anger att satskörningen (anropet execute() eller next()) inte har slutförts. Om däremot ett värde har angetts för parametern responder för anropet execute() eller next(), anropas den angivna felhanteringsmetoden istället. I båda fallen har SQLError-instansen som har skickats till avlyssnarna en errorID-egenskap med värdet 3118 (Avbruten åtgärd).

Tar bort alla aktuella parameterinställningar.

Relaterade API-element

Kör SQL:en i text-egenskapen mot databasen som är ansluten till SQLConnection-objektet i egenskapen sqlConnection.

Om argumentet responder inte är null anger det angivna Responder-objektet vilka metoder som ska anropas för att hantera åtgärdsresultaten. Om argumentet responder är null i asynkront körningsläge skickas en result-händelse om åtgärden fungerar och en error-händelse om åtgärden misslyckas.

Anropa metoden getResult() om du vill se resultatet av en sats, t.ex. resultatraderna för en SELECT-sats eller den databasgenererade primära nyckeln för en INSERT-sats. Resultaten är tillgängliga direkt efter det att satsen körs i synkront läge eller när result-händelsen skickas i asynkront läge.

Alla satser måste förberedas (kompileras) innan de kan köras. Första gången en execute()-metod för en SQLStatement-instans anropas förbereds satsen av körningen. När en sats har förberetts behöver den inte förberedas igen om inte egenskapen text ändras. Inställning av ett eller flera parametervärden medför inte att satsen behöver förberedas på nytt.

Parametrar

Relaterade API-element

var conn:SQLConnection;
var dbStatement:SQLStatement;

function init():void
{
    conn = new SQLConnection();
    conn.addEventListener(SQLEvent.OPEN, connOpenHandler);
    
    dbStatement = new SQLStatement();
    dbStatement.sqlConnection = conn;
    dbStatement.text = "SELECT id, name, ssn FROM employees";
    
    var dbFile:File = new File(File.separator + "employee.db");
    conn.open(dbFile);
}

function connOpenHandler(event:SQLEvent):void
{
    dbStatement.addEventListener(SQLEvent.RESULT, resultHandler);
    dbStatement.addEventListener(SQLErrorEvent.ERROR, errorHandler);
    dbStatement.execute();
}

function resultHandler(event:SQLEvent):void
{
    var result:SQLResult = dbStatement.getResult();
    if (result != null)
    {
        var numRows:int = result.data.length;
        for (var i:int = 0; i < numRows; i++)
        {
            var row:Object = result.data[i];
            trace("id:", row.id, ", name:", row.name, ", ssn:", row.ssn);
        }
    }
}

function errorHandler(event:SQLErrorEvent):void
{
    trace("An error occured while executing the statement.");
}

var conn:SQLConnection;
var dbStatement:SQLStatement;
var employeeResponder:Responder;

function init():void
{
    conn = new SQLConnection();
    conn.addEventListener(SQLEvent.OPEN, connOpenHandler);
    
    dbStatement = new SQLStatement();
    dbStatement.sqlConnection = conn;
    dbStatement.text = "SELECT id, name, ssn FROM employees";
    
    var dbFile:File = new File(File.separator + "employee.db");
    conn.open(dbFile);
}

function connOpenHandler(event:SQLEvent):void
{
    employeeResponder = new Responder(resultHandler, errorHandler);
    dbStatement.execute(-1, employeeResponder);
}

function resultHandler(result:SQLResult):void
{
    if (result != null)
    {
        var numRows:int = result.data.length;
        for (var i:int = 0; i < numRows; i++)
        {
            var row:Object = result.data[i];
            trace("id:", row.id, ", name:", row.name, ", ssn:", row.ssn);
        }
    }
}

function errorHandler(error:SQLError):void
{
    trace("An error occured while executing the statement.");
}

Ger åtkomst till ett SQLResult-objekt som innehåller satskörningsresultaten, inklusive resultatrader från en SELECT-sats och annan information om satskörningen för alla satser som har körts. I asynkront körningsläge är inte resultatinformationen tillgänglig förrän result-händelsen har skickats.

När en SELECT-sats körs, och om execute()-metoden anropas med standardvärdet för prefetch-argumentet inställt på -1, finns hela frågeresultatuppsättningen i det SQLResult-objekt som returneras.

När ett prefetch-argument har angetts för ett execute() eller next()-metodanrop fungerar metoden getResult() som en resultatkö enligt principen först-in-först-ut. Varje gång en result-händelse skickas läggs ett nytt SQLResult-objekt till i kön. Varje gång metoden getResult() anropas returneras det första SQLResult-objektet (det som först lades till i kön) och tas bort från kön. När det inte återstår fler SQLResult-objekt i kön returnerar getResult() null.

Observera att SQLResult-objekten står kvar i kön om de inte tas bort genom anrop till getResult(). Om t.ex. metoden execute() anropas flera gånger utan att getResult() anropas står SQLResult-objekten för varje execute()-anrop kvar i kön.

Relaterade API-element

Hämtar nästa del av resultatuppsättningen för en SELECT-sats. Om det inte finns några fler rader i resultatuppsättningen skickas en result-händelse, men inga fler SQLResult-objekt läggs till i getResult()-kön.

Om argumentet responder inte är null i asynkront körningsläge anger det angivna Responder-objektet vilka metoder som ska anropas för att hantera åtgärdsresultaten. Om argumentet responder är null skickas en result-händelse om åtgärden fungerar och en error-händelse om åtgärden misslyckas.

Den här metoden kan bara anropas medan satsen fortfarande körs. Om satsen är en SELECT-fråga och det angivna prefetch-argumentet är större än noll, körs satsen tills hela resultatuppsättningen returneras eller någon av metoderna SQLStatement.cancel() och SQLConnection.cancel() anropas.

Parametrar

Relaterade API-element

var conn:SQLConnection;
var dbStatement:SQLStatement;

function init():void
{
    conn = new SQLConnection();
    conn.addEventListener(SQLEvent.OPEN, connOpenHandler);
    
    dbStatement = new SQLStatement();
    dbStatement.sqlConnection = conn;
    dbStatement.text = "SELECT id, name, ssn FROM employees";
    
    var dbFile:File = new File(File.separator + "employee.db");
    conn.open(dbFile);
}

function connOpenHandler(event:SQLEvent):void
{
    dbStatement.addEventListener(SQLEvent.RESULT, resultHandler);
    dbStatement.addEventListener(SQLErrorEvent.ERROR, errorHandler);
    dbStatement.execute(10);
}

function resultHandler(event:SQLEvent):void
{
    var result:SQLResult = dbStatement.getResult();
    if (result != null)
    {
        var numRows:int = result.data.length;
        for (var i:int = 0; i < numRows; i++)
        {
            var row:Object = result.data[i];
            trace("id:", row.id, ", name:", row.name, ", ssn:", row.ssn);
        }
        if (!result.complete)
        {
            dbStatement.next(10);
        }
    }
}

function errorHandler(event:SQLErrorEvent):void
{
    trace("An error occured while executing the statement.");
}

Skickas om ett fel uppstår under en åtgärd.

Relaterade API-element

Skickas när åtgärderna för metodanropen execute() eller next() har slutförts. När åtgärden result har skickats kan metoden getResult() anropas för att hämta satsresultat.

Relaterade API-element