FocusEvent  - AS3

Указывает направление фокуса для события focusIn.

Связанные элементы API

Если принимает значение true, свойство relatedObject принимает значение null по причинам, связанным с изолированными средами безопасности. Если номинальным значением свойства relatedObject является ссылка на объект DisplayObject в другой изолированной среде, свойство relatedObject принимает значение null, пока не будут заданы двусторонние права в границах данной изолированной среды. Права задаются путем вызова метода Security.allowDomain() из SWF-файла или указания файла политик на сервере файла изображений и задания свойства LoaderContext.checkPolicyFile при загрузке изображения.

Связанные элементы API

Значение кода клавиши, нажатой для запуска события keyFocusChange.

Ссылка на дополняющий экземпляр InteractiveObject, на который влияет смена фокуса. Например, когда происходит событие focusOut, relatedObject представляет InteractiveObject, получивший фокус.

Это свойство может принимать значение null по двум причинам: связанный объект отсутствует или связанный объект существует, но находится в изолированной программной среде безопасности, доступ к которой запрещен. Используйте свойство isRelatedObjectInaccessible() для определения причины.

Связанные элементы API

Определяет, активирован ли модификатор клавиши Shift. Если да, то параметр имеет значение true. В противном случае значение — false. Это свойство используется, только если FocusEvent относится к типу keyFocusChange.

Создает объект Event со специфической информацией, имеющей отношение к событиям фокуса. Объекты Event передаются прослушивателям событий в качестве параметров.

Связанные элементы API

Создает копию объекта FocusEvent и задает значение каждого свойства, совпадающее с оригиналом.

Возвращает строку, содержащую все свойства объекта FocusEvent. Строка имеет следующий формат:

[FocusEvent type=value bubbles=value cancelable=value relatedObject=value shiftKey=value] keyCode=value]

Задает значение свойства type для объекта события focusIn.

Это событие имеет следующие свойства:

Связанные элементы API

Задает значение свойства type для объекта события focusOut.

Это событие имеет следующие свойства:

Связанные элементы API

Задает значение свойства type для объекта события keyFocusChange.

Это событие имеет следующие свойства:

Связанные элементы API

Задает значение свойства type для объекта события mouseFocusChange.

Это событие имеет следующие свойства:

Связанные элементы API

1. Объявляются свойства child (типа Sprite) и childCount (типа uint).
2. Цикл for создает пять голубых квадратов в точке с координатами (0,0). Сначала свойство child назначается новому экземпляру CustomSprite. При создании каждого объекта CustomSprite происходит следующее.
   • Свойству size типа uint задается значение 50 (в пикселях), а для bgColor задается голубой цвет.
   • В конструкторе свойствам класса Sprite buttonMode и useHandCursor задается значение true.
   • Регистрируется прослушиватель событий типа click вместе со связанным подписчиком clickHandler(). Метод подписчика создает локальную переменную target типа Sprite и присваивает ее полю, получившему щелчок. После этого фокус монтажного стола переводится на target.
   • Вызывается метод draw(), создающий квадрат 50 x 50 пикселей путем вызова методов beginFill(), drawRect() и endFill() класса Graphics и свойств экземпляра.
3. В цикле for вызывается метод configureListeners(), создающий три пары прослушивателей событий и подписчиков:
   • focusIn/focusInHandler() отправляется после события click для любого объекта списка отображения (поля) получившего щелчок.
   • focusOut/focusOutHandler() отправляется, когда щелчок получает другое поле или когда фокус покидает монтажный стол (например, при щелчке за пределами Flash Player).
   • keyFocusChange/keyFocusChangeHandler() отправляется, если для выбора объекта списка отображения используется клавиша Tab или клавиши со стрелками влево или вправо. Однако метод keyFocusChangeHandler() перехватывает клавиши со стрелками влево и вправо и отключает их, вызвав метод preventDefault().
4. В цикле for каждый квадрат добавляется в список отображения и показывается с помощью метода addChild() (все в одной и той же области).
5. Конструктор вызывает метод refreshLayout(), располагающий оранжевые квадраты по верхнему краю экрана (y = 0) на расстоянии 5 пикселей друг от друга.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.events.FocusEvent;
    import flash.events.IEventDispatcher;

    public class FocusEventExample extends Sprite {
        private var gutter:uint = 5;
        private var childCount:uint = 5;

        public function FocusEventExample() {
            var child:Sprite;
            for(var i:uint; i < childCount; i++) {
                child = new CustomSprite();
                configureListeners(child);
                addChild(child);
            }
            refreshLayout();
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(FocusEvent.FOCUS_IN, focusInHandler);
            dispatcher.addEventListener(FocusEvent.FOCUS_OUT, focusOutHandler);
            dispatcher.addEventListener(FocusEvent.KEY_FOCUS_CHANGE, keyFocusChangeHandler);
            dispatcher.addEventListener(FocusEvent.MOUSE_FOCUS_CHANGE, mouseFocusChangeHandler);
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject = getChildAt(0);
            var lastChild:DisplayObject = child;
            for(var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = lastChild.x + lastChild.width + gutter;
                lastChild = child;
            }
        }

        private function focusInHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusInHandler: " + target.name);
        }

        private function focusOutHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusOutHandler: " + target.name);
        }

        private function keyFocusChangeHandler(event:FocusEvent):void {
            if(event.keyCode == 39 || event.keyCode == 37){
                event.preventDefault()
            }
            var target:CustomSprite = CustomSprite(event.target);
            trace("keyFocusChangeHandler: " + target.name);
        }
        private function mouseFocusChangeHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("mouseFocusChangeHandler: " + target.name);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0x00CCFF;

    public function CustomSprite() {
        buttonMode = true;
        useHandCursor = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        var target:Sprite = Sprite(event.target);
        trace("clickHandler: " + target.name);
        stage.focus = target;
    }
}