JSON  - AS3

Przyjmuje ciąg w formacie JSON i zwraca obiekt ActionScript reprezentujący wprowadzoną wartość. Obiekty, tablice, ciągi, liczby, operatory logiczne i odwzorowania wartości null w formacie JSON odpowiadające wartościom ActionScript przedstawiono poniżej:

Parametr reviver jest funkcją, która pobiera dwa parametry: klucz i wartość. Funkcji tej można używać do przekształcania lub filtrowania każdej pary klucz-wartość podczas jej analizowania. Zastosowanie funkcji reviver powoduje, że funkcja parse() zwraca przekształconą lub przefiltrowaną wartość dla każdej pary zamiast domyślnego produktu analizy. Jeżeli funkcja reviver zwraca właściwość undefined dla dowolnej z par, właściwość ta jest usuwana z wyniku końcowego.

Jeśli argument przekazany do parametru reviver nie jest funkcją, kod ActionScript generuje wyjątek TypeError z identyfikatorem błędu kJSONInvalidReviver. Jest również publikowany zlokalizowany komunikat o błędzie.

Jeśli funkcja parse() napotka klucz powielony w obrębie obiektu, wartość dla wszystkich wystąpień klucza zostanie określona na podstawie ostatniego napotkanego wystąpienia klucza.

Parametry

Zwraca ciąg w formacie JSON reprezentujący wartość ActionScript. Metoda stringify może pobierać trzy parametry.

Parametr value jest wymagany. Ten parametr to wartość ActionScript. Zwykle jest to obiekt lub tablica, ale może to być również ciąg, operator logiczny, liczba lub wartość null.

Opcjonalny parametr replacer może być funkcją lub tablicą ciągów albo liczb. Jeśli jest funkcją, pobiera ona dwa parametry: klucz i wartość. Funkcji tej można używać do przekształcania lub filtrowania każdej pary klucz-wartość podczas jej analizowania. Zastosowanie funkcji replacer powoduje, że funkcja parse() zwraca przekształconą lub przefiltrowaną wartość dla każdej pary zamiast domyślnego produktu analizy. Jeżeli funkcja replacer zwraca właściwość undefined dla dowolnej z par, właściwość ta jest usuwana z wyniku końcowego. Jeśli funkcja replacer jest tablicą, jest używana jako filtr do określania, które właściwości są uwzględniane w danych wyjściowych.

Jeśli argument przekazany do parametru replacer nie jest ani tablicą ani funkcją, kod ActionScript generuje wyjątek TypeError z identyfikatorem błędu kJSONInvalidReplacer. Jest również publikowany zlokalizowany komunikat o błędzie.

Opcjonalny parametr space jest ciągiem lub liczbą i umożliwia wstawienie odstępu do zwracanego ciągu w celu zwiększenia jego czytelności dla użytkownika. Wpisy w wygenerowanych obiektach JSON i tablicach JSON są oddzielone odstępem określanym przez parametr space. Wielkość tego odstępu przyjmuje zawsze wartość z przedziału od 0 do 10 znaków. Jeśli parametr space jest ciągiem, określany przez niego odstęp składa się z pierwszych dziesięciu znaków tego ciągu. Jeśli parametr space jest liczbą nieujemną x, odstęp składa się z x (ale maksymalnie dziesięciu) znaków spacji. Jeśli argument przekazany do parametru space nie jest ani ciągiem, ani liczbą, jest konwertowany na ciąg i używany jako odstęp w danych wyjściowych. Następnie wykonywanie kodu jest kontynuowane.

Jeśli metoda stringify() napotka strukturę cykliczną, generuje wyjątek TypeError z identyfikatorem błędu kJSONCyclicStructure. Jest również publikowany zlokalizowany komunikat o błędzie.

Parametry

