Werken met objecten

Een eigenschap vertegenwoordigt één van de gegevens die zijn samengebracht in een object. Een Songobject heeft bijvoorbeeld de eigenschappen artist en title . De klasse MovieClip kan eigenschappen als rotation , x , width en alpha hebben. Eigenschappen worden als individuele variabelen behandeld. Een andere manier om eigenschappen te omschrijven is als de 'onderliggende' variabelen in een object.

Hieronder volgen enkele voorbeelden van ActionScript-code waarin gebruik wordt gemaakt van eigenschappen. De volgende coderegel verplaatst de MovieClip met de naam square naar 100 pixels op de x-coördinaat:

square.x = 100;

De volgende code gebruikt de eigenschap rotation om de MovieClip square te roteren zodat de rotatie gelijk wordt aan die van de MovieClip triangle :

square.rotation = triangle.rotation;

De volgende code wijzigt de horizontale schaal van de MovieClip square zodat deze anderhalf keer breder wordt:

square.scaleX = 1.5;

Let op de gemeenschappelijke structuur: u gebruikt een variabele ( square , triangle ) als naam van het object, gevolgd door een punt ( . ) en vervolgens de naam van de eigenschap ( x , rotation , scaleX ). De punt, die puntoperator wordt genoemd, wordt gebruikt om aan te geven dat u een van de onderliggende elementen van een object benadert. De gehele structuur samen, ‘variabelenaam-punt-eigenschapnaam’, wordt gebruikt als een enkele variabele, dus als een naam voor een enkele waarde in het computergeheugen.

Een methode is een actie die door een object kan worden uitgevoerd. U hebt bijvoorbeeld een filmclipsymbool gemaakt in Flash Professional met op de tijdslijn meerdere hoofdframes en animatie. Deze filmclip kan worden afgespeeld of gestopt of kan worden verteld om de afspeelkop naar een bepaald frame te verplaatsen.

De volgende coderegel zorgt ervoor dat de MovieClip met de naam shortFilm begint met afspelen:

shortFilm.play();

De volgende coderegel zorgt ervoor dat de MovieClip met de naam shortFilm stopt met afspelen (de afspeelkop blijft op zijn plaats, zoals bij het pauzeren van een video):

shortFilm.stop();

De volgende coderegel zorgt ervoor dat de afspeelkop van de MovieClip met de naam shortFilm wordt verplaatst naar frame 1 en stopt met afspelen (zoals bij het terugspoelen van een video):

shortFilm.gotoAndStop(1);

Methoden worden, net zoals eigenschappen, benaderd door de naam van het object (een variabele) te schrijven, gevolgd door een punt en de naam van de methode met haakjes erachter. Met de haakjes geeft u aan dat u de methode aanroept , met andere woorden, het object de instructie geeft een bepaalde handeling uit te voeren. Soms worden waarden (of variabelen) tussen haakjes geplaatst om aanvullende informatie door te geven die nodig is om de handeling uit te voeren. Deze waarden worden de parameters van een methode genoemd. De methode gotoAndStop() moet bijvoorbeeld weten naar welk frame moet worden gegaan en heeft dus een enkele parameter tussen de haakjes nodig. Andere methoden, zoals play() en stop() behoeven geen uitleg en hebben dus geen aanvullende informatie nodig. Deze methoden worden echter wel met haakjes geschreven.

In tegenstelling tot eigenschappen (en variabelen), worden methoden niet gebruikt als plaatsaanduidingen voor waarden. Sommige methoden kunnen echter berekeningen uitvoeren en een resultaat retourneren dat kan worden gebruikt als een variabele. De methode toString() van de klasse Number zet bijvoorbeeld een numerieke waarde om in de bijbehorende tekstrepresentatie:

var numericData:Number = 9; 
var textData:String = numericData.toString();

U kunt de methode toString() bijvoorbeeld gebruiken wanneer u de waarde van een variabele Getal wilt weergeven in een tekstveld op het scherm. De eigenschap text van de klasse TextField wordt gedefinieerd als een String, zodat deze alleen tekstwaarden kan bevatten. (De tekst property vertegenwoordigt de werkelijke tekstinhoud die op het scherm wordt weergegeven.) Deze coderegel zet de numerieke waarde in de variabele numericData om in tekst. De waarde wordt vervolgens weergegeven op het venster in het TextField-object calculatorDisplay :

calculatorDisplay.text = numericData.toString();

Hierboven is een computerprogramma beschreven als een serie instructies die de computer stapsgewijs uitvoert. Sommige eenvoudige computerprogramma’s bestaan inderdaad uit niets meer dan dat: een paar stappen die worden uitgevoerd door de computer, waarna het programma stopt. ActionScript-programma’s zijn echter ontworpen om continu te worden uitgevoerd, terwijl wordt gewacht op gebruikersinvoer of iets anders. Gebeurtenissen vormen het mechanisme waarmee wordt bepaald welke instructies de computer uitvoert en wanneer.

