Ondersteuning voor de uitsleepbeweging

Om gegevens of een object voor te bereiden op slepen, maakt u een Clipboard-object en voegt u de gegevens die moeten worden overgebracht toe in een of meer indelingen. U kunt de standaardgegevensindelingen gebruiken voor het doorgeven van gegevens die automatisch kunnen worden omgezet in eigen klembordindelingen en toepassingsspecifieke indelingen gebruiken voor het doorgeven van objecten.

Als het een grote belasting voor de processor is om de gegevens die moeten worden overgebracht, te converteren naar een bepaalde indeling, kunt u de naam opgeven van een handlerfunctie die de conversie uitvoert. Deze functie wordt alleen opgeroepen als de ontvangende component of toepassing de bijbehorende indeling leest.

Zie Klembordgegevensindelingen voor meer informatie over de indelingen voor klembordgegevens.

In het volgende voorbeeld wordt een Clipboard-object gemaakt dat een bitmap in diverse indelingen bevat: een bitmapobject, een native bitmapindeling en een bestandenlijstindeling die het bestand bevat waaruit de bitmap oorspronkelijk is geladen:

import flash.desktop.Clipboard; 
import flash.display.Bitmap; 
import flash.filesystem.File; 
public function createClipboard(image:Bitmap, sourceFile:File):Clipboard{ 
    var transfer:Clipboard = new Clipboard(); 
    transfer.setData("CUSTOM_BITMAP", image, true); //Flash object by value and by reference 
    transfer.setData(ClipboardFormats.BITMAP_FORMAT, image.bitmapData, false); 
    transfer.setData(ClipboardFormats.FILE_LIST_FORMAT, new Array(sourceFile), false); 
    return transfer; 
}

Om een sleepbewerking te starten, roept u de methode NativeDragManager.doDrag() op als reactie op het indrukken van de muis. De methode doDrag() is een statische methode met de volgende parameters:

In het volgende voorbeeld ziet u hoe u een sleepbewerking start voor een bitmapobject dat uit een bestand is geladen. In het voorbeeld wordt een afbeelding geladen en wordt de sleepbewerking gestart bij de gebeurtenis mouseDown .

package 
{ 
import flash.desktop.NativeDragManager; 
import mx.core.UIComponent; 
import flash.display.Sprite; 
import flash.display.Loader; 
import flash.system.LoaderContext; 
import flash.net.URLRequest; 
import flash.geom.Point; 
import flash.desktop.Clipboard; 
import flash.display.Bitmap; 
import flash.filesystem.File; 
import flash.events.Event; 
import flash.events.MouseEvent; 
 
public class DragOutExample extends UIComponent Sprite { 
    protected var fileURL:String = "app:/image.jpg"; 
    protected var display:Bitmap; 
 
    private function init():void { 
        loadImage(); 
    } 
    private function onMouseDown(event:MouseEvent):void { 
        var bitmapFile:File = new File(fileURL); 
        var transferObject:Clipboard = createClipboard(display, bitmapFile); 
        NativeDragManager.doDrag(this,  
                            transferObject, 
                            display.bitmapData, 
                            new Point(-mouseX,-mouseY)); 
    } 
    public function createClipboard(image:Bitmap, sourceFile:File):Clipboard { 
        var transfer:Clipboard = new Clipboard(); 
        transfer.setData("bitmap",  
                            image,  
                            true);  
                            // ActionScript 3 Bitmap object by value and by reference 
        transfer.setData(ClipboardFormats.BITMAP_FORMAT,  
                            image.bitmapData,  
                            false);  
                            // Standard BitmapData format 
        transfer.setData(ClipboardFormats.FILE_LIST_FORMAT,  
                            new Array(sourceFile),  
                            false);  
                            // Standard file list format 
        return transfer;  
    } 
    private function loadImage():void { 
        var url:URLRequest = new URLRequest(fileURL); 
        var loader:Loader = new Loader(); 
        loader.load(url,new LoaderContext()); 
        loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onLoadComplete);       
    } 
    private function onLoadComplete(event:Event):void { 
        display = event.target.loader.content; 
        var flexWrapper:UIComponent = new UIComponent(); 
        flexWrapper.addChild(event.target.loader.content); 
        addChild(flexWrapper); 
        flexWrapper.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown); 
    } 
} 
}

Wanneer een gebruiker het gesleepte item neerzet door de muisknop los te laten, verzendt het initiatorobject de gebeurtenis nativeDragComplete . U kunt de eigenschap dropAction van het gebeurtenisobject controleren en vervolgens de juiste actie uitvoeren. Als de actie bijvoorbeeld NativeDragAction.MOVE, is, kunt u het bronitem op de bronlocatie verwijderen. De gebruiker kan een sleepbeweging annuleren door de muisknop los te laten terwijl de cursor zich buiten een geschikt neerzetdoel bevindt. De sleepbeheerder stelt de eigenschap dropAction voor een geannuleerde beweging in op NativeDragAction.NONE .