Przykład z klipem filmowym: RuntimeAssetsExplorer

Aby interakcja eksploratora z biblioteka SWF przebiegała prawidłowo, konieczne jest sformalizowanie struktury bibliotek zasobów przeznaczonych do wykorzystania w czasie wykonywania. W tym celu utworzymy interfejs. Interfejs przypomina klasę w tym, że jest szablonem metod wyznaczającym określoną strukturę, jednak w przeciwieństwie do klasy nie zawiera treści metod. Interfejs umożliwia komunikację między biblioteką a eksploratorem w czasie wykonywania. Każdy plik SWF z zasobami ładowany do naszej przeglądarki będzie implementował ten interfejs. Więcej informacji o interfejsach i sposobach ich wykorzystania zawiera sekcja Interfejsy w publikacji Poznajemy język ActionScript 3.0 .

Interfejs RuntimeLibrary będzie bardzo prosty — potrzebna nam jest tylko funkcja udostępniająca eksploratorowi zestaw ścieżek klas symboli, które zostały wyeksportowane i są dostępne w bibliotece. Dlatego interfejs zawiera tylko jedną metodę: getAssets() .

package com.example.programmingas3.runtimeassetexplorer 
{ 
    public interface RuntimeLibrary 
    { 
        function getAssets():Array; 
    } 
}

Zdefiniowanie interfejsu RuntimeLibrary otwiera drogę do utworzenia wielu różnych plików SWF z zasobami. Każdy taki plik będzie można załadować do innego pliku SWF. W celu utworzenia jednego pliku SWF zawierającego bibliotekę zasobów należy wykonać cztery zadania:

• Utworzyć klasę dla pliku SWF z biblioteką zasobów.

• Utworzyć klasy dla poszczególnych zasobów zawartych w bibliotece.

• Utworzyć faktyczne zasoby graficzne.

• Skojarzyć elementy graficzne z klasami i opublikować plik SWF z biblioteką.

package 
{ 
    import flash.display.Sprite; 
    import com.example.programmingas3.runtimeassetexplorer.RuntimeLibrary; 
     
    public class GeometricAssets extends Sprite implements RuntimeLibrary  
    { 
        public function GeometricAssets() { 
             
        } 
        public function getAssets():Array { 
            return [ "com.example.programmingas3.runtimeassetexplorer.AnimatingBox", 
                     "com.example.programmingas3.runtimeassetexplorer.AnimatingStar" ];     
        } 
    } 
}

package com.example.programmingas3.runtimeassetexplorer 
{ 
    import flash.display.MovieClip; 
     
    public class AnimatingStar extends MovieClip 
    { 
        public function AnimatingStar() { 
        } 
    } 
}

Ostatnim elementem funkcjonalnym, jakim musimy się zająć, jest interfejs eksploratora zasobów. W tym przykładzie ścieżka do biblioteki ładowanej w czasie wykonywania jest zakodowana na stałe w zmiennej o nazwie ASSETS_PATH . Zamiast tego moglibyśmy jednak użyć klasy FileReference — np. w celu utworzenia interfejsu pozwalającego użytkownikowi na wybranie konkretnego pliku SWF na dysku twardym.

Po pomyślnym załadowaniu biblioteki program Flash Player wywołuje metodę runtimeAssetsLoadComplete() :

private function runtimeAssetsLoadComplete(event:Event):void 
{ 
    var rl:* = event.target.content; 
    var assetList:Array = rl.getAssets(); 
    populateDropdown(assetList); 
    stage.frameRate = 60; 
}

W tej metodzie zmienna rl reprezentuje załadowany plik SWF. Kod wywołuje metodę getAssets() załadowanego pliku SWF, uzyskując w ten sposób listę dostępnych zasobów i na podstawie tej listy wypełnia składnik ComboBox, wywołując metodę populateDropDown() . Z kolei ta metoda zapisuje pełne ścieżki klas poszczególnych zasobów. Kliknięcie przycisku Add w interfejsie użytkownika wywołuje metodę addAsset() :

private function addAsset():void 
{ 
    var className:String = assetNameCbo.selectedItem.data; 
    var AssetClass:Class = getDefinitionByName(className) as Class; 
    var mc:MovieClip = new AssetClass(); 
    ... 
}

Metoda ta pobiera ścieżkę klas zasobu wybranego w danej chwili w składniku ComboBox ( assetNameCbo.selectedItem.data ) i wywołuje funkcję getDefinitionByName() (z pakietu flash.utils) w celu uzyskania rzeczywistego odwołania do zasobu klasy w celu utworzenia nowej instancji tego zasobu.