HTMLHost

Pacote	flash.html
Classe	public class HTMLHost
Herança	HTMLHost Object

Versões de runtime:

AIR 1.0

Um objeto HTMLHost define comportamentos de um objeto HTMLLoader para os elementos da interface do usuário que podem ser controlados pela configuração de várias propriedades ou da chamada de vários métodos do objeto de janela de uma página HTML. Esses métodos e propriedades são:

window.blur()
window.focus()
window.moveBy()
window.moveTo()
window.location
window.close()
window.open()
window.resizeBy()
window.resizeTo()
window.status
window.document.title

Os métodos na classe HTMLHost fornecem modos de manipular alterações em cada uma dessas configurações de janela. Para usar essa classe, crie uma nova classe (subclasse) que amplie a classe HTMLHost e substitua os métodos para os quais você deseja definir comportamentos. Os métodos da classe HTMLHost lidam com as propriedades JavaScript e métodos conforme a seguir:

Propriedade ou método JavaScript	Método HTMLHost
`window.blur()`	`windowBlur()`
`window.focus()`	`windowFocus`
`window.location`	`updateLocation`
`window.close()`	`windowClose`
`window.open()`	`createWindow`
`window.status`	`updateStatus`
`window.document.title`	`updateTitle`

Para responder às alterações nos métodos window.moveBy(), window.moveTo(), window.resizeBy() e window.resizeTo(), substitua o método set windowRect() na subclasse de HTMLHost.

Cada objeto HTMLHost pode ser associado a no máximo um objeto HTMLLoader. A atribuição de uma instância HTMLHost à propriedade htmlHost do objeto HTMLLoader estabelece esse relacionamento. A atribuição de null para a propriedade htmlHost do objeto HTMLLoader ou a definição do objeto HTMLHost como a propriedade htmlHost de outro objeto HTMLLoader remove o HTMLHost do primeiro objeto HTMLLoader.

Veja os exemplos

Elementos da API relacionados

HTMLLoader
HTMLWindowCreateOptions

Propriedades públicas

Ocultar propriedades públicas herdadas

Mostrar propriedades públicas herdadas

	Propriedade		Definido por
		constructor : Object Uma referência ao objeto de classe ou à função de construtor de uma determinada ocorrência de objeto.	Object
		htmlLoader : flash.html:HTMLLoader [somente leitura] O objeto HTMLLoader ao qual se aplica este objeto HostControl.	HTMLHost
		windowRect : Rectangle A propriedade que é alterada quando o código JavaScript no objeto HTMLLoader chama o método window.moveBy(), window.moveTo(), window.resizeBy() ou window.resizeTo().	HTMLHost

Métodos públicos

Ocultar métodos públicos herdados

Mostrar métodos públicos herdados

	Método		Definido por
		HTMLHost(defaultBehaviors:Boolean = true) Cria um objeto HTMLHost.	HTMLHost
		createWindow(windowCreateOptions:flash.html:HTMLWindowCreateOptions):flash.html:HTMLLoader A função chamada quando o código JavaScript no HTMLLoader chama o método window.open().	HTMLHost
		hasOwnProperty(name:String):Boolean Indica se um objeto tem uma propriedade especificada definida.	Object
		isPrototypeOf(theClass:Object):Boolean Indica se uma ocorrência da classe Object está na cadeia de protótipos do objeto especificado como o parâmetro.	Object
		propertyIsEnumerable(name:String):Boolean Indica se a propriedade especificada existe e é enumerável.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Define a disponibilidade de uma propriedade dinâmica para operações de repetição.	Object
		toLocaleString():String Retorna a representação da string deste objeto, formatado segundo as convenções específicas para a localidade.	Object
		toString():String Retorna a representação de string do objeto especificado.	Object
		updateLocation(locationURL:String):void A função chamada quando o código JavaScript no objeto HTMLLoader define a propriedade window.location.	HTMLHost
		updateStatus(status:String):void A função chamada quando o código JavaScript no objeto HTMLLoader define a propriedade window.status.	HTMLHost
		updateTitle(title:String):void A função chamada quando o código JavaScript no objeto HTMLLoader define a propriedade window.document.title, ou quando o elemento title é alterado, seja via DOM ou devido a uma nova página carregada.	HTMLHost
		valueOf():Object Retorna o valor primitivo do objeto especificado.	Object
		windowBlur():void A função chamada quando o código JavaScript no objeto HTMLLoader chama o método window.blur().	HTMLHost
		windowClose():void A função chamada quando o código JavaScript no objeto HTMLLoader chama o método window.close().	HTMLHost
		windowFocus():void A função chamada quando o código JavaScript no objeto HTMLLoader chama o método window.focus().	HTMLHost

