Captura de entrada de texto

Flash Player 9 e posterior, Adobe AIR 1.0 e posterior

Por padrão, a propriedade type de um campo de texto está definida como dynamic . Se você definir a propriedade type como input usando a classe TextFieldType, poderá colecionar a entrada do usuário e salvar o valor para uso em outras partes do aplicativo. Os campos de texto de entrada são úteis para formulários e quaisquer aplicativos que desejem que o usuário defina um valor de texto a ser utilizado em outro lugar no programa.

Por exemplo, o código a seguir cria um campo de texto de entrada denominado myTextBox . Assim que o usuário inserir texto no campo, o evento textInput será acionado. Um manipulador de eventos denominado textInputCapture capturará a sequência de caracteres de texto inserida e a designará para uma variável. O Flash Player ou AIR exibirá o novo texto em outro campo de texto, denominado myOutputBox .

package 
{ 
    import flash.display.Sprite; 
    import flash.display.Stage; 
    import flash.text.*; 
    import flash.events.*; 
 
    public class CaptureUserInput extends Sprite 
    { 
        private var myTextBox:TextField = new TextField(); 
        private var myOutputBox:TextField = new TextField(); 
        private var myText:String = "Type your text here."; 
 
        public function CaptureUserInput() 
        { 
            captureText(); 
        } 
         
        public function captureText():void 
        { 
            myTextBox.type = TextFieldType.INPUT; 
            myTextBox.background = true; 
            addChild(myTextBox); 
            myTextBox.text = myText; 
            myTextBox.addEventListener(TextEvent.TEXT_INPUT, textInputCapture); 
        } 
         
        public function textInputCapture(event:TextEvent):void 
        { 
            var str:String = myTextBox.text; 
            createOutputBox(str); 
        } 
             
        public function createOutputBox(str:String):void 
        { 
            myOutputBox.background = true; 
            myOutputBox.x = 200; 
            addChild(myOutputBox); 
            myOutputBox.text = str; 
        } 
         
    } 
}