| Pacote | flashx.textLayout.events |
| Classe | public class FlowOperationEvent |
| Herança | FlowOperationEvent  Event Object |
| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | Flash Player 10, AIR 1.5 |
Antes que qualquer operação seja realizada, o objeto TextFlow despacha um FlowOperationEvent com a propriedade type definida como FlowOperationEvent.FLOW_OPERATION_BEGIN. Você pode determinar que tipo de operação está prestes a começar, verificando a propriedade operation. Os eventos do tipo FLOW_OPERATION_BEGIN podem ser cancelados. Isso significa que, se você decidir que a operação não deve prosseguir, poderá chamar Event.PreventDefault() para cancelar a operação. Se você cancelar a operação, ela não será realizada e o evento FLOW_OPERATION_END não será despachado. Além disso, você pode optar por chamar o EditManager para realizar outra operação antes que a operação que disparou o evento seja efetuada. Caso você faça isso, as operações realizadas no seu controlador de eventos serão desfeitas como uma única operação que disparou o evento.
Se você permitir que a operação prossiga, TextFlow despachará um FlowOperationEvent quando a operação for concluída, e sua propriedade type terá o valor FlowOperationEvent.FLOW_OPERATION_END. Este evento é despachado antes que o Flash Player emita algum erro que possa ter ocorrido em virtude da operação. Isso dará a você a oportunidade de processar o erro antes que o Flash Player gere o erro. Você pode acessar o erro através da propriedade error do evento. Se você optar por solucionar o erro no seu gerenciador de eventos, poderá evitar que o Flash Player gere o erro, cancelando o evento FLOW_OPERATION_END através da chamada a Event.preventDefault(). Além disso, você pode optar por chamar novamente o EditManager para realizar outras operações. Se você fizer isso, as operações resultantes serão desfeitas como uma unidade com a operação que disparou o evento.
Elementos da API relacionados
Ocultar propriedades públicas herdadas
Mostrar propriedades públicas herdadas| Propriedade | Definido por | ||
|---|---|---|---|
 | bubbles : Boolean [somente leitura]