In wezen is een gebeurtenis een voorval dat bekend is bij ActionScript en waarop gereageerd kan worden. Veel gebeurtenissen zijn gerelateerd aan gebruikersinteractie, zoals een gebruiker die op een knop klikt of op een toets op het toetsenbord drukt. Er zijn ook andere gebeurtenistypen. Wanneer u ActionScript bijvoorbeeld gebruikt om een externe afbeelding te laden, bestaat er een gebeurtenis die u kan waarschuwen wanneer de afbeelding is geladen. Wanneer er een ActionScript-programma wordt uitgevoerd, wacht het eigenlijk tot er een aantal dingen gebeuren. Wanneer die dingen gebeuren, wordt de ActionScript-code uitgevoerd, die u voor die gebeurtenissen hebt opgegeven.

function eventResponse(eventObject:EventType):void 
{ 
    // Actions performed in response to the event go here. 
} 
  
eventSource.addEventListener(EventType.EVENT_NAME, eventResponse);

function eventResponse(event:MouseEvent):void 
{ 
    // Actions performed in response to the event go here. 
} 
 
myButton.addEventListener(MouseEvent.CLICK, eventResponse);

Voordat u een object kunt gebruiken in ActionScript, moet dit object uiteraard wel eerst bestaan. Een onderdeel van het maken van een object is het declareren van een variabele. Hiermee wordt echter alleen een lege plaats in het computergeheugen gemaakt. Voordat u een variabele kunt gebruiken of manipuleren, moet u er een werkelijke waarde aan toekennen (dat wil zeggen, een object maken en dit in de variabele opslaan). Het proces om een object te maken wordt ook wel het instantiëren van het object genoemd. U maakt met andere woorden een instantie van een bepaalde klasse.

Een eenvoudige manier om een objectinstantie te maken is zonder ActionScript. Plaats in Flash Professional een filmclipsymbool, knopsymbool of tekstveld op het werkgebied en wijs er een instantienaam aan toe. Flash professional declareert automatisch een variabele met die instantienaam, maakt een objectinstantie en slaat dat object in een variabele op. In Flex kunt u een component in MXML maken, door een MXML-tag te coderen of het component op de editor in de modus Flash Builder Design te plaatsen. Wanneer u aan dat component een id toewijst, wordt die id de naam van een ActionScript-variabele met een componentinstantie.

U wilt echter een object misschien niet altijd visueel maken en dit is niet mogelijk voor niet-visuele objecten. Er zijn verschillende andere manieren waarop u alleen met ActionScript objectinstanties kunt maken.

Allereerst kunt u voor verschillende gegevenstypen in ActionScript een instantie maken met behulp van een letterlijke expressie . Dit is een waarde die rechtstreeks in de ActionScript-code wordt geschreven. Hieronder volgen enkele voorbeelden:

• Letterlijke numerieke waarde (voer het getal rechtstreeks in):

  var someNumber:Number = 17.239; 
  var someNegativeInteger:int = -53; 
  var someUint:uint = 22;

• Letterlijke tekenreekswaarde (plaats dubbele aanhalingtekens rond de tekst):

  var firstName:String = "George"; 
  var soliloquy:String = "To be or not to be, that is the question...";

• Letterlijke Booleaanse waarde (gebruik de letterlijke waarden true of false ):

  var niceWeather:Boolean = true; 
  var playingOutside:Boolean = false;

• Letterlijke arraywaarde (laat een door komma's gescheiden lijst met waarden teruglopen in vierkante haken):

  var seasons:Array = ["spring", "summer", "autumn", "winter"];

• Letterlijke XML-waarde (voer de XML rechtstreeks in):

  var employee:XML = <employee> 
          <firstName>Harold</firstName> 
          <lastName>Webster</lastName> 
      </employee>;

In ActionScript zijn ook letterlijke expressies gedefinieerd voor de gegevenstypen Array, RegExp, Object en Function.

De meest algemene manier om voor elk gegevenstype een instantie te maken is met behulp van de operator new met de klassenaam, zoals hier wordt weergegeven:

var raceCar:MovieClip = new MovieClip(); 
var birthday:Date = new Date(2006, 7, 9);

Het maken van een object met behulp van de operator new wordt doorgaans het ‘aanroepen van de klassenconstructor’ genoemd. Een constructor is een speciale methode die wordt aangeroepen tijdens het proces waarin een instantie van een klasse wordt gemaakt. Wanneer u op deze manier een instantie maakt, moet u erop letten dat u na de klassenaam een haakje plaatst. Soms geeft u tussen deze haakjes parameterwaarden op. Dit zijn twee dingen die u ook doet wanneer u een methode oproept.

Zelfs bij gegevenstypen waarvoor u instanties kunt maken met behulp van een literale expressie, kunt u de operator new gebruiken om een objectinstantie te maken. De volgende twee coderegels doen bijvoorbeeld precies hetzelfde:

var someNumber:Number = 6.33; 
var someNumber:Number = new Number(6.33);

Het is van belang dat u bekend met de manier new ClassName () om objecten te maken. Veel ActionScript-gegevenstypen worden niet visueel weergegeven. U kunt ze niet maken door een item in het werkgebied van Flash Professional, de ontwerpmodus of de MXML-editor van Flash Builder te plaatsen. U kunt in ActionScript van een van deze gegevenstypen alleen een instantie maken met de operator new .