Detalhes da propriedade

htmlLoader

propriedade

htmlLoader:flash.html:HTMLLoader [somente leitura]

Versões de runtime:

AIR 1.0

O objeto HTMLLoader ao qual se aplica este objeto HostControl. A propriedade htmlHost para a qual o objeto HTMLLoader foi definido para este HostControl.

Implementação
public function get htmlLoader():flash.html:HTMLLoader

Elementos da API relacionados

HTMLLoader.htmlHost

windowRect

propriedade

windowRect:Rectangle

Versões de runtime:

AIR 1.0

A propriedade que é alterada quando o código JavaScript no objeto HTMLLoader chama o método window.moveBy(), window.moveTo(), window.resizeBy() ou window.resizeTo().

Na subclasse do HTMLHost, substitua a definição do método windowRect() para manipular os novos limites window, conforme desejado.

Implementação
public function get windowRect():Rectangle
public function set windowRect(value:Rectangle):void

Detalhes do construtor

()

Construtor

public function HTMLHost(defaultBehaviors:Boolean = true)

Versões de runtime:

AIR 1.0

Cria um objeto HTMLHost.

Parâmetros

defaultBehaviors:Boolean (default = true) — Indica se os comportamentos de conteúdo-raiz devem ser fornecidos por padrão.

Detalhes do método

createWindow

()

método

public function createWindow(windowCreateOptions:flash.html:HTMLWindowCreateOptions):flash.html:HTMLLoader

Versões de runtime:

AIR 1.0

A função chamada quando o código JavaScript no objeto HTMLLoader chama o método window.open().

Por padrão, uma chamada JavaScript para window.open() na página HTML de um HTMLLoader não abre um novo objeto NativeWindow no tempo de execução. É possível abrir um novo objeto NativeWindow no tempo de execução criando um novo objeto NativeWindow na substituição do método createWindow na subclasse da classe HTMLHost.

Parâmetros

windowCreateOptions:flash.html:HTMLWindowCreateOptions — Um objeto contendo propriedades na string despachado como o parâmetro features da chamada para window.open().

Retorna

flash.html:HTMLLoader — Um objeto HTMLLoader que contém a nova página HTML. Tipicamente, você cria um novo objeto HTMLLoader nesse método, adiciona ao palco de um novo objeto NativeWindow e o retorna.

updateLocation

()

método

public function updateLocation(locationURL:String):void

Versões de runtime:

AIR 1.0

A função chamada quando o código JavaScript no objeto HTMLLoader define a propriedade window.location.

Parâmetros

locationURL:String — O valor definido para a propriedade location da propriedade window do objeto HTMLLoader.

updateStatus

()

método

public function updateStatus(status:String):void

Versões de runtime:

AIR 1.0

A função chamada quando o código JavaScript no objeto HTMLLoader define a propriedade window.status.

Parâmetros

status:String — O valor definido para a propriedade status da propriedade window do objeto HTMLLoader.

updateTitle

()

método

public function updateTitle(title:String):void

Versões de runtime:

AIR 1.0

A função chamada quando o código JavaScript no objeto HTMLLoader define a propriedade window.document.title, ou quando o elemento title é alterado, seja via DOM ou devido a uma nova página carregada.

Parâmetros

title:String — O valor definido para a propriedade window.document.title do objeto HTMLLoader.

windowBlur

()

método

public function windowBlur():void

Versões de runtime:

AIR 1.0

A função chamada quando o código JavaScript no objeto HTMLLoader chama o método window.blur().

windowClose

()

método

public function windowClose():void

Versões de runtime:

AIR 1.0

A função chamada quando o código JavaScript no objeto HTMLLoader chama o método window.close().

Por padrão, uma chamada JavaScript para window.close() na página HTML de um objeto HTMLLoader fecha as janelas que contêm o objeto HTMLLoader.

windowFocus

()

método

public function windowFocus():void

Versões de runtime:

AIR 1.0

A função chamada quando o código JavaScript no objeto HTMLLoader chama o método window.focus().

Exemplos Como usar este exemplo

HTMLHost.1.as

O seguinte código define CustomHost, uma subclasse de HTMLHost. Os métodos da classe CustomHost substituem os métodos herdados na classe HTMLHost para definir as ações a serem tomadas quando o código JavaScript na página HTMLLoader definir várias propriedades ou chamar vários métodos de objeto window:

