Tekstinvoer vastleggen

Flash Player 9 of hoger, Adobe AIR 1.0 of hoger

De eigenschap type van een tekstveld is standaard ingesteld op dynamic . Als u de eigenschap type instelt op input met de klasse TextFieldType, kunt u invoer van de gebruiker verzamelen en de waarde opslaan om te worden gebruikt in andere delen van de toepassing. Invoertekstvelden zijn handig voor formulieren en alle toepassingen waarbij de gebruiker een tekstwaarde moet definiëren om elders in het programma te worden gebruikt.

De volgende code maakt bijvoorbeeld een invoertekstveld met de naam myTextBox . Wanneer de gebruiker tekst in het veld invoert, wordt de gebeurtenis textInput geactiveerd. Een gebeurtenishandler met de naam textInputCapture legt de tekstreeks die wordt ingevoerd vast en wijst daaraan een variabele toe. Flash Player of AIR geeft de nieuwe tekst in een ander tekstveld met de naam myOutputBox weer.

package 
{ 
    import flash.display.Sprite; 
    import flash.display.Stage; 
    import flash.text.*; 
    import flash.events.*; 
 
    public class CaptureUserInput extends Sprite 
    { 
        private var myTextBox:TextField = new TextField(); 
        private var myOutputBox:TextField = new TextField(); 
        private var myText:String = "Type your text here."; 
 
        public function CaptureUserInput() 
        { 
            captureText(); 
        } 
         
        public function captureText():void 
        { 
            myTextBox.type = TextFieldType.INPUT; 
            myTextBox.background = true; 
            addChild(myTextBox); 
            myTextBox.text = myText; 
            myTextBox.addEventListener(TextEvent.TEXT_INPUT, textInputCapture); 
        } 
         
        public function textInputCapture(event:TextEvent):void 
        { 
            var str:String = myTextBox.text; 
            createOutputBox(str); 
        } 
             
        public function createOutputBox(str:String):void 
        { 
            myOutputBox.background = true; 
            myOutputBox.x = 200; 
            addChild(myOutputBox); 
            myOutputBox.text = str; 
        } 
         
    } 
}