BevelFilter  - AS3

Угол наклона. Действительны значения от 0 до 360°. Значением по умолчанию является 45°.

Значение угла представляет угол, под которым падает свет из предполагаемого источника, и определяет расположение эффекта относительно объекта. Если свойство distance имеет значение 0, эффект не смещается относительно объекта и, следовательно, свойство angle никак не влияет на результат.

Интенсивность горизонтальной размывки (в пикселях). Действительны значения от 0 до 255 (плавающая запятая). По умолчанию используется значение 4. Значения, являющиеся степенью 2 (т. е. 2, 4, 8, 16 и 32), оптимизируются и выполняются быстрее, чем остальные.

Интенсивность вертикальной размывки (в пикселях). Действительны значения от 0 до 255 (плавающая запятая). По умолчанию используется значение 4. Значения, являющиеся степенью 2 (т. е. 2, 4, 8, 16 и 32), оптимизируются и выполняются быстрее, чем остальные.

Расстояние смещения наклона. Действительные значения заданы в пикселах (плавающая запятая). По умолчанию — 4.

Значение альфа-прозрачности цвета выделения. Значение указано в виде нормализованного значения от 0 до 1. Например, при 0,25 устанавливается 25-процентная прозрачность. Значением по умолчанию является 1.

Цвет подсветки наклона. Действительны значения в шестнадцатеричном формате, 0xRRGGBB. Значение по умолчанию — 0xFFFFFF.

Применяет эффект выбивки (true), который фактически делает заливку объекта прозрачной и выявляет цвет фона документа. Значение по умолчанию — false (без эффекта выбивки).

Заданное число применений фильтра. Значение по умолчанию — BitmapFilterQuality.LOW, что эквивалентно однократному применению фильтра. Значение BitmapFilterQuality.MEDIUM применяет фильтр дважды; значение BitmapFilterQuality.HIGH — трижды. Фильтры с более низкими значениями выполняются быстрее.

Для большинства приложений достаточно значения quality на уровне «low» («низкое»), «medium» («среднее») или «high» («высокое»). Хотя можно использовать дополнительные числовые значения до 15 для получения разнообразных эффектов, более высокие значения выполняются дольше. Вместо увеличения значения quality можно просто увеличить значения свойств blurX и blurY. Это даст похожий эффект, а выполнение будет происходить быстрее.

Можно использовать следующие константы BitmapFilterQuality для задания значений свойства quality:

• BitmapFilterQuality.LOW
• BitmapFilterQuality.MEDIUM
• BitmapFilterQuality.HIGH

Значение альфа-прозрачности цвета тени. Данное значение указано в виде нормализованного значения от 0 до 1. Например, при 0,25 устанавливается 25-процентная прозрачность. По умолчанию — 1.

Цвет тени для наклона. Действительны значения в шестнадцатеричном формате, 0xRRGGBB. Значение по умолчанию — 0x000000.

Степень вдавливания или нанесения. Действительны значения от 0 до 255. Чем выше значение, тем более насыщен цвет фаски и тем сильнее контраст между наклоном и фоном. Значением по умолчанию является 1.

Расположение наклона на объекте. Внутренний и внешний наклоны применяются к внутренней и внешней сторонам, а полная фаска применяется ко всему объекту. Действительными значениями являются константы BitmapFilterType:

• BitmapFilterType.INNER
• BitmapFilterType.OUTER
• BitmapFilterType.FULL

Инициализирует новый экземпляр BevelFilter с заданными параметрами.

Связанные элементы API

Возвращает копию данного объекта фильтра.

1. Импортируется требуемый класс.
2. Объявляются три свойства функции draw(), рисующей объект, к которому и применяется фильтр наклона.
3. Создается функция конструктора BevelFilterExample(), которая выполняет следующее:
   • Вызывает функцию draw(), которая объявляется позднее.
   • Объявляет переменную filter в виде объекта BitmapFilter и назначает ее возвращаемому значению вызова getBitmapFilter().
   • Создает новый массив myFilters и добавляет к массиву filter, а также назначает myFilters свойству filters объекта BevelFilterExample. В результате применяются все фильтры, обнаруженные в myFilters. В нашем случае это только один фильтр filter.
4. Создайте функцию getBitmapFilter для создания фильтра и задания его свойств.
5. Создайте функцию draw(). Эта функция использует методы класса Graphics, доступные через свойство graphics класса Sprite для рисования квадрата.

package {
    import flash.display.Sprite;
    import flash.filters.BevelFilter;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BitmapFilterType;

    public class BevelFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function BevelFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var distance:Number       = 5;
            var angleInDegrees:Number = 45;
            var highlightColor:Number = 0xFFFF00;
            var highlightAlpha:Number = 0.8;
            var shadowColor:Number    = 0x0000FF;
            var shadowAlpha:Number    = 0.8;
            var blurX:Number          = 5;
            var blurY:Number          = 5;
            var strength:Number       = 5;
            var quality:Number        = BitmapFilterQuality.HIGH;
            var type:String           = BitmapFilterType.INNER;
            var knockout:Boolean      = false;

            return new BevelFilter(distance,
                                   angleInDegrees,
                                   highlightColor,
                                   highlightAlpha,
                                   shadowColor,
                                   shadowAlpha,
                                   blurX,
                                   blurY,
                                   strength,
                                   quality,
                                   type,
                                   knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}