package
{
    import flash.html.HTMLHost;
    import flash.html.HTMLLoader;
    import flash.display.NativeWindow;
    import flash.display.NativeWindowInitOptions;
    import flash.display.StageScaleMode;
    import flash.geom.Rectangle;
    import flash.text.TextField;

    public class CustomHost extends HTMLHost
    {
        import flash.html.*;
        public var statusField:TextField;
        public function CustomHost(defaultBehaviors:Boolean=true)
        {
            super(defaultBehaviors);
        }
        override public function windowClose():void
        {
            htmlLoader.stage.window.close();
        }
        override public function createWindow(windowCreateOptions:HTMLWindowCreateOptions):HTMLLoader
        {
            var initOptions:NativeWindowInitOptions = new NativeWindowInitOptions();
            var window:NativeWindow = new NativeWindow(initOptions);
            window.visible = true;
            var htmlLoader2:HTMLLoader = new HTMLLoader();
            htmlLoader2.width = window.width;
            htmlLoader2.height = window.height;
            window.stage.scaleMode = StageScaleMode.NO_SCALE;
            window.stage.addChild(htmlLoader2);
            return htmlLoader2;
        }
        override public function updateLocation(locationURL:String):void
        {
            trace(locationURL);
        }        
        override public function set windowRect(value:Rectangle):void
        {
            htmlLoader.stage.nativeWindow.bounds = value;
        }
        override public function updateStatus(status:String):void
        {
            statusField.text = status;
        }        
        override public function updateTitle(title:String):void
        {
            htmlLoader.stage.nativeWindow.title = title + "- Example Application";
        }
        override public function windowBlur():void
        {
            htmlLoader.alpha = 0.5;
        }
        override public function windowFocus():void
        {
            htmlLoader.alpha = 1;
        }
    }
}

Crie a seguinte classe, que adiciona um objeto HTMLLoader ao palco, bem como o objeto TextField chamado statusBar. O objeto HTMLLoader define um objeto CustomHost como sua propriedade htmlHost:

package
 {
     import flash.display.Sprite;
 
     public class SimpleHTMLBox extends Sprite
     {
         import flash.html.HTMLHost;
         import flash.html.HTMLLoader;
         import flash.text.TextField;
         import flash.net.URLRequest;
         import CustomHost;
         private var host:CustomHost;
         private var statusField:TextField;
         private var html:HTMLLoader;
         
         public function SimpleHTMLBox()
         {
             html = new HTMLLoader();
             var url:String = "Test.html";
             var urlReq:URLRequest = new URLRequest(url); 
             html.load(urlReq);
             
             host = new CustomHost();
             html.htmlHost = host;
             statusField = new TextField();
             host.statusField = statusField;
             
             configureUI();
         }
         private function configureUI():void
         {
             html.width = 400;
             html.height = 200;
             statusField.width = 400;
             statusField.height = 24;
             statusField.border = true;
             statusField.y = 200;
             
             addChild(html);
             addChild(statusField);                
         }
         
     }
 }

Criar um aplicativo AIR que adiciona um objeto definido por essa classe ao palco da janela principal.

Crie uma página HTML chamada Test.html no diretório de recursos do aplicativo (o diretório que contém o arquivo descritivo do aplicativo), e adicione o seguinte conteúdo nela:

<html>
     <head>
         <title>Test</title>
     </head>
     <body>
         <a href="#" onclick="window.open('Test.html')">window.open('Test.html')</a>
         <br/><a href="#" onclick="window.document.location = 'www.adobe.com'">window.document.location = 'www.adobe.com'</a>
         <br/><a href="#" onclick="window.moveBy(6, 12)">moveBy(6, 12)</a>
         <br/><a href="#" onclick="window.close()">window.close()</a>
         <br/><a href="#" onclick="window.blur()">window.blur()</a>
         <br/><a href="#" onclick="window.focus()">window.focus()</a>
         <br/><a href="#" onclick="window.status = new Date().toString()">window.status = new Date().toString()</a>
     </body>
 </html>

Ao testar o aplicativo, a classe CustomHost lidará com as configurações JavaScript relacionadas à interface do usuário na página HTML.

Aspectos jurídicos | Política de privacidade on-line

HTMLHost - AS3

Classes x

htmlLoader

windowRect

HTMLHost

createWindow

updateLocation

updateStatus

updateTitle

windowBlur

windowClose

windowFocus