1. Kontruktor klasy JSONExample przypisuje ciąg do elementu text klasy nadrzędnej i inicjuje licznik wewnętrzny.
2. Oprócz tego klasa ta definiuje tablicę, która może zawierać obiekty JSONExample wyeksportowane do formatu JSON.
3. Klasa JSONExample definiuje także metody toJSON() i revive(). W metodzie JSON.stringify() metoda toJSON() jest wywoływana w celu przeprowadzenia serializacji obiektów JSONExample do formatu JSON. Metoda revive() może być wywoływana w metodach JSON.parse() w celu przywrócenia pełnego obiektu JSONExample. To przywrócenie jest realizowane przy użyciu określonego identyfikatora, który pozwala pobrać oryginalny obiekt z tablicy obiektów możliwych do przywrócenia.
4. Skrypt używający definicji klasy tworzy obiekt zawierający dwa obiekty TextField i jeden obiekt JSONExample. Tworzy również tablicę obiektów możliwych do przywrócenia, w której są przechowywane obiekty TextField wyeksportowane do formatu JSON.
5. Funkcja replacer metody JSON.stringify() odfiltrowuje obiekty TextField z ciągu JSON. W miejsce każdego usuniętego obiektu funkcja replacer wstawia znacznik z identyfikatorem pozwalającym przywrócić obiekt w przyszłości. Obiekty JSONExample przechodzą przez filtr zgodnie z ich natywnym kodowaniem JSON.
6. Funkcja reviver metody parse() odtwarza pierwotny obiekt przez przywrócenie wszystkich obiektów TextField i JSONExample, do których istnieją odniesienia.

 
 package {
    import flash.text.TextField;
    public class JSONExample extends TextField
    {
        static var nextId = 10000;
        static var revivable_objects:Array = [];
            public var id;

        public function JSONExample(s:String){
            super.text = s;
            id = ++nextId;
        }
        public function toJSON(k):*
        {
            // To be called internally by the JSON.stringify() method.
            // Save the original object internally.
            // Write out only a generated ID and the text value.
            revivable_objects[id] = this;
            return {"classJSONExample":{"reviveId":id,"contents":this.text}};
        }
        public static function revive(id:int):JSONExample
        {
            // For explicit use in the JSON.parse() method.
            // Revives the object using the ID obtained from the JSON string.
            return revivable_objects[id];
        }
    }
}

import flash.text.TextField;

var lastId = 20000;
var tf1:TextField = new TextField();
tf1.text = "Lorem ipsum";
var tf2:TextField = new TextField();
tf2.text = "Laughing cows";
var nt:JSONExample = new JSONExample("It was the best of times; it was the worst of times.");

var obj:Object = {a:tf1, b:nt, c:tf2};
var revivable_objects:Array = new Array();

var json_out = JSON.stringify(obj, function(k,v){
        if (v is JSONExample)
        {
            // Send JSONExample objects to the JSON output.
            // Note that stringify() calls JSONExample.toJSON() to serialize this object.
            return v;
        }
        if (v is TextField)
        {
            // Remove TextField objects from the JSON output.
            // Save the original object for reviving later.
            // Return a new object containing an identification marker
            // and the original object's revival ID.
            revivable_objects[++lastId] = v;
            return {"classTextField":{"reviveId":lastId}};
        }
        return v;
    }
);
               
trace("json_out: " + json_out);

var json_in = JSON.parse(json_out, function(k,v) {
        if ("classTextField" in v) { // special marker tag from stringify() replacer code
            // Retrieve the original object based on the ID stored in the stringify() replacer function.
            var id = v["classTextField"].reviveId;
            return revivable_objects[id];
        } else if ("classJSONExample" in v){
            // Retrieve the original object based on the ID generated in JSONExample.toJSON().
            return JSONExample.revive(v["classJSONExample"].reviveId);
        }
        return v;
    }
);

if (json_in.a)
{
    if (json_in.a.hasOwnProperty("text"))
        {
            trace("json_in.a: " + json_in.a.text);
        }
}
if (json_in.b)
{
    if (json_in.b.hasOwnProperty("text"))
        {
            trace("json_in.b: " + json_in.b.text);
        }
}

if (json_in.c)
{
    if (json_in.c.hasOwnProperty("text"))
        {
            trace("json_in.c: " + json_in.c.text);
        }
}