ColorMatrixFilter  - AS3

Matriz de 20 itens para uma transformação de cores 4 x 5. A propriedade matrix não pode ser alterada ao modificar diretamente seu valor (por exemplo, myFilter.matrix[2] = 1;). Em vez disso, é necessário obter uma referência para a matriz, fazer a alteração na referência e redefinir o valor.

O filtro da matriz de cor separa cada pixel de origem em seus componentes vermelho, verde, azul e alfa como srcR, srcG, srcB, srcA. Para calcular o resultado de cada um dos quatro canais, o valor de cada pixel na imagem é multiplicado pelos valores na matriz de transformação. Um deslocamento, entre -255 e 255, pode opcionalmente ser adicionado a cada resultado (o quinto item em cada linha da matriz). O filtro combina cada componente de cor em um único pixel e grava o resultado. Na fórmula a seguir, a[0] até a[19] correspondem às entradas 0 a 19 na matriz de 20 itens que é transmitida para a propriedade matrix:

	redResult   = (a[0]  * srcR) + (a[1]  * srcG) + (a[2]  * srcB) + (a[3]  * srcA) + a[4]
	greenResult = (a[5]  * srcR) + (a[6]  * srcG) + (a[7]  * srcB) + (a[8]  * srcA) + a[9]
	blueResult  = (a[10] * srcR) + (a[11] * srcG) + (a[12] * srcB) + (a[13] * srcA) + a[14]
	alphaResult = (a[15] * srcR) + (a[16] * srcG) + (a[17] * srcB) + (a[18] * srcA) + a[19]
	

Para cada valor na matriz, um valor 1 é igual a 100% de cada canal que está sendo despachado para a saída, preservando o valor do canal de cores.

Os cálculos são realizados em valores de cor não calculados. Se o gráfico de entrada consistir em valores de cor recalculados, esses valores serão automaticamente convertidos em valores de cor não calculados para essa operação.

Dois modos otimizados estão disponíveis:

Somente Alfa. Quando você transmite ao filtro uma matriz que se ajusta somente ao componente alfa, conforme mostrado aqui, o filtro otimiza seu desempenho:

	    1 0 0 0 0
	    0 1 0 0 0
	    0 0 1 0 0
	    0 0 0 N 0  (where N is between 0.0 and 1.0)
	

Versão mais rápida. Disponível somente com os processadores compatíveis com o acelerador SSE/AltiVec, como Intel ^® Pentium ^® 3 e posterior e Apple ^® G4 e posterior. O acelerador é usado quando os termos do multiplicador estão na faixa de -15,99 a 15,99 e os termos do somador a[4], a[9], a[14] e a[19] estão na faixa de -8000 a 8000.

Inicializa uma nova ocorrência ColorMatrixFilter com os parâmetros especificados.

Retorna uma cópia deste objeto de filtro.

A função buildChild() cria um novo objeto Loader chamado loader. Para cada chamada para buildChild(), anexe um tratamento de eventos ao objeto Loader para tratar dos eventos complete, que são manipulados pela função passada para buildChild().

As funções applyRed(), applyGreen() e applyBlue() usam diferentes valores para a matriz matrix para obter efeitos diferentes.

Nota: para obter melhores resultados, use uma imagem de aproximadamente 80 pixels de largura. O nome e o local do arquivo de imagem deve corresponder ao valor passado para a propriedade url. Por exemplo, o valor passado para url no exemplo aponta para um arquivo de imagem chamado "Image.jpg" que está no mesmo diretório que seu arquivo SWF.

package {
    import flash.display.DisplayObject;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.filters.ColorMatrixFilter;
    import flash.net.URLRequest;

    public class ColorMatrixFilterExample extends Sprite {
        private var size:uint  = 140;
        private var url:String = "Image.jpg";

        public function ColorMatrixFilterExample() {
            buildChild(null);
            buildChild(applyRed);
            buildChild(applyGreen);
            buildChild(applyBlue);
        }

        private function buildChild(loadHandler:Function):void {
            var loader:Loader = new Loader();
            loader.x = numChildren * size;
            loader.y = size;
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            if (loadHandler != null) {
                loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadHandler);
            }

            var request:URLRequest = new URLRequest(url);
            loader.load(request);
            addChild(loader);
        }

        private function applyRed(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            var matrix:Array = new Array();
            matrix = matrix.concat([1, 0, 0, 0, 0]); // red
            matrix = matrix.concat([0, 0, 0, 0, 0]); // green
            matrix = matrix.concat([0, 0, 0, 0, 0]); // blue
            matrix = matrix.concat([0, 0, 0, 1, 0]); // alpha

            applyFilter(child, matrix);
        }

        private function applyGreen(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            var matrix:Array = new Array();
            matrix = matrix.concat([0, 0, 0, 0, 0]); // red
            matrix = matrix.concat([0, 1, 0, 0, 0]); // green
            matrix = matrix.concat([0, 0, 0, 0, 0]); // blue
            matrix = matrix.concat([0, 0, 0, 1, 0]); // alpha

            applyFilter(child, matrix);
        }

        private function applyBlue(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            var matrix:Array = new Array();
            matrix = matrix.concat([0, 0, 0, 0, 0]); // red
            matrix = matrix.concat([0, 0, 0, 0, 0]); // green
            matrix = matrix.concat([0, 0, 1, 0, 0]); // blue
            matrix = matrix.concat([0, 0, 0, 1, 0]); // alpha

            applyFilter(child, matrix);
        }

        private function applyFilter(child:DisplayObject, matrix:Array):void {
            var filter:ColorMatrixFilter = new ColorMatrixFilter(matrix);
            var filters:Array = new Array();
            filters.push(filter);
            child.filters = filters;
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}