Indica se um evento é do tipo bubbling. | Event | |
| cancelable : Boolean [somente leitura]
Indica se o comportamento associado ao evento pode ser impedido. | Event | |
| constructor : Object
Uma referência ao objeto de classe ou à função de construtor de uma determinada ocorrência de objeto. | Object | |
| currentTarget : Object [somente leitura]
O objeto que está processando ativamente o objeto Event com um ouvinte de evento. | Event | |
| error : Error
O erro gerado, se houve, durante uma operação. | FlowOperationEvent | ||
| eventPhase : uint [somente leitura]
A fase atual no fluxo de eventos. | Event | |
| level : int
As operações podem ser mescladas em operações compostas pelo aninhamento. | FlowOperationEvent | ||
| operation : FlowOperation
A operação que está prestes a começar ou que terminou há pouco. | FlowOperationEvent | ||
| target : Object [somente leitura]
O destino de evento. | Event | |
| type : String [somente leitura]
O tipo de evento. | Event | |
| Método | Definido por | ||
|---|---|---|---|
FlowOperationEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false, operation:FlowOperation = null, level:int = 0, error:Error = null) Cria um objeto de evento que contém informações sobre uma operação de fluxo. | FlowOperationEvent | ||
|
Duplica uma ocorrência de uma subclasse Event. | Event | |
|
Uma função de utilitário para implementar o método toString() em classes ActionScript 3.0 Event personalizadas. | Event | |
|
Indica se um objeto tem uma propriedade especificada definida. | Object | |
|
Verifica se o método preventDefault() foi chamado no evento. | Event | |
|
Indica se uma ocorrência da classe Object está na cadeia de protótipos do objeto especificado como o parâmetro. | Object | |
|
Cancela um comportamento padrão de evento se esse comportamento puder ser cancelado. | Event | |
|
Indica se a propriedade especificada existe e é enumerável. | Object | |
|
Define a disponibilidade de uma propriedade dinâmica para operações de repetição. | Object | |
|
Impede o processamento de qualquer ouvinte de evento no nó atual e qualquer nó subsequente no fluxo de eventos. | Event | |
|
Impede o processamento de algum ouvinte de evento em nós subsequentes ao nó atual no fluxo de eventos. | Event | |
|
Retorna a representação da string deste objeto, formatado segundo as convenções específicas para a localidade. | Object | |
|
Retorna uma string que contém todas as propriedades do objeto Event. | Event | |
|
Retorna o valor primitivo do objeto especificado. | Object | |
| Constante | Definido por | ||
|---|---|---|---|
| FLOW_OPERATION_BEGIN : String = "flowOperationBegin" [estático]
Define o valor da propriedade type de um objeto de evento flowOperationBegin. | FlowOperationEvent | ||
| FLOW_OPERATION_COMPLETE : String = "flowOperationComplete" [estático]
Define o valor da propriedade type de um objeto de evento flowOperationComplete. | FlowOperationEvent | ||
| FLOW_OPERATION_END : String = "flowOperationEnd" [estático]
Define o valor da propriedade type de um objeto de evento flowOperationEnd. | FlowOperationEvent | ||
error | propriedade |
error:Error| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | Flash Player 10, AIR 1.5 |
O erro gerado, se houve, durante uma operação. Se ocorrer um erro durante uma operação, uma referência ao objeto de erro será anexada ao evento FLOW_OPERATION_END. Isso dará a você a oportunidade de tratar o erro antes que o Flash Player gere o erro. Se você cancelar o evento, o Flash Player não gerará o erro.
Implementação
public function get error():Error public function set error(value:Error):voidlevel | propriedade |
level:int| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | Flash Player 10, AIR 1.5 |
As operações podem ser mescladas em operações compostas pelo aninhamento. Este marcador descreve o nível de aninhamento da operação.
Implementação
public function get level():int public function set level(value:int):voidoperation | propriedade |
operation:FlowOperation| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | Flash Player 10, AIR 1.5 |
A operação que está prestes a começar ou que terminou há pouco.
Implementação
public function get operation():FlowOperation public function set operation(value:FlowOperation):voidElementos da API relacionados
FlowOperationEvent | () | Construtor |
public function FlowOperationEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false, operation:FlowOperation = null, level:int = 0, error:Error = null)| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | Flash Player 10, AIR 1.5 |
Cria um objeto de evento que contém informações sobre uma operação de fluxo.
Parâmetrostype:String — O tipo de evento. Ouvintes de eventos podem acessar essas informações por meio da propriedade type herdada. Existem dois tipos: FlowOperationEvent.FLOW_OPERATION_BEGIN; FlowOperationEvent.FLOW_OPERATION_END.
| |
bubbles:Boolean (default = false) | |
cancelable:Boolean (default = false)Event.preventDefault() na sua função gerenciadora de eventos.
| |
operation:FlowOperation (default = null) | |
level:int (default = 0) | |
error:Error (default = null) |
FLOW_OPERATION_BEGIN | Constante |
public static const FLOW_OPERATION_BEGIN:String = "flowOperationBegin"| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | Flash Player 10, AIR 1.5 |
Define o valor da propriedade type de um objeto de evento flowOperationBegin despachado antes que uma operação seja executada. Se este evento for cancelado, a operação será bloqueada.
FLOW_OPERATION_COMPLETE | Constante |
public static const FLOW_OPERATION_COMPLETE:String = "flowOperationComplete"| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | Flash Player 10, AIR 1.5 |
Define o valor da propriedade type de um objeto de evento flowOperationComplete. Despachado depois que todas as operações, incluindo operações pendentes e de correção, forem concluídas, a composição for concluída e a tela for rolada.
FLOW_OPERATION_END | Constante |
public static const FLOW_OPERATION_END:String = "flowOperationEnd"| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | Flash Player 10, AIR 1.5 |
Define o valor da propriedade type de um objeto de evento flowOperationEnd despachado depois que uma operação é concluída. Todos os erros são armazenados em OperationEvent.error. Se houver um erro, o cancelamento deste evento bloqueará a nova geração do erro. Em geral, todos os erros têm a probabilidade de ser fatais.
A alteração de uma operação neste momento (após sua execução) poderá falhar.
Este exemplo mostra como criar um gerenciador de eventos que monitora o começo e o fim de uma operação de fluxo de texto. As duas etapas principais são chamar o método addEventListener() no fluxo de texto e criar uma função gerenciadora de eventos.
A chamada a addEventListener() é efetuada à instância de TextFlow. Você pode usar a string simples "flowOperationBegin" ou "flowOperationEnd", mas é mais seguro usar a constante estática FlowOperationEvent. FLOW_OPERATION_BEGIN ou FlowOperationEvent. FLOW_OPERATION_END, respectivamente.
As funções do gerenciador de eventos neste exemplo são denominadas opBeginHandler() e opEndHandler(). O método opBeginHandler() usa a função trace() para produzir uma instrução trace que indica que uma operação de colagem iniciou. O método opEndHandler() também usa a função trace(), mas produz uma instrução trace só quando ocorre um erro.
package flashx.textLayout.events.examples
{
import flash.display.Sprite;
import flashx.textLayout.compose.StandardFlowComposer;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.edit.EditManager;
import flashx.textLayout.elements.TextFlow;
import flashx.textLayout.events.FlowOperationEvent;
import flashx.textLayout.operations.FlowOperation;
import flashx.textLayout.operations.PasteOperation;
import flashx.undo.UndoManager;
public class FlowOperationEvent_example extends Sprite
{
private var inputContainer:Sprite;
private var inputTextFlow:TextFlow;
private var inputController:ContainerController;
private var inputEditManager:EditManager;
private var inputUndoManager:UndoManager;
public function FlowOperationEvent_example()
{
var replaceText:String = "paste text here";
inputTextFlow = new TextFlow();
inputContainer = new Sprite();
inputContainer.x = 30;
inputContainer.y = 100;
this.stage.addChild( inputContainer );
inputController = new ContainerController(inputContainer, 225, 20);
inputController.verticalScrollPolicy = flashx.textLayout.container.ScrollPolicy.OFF;
inputTextFlow = TextConverter.importToFlow(replaceText, TextConverter.PLAIN_TEXT_FORMAT);
inputTextFlow.flowComposer = new StandardFlowComposer();
inputTextFlow.flowComposer.addController(inputController);
inputUndoManager = new UndoManager();
inputEditManager = new EditManager(inputUndoManager);
inputTextFlow.interactionManager = inputEditManager;
inputTextFlow.addEventListener(FlowOperationEvent.FLOW_OPERATION_BEGIN, opBeginHandler);
inputTextFlow.addEventListener(FlowOperationEvent.FLOW_OPERATION_END, opEndHandler);
inputTextFlow.flowComposer.updateAllControllers();
}
private function opBeginHandler(evt:FlowOperationEvent):void {
var flowOp:FlowOperation = evt.operation;
if(flowOp is PasteOperation) {
trace("You can cancel or modify the paste operation in this event handler.");
}
}
private function opEndHandler(evt:FlowOperationEvent):void {
var flowOp:FlowOperation = evt.operation;
if(evt.error) {
trace("You can handle the error here and call preventDefault().");
}
}
}
}
Wed Jun 13 2018, 11:10 AM Z