QName

패키지	최상위 레벨
클래스	public final class QName
상속	QName Object

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9, Flash Lite 4

QName 객체는 XML 요소 및 특성의 정규화된 이름을 나타냅니다. 각 QName 객체에는 로컬 이름과 네임스페이스 URI(Uniform Resource Identifier)가 있습니다. 네임스페이스 URI의 값이 null인 경우 QName 객체는 모든 네임스페이스와 일치합니다. Namespace 객체의 uri 및 QName 객체의 localName을 사용하여 다른 QName 객체의 복사본 또는 새 QName 객체를 만들려면 QName 생성자를 사용합니다.

E4X 전용 메서드에서는 문자열과 QName 객체를 서로 바꾸어 사용할 수 있습니다. E4X 메서드는 QName, Namespace, XML 및 XMLList 클래스에서 제공합니다. 이러한 E4X 메서드에는 문자열과 QName 객체를 모두 사용할 수 있습니다. 이러한 상호 교환성으로 인해 네임스페이스에서 XML.child() 등의 메서드를 사용할 수 있습니다.

QName 클래스는 XML, XMLList 및 Namespace 클래스와 더불어 E4X(ECMAScript for XML) 사양(ECMA-357 버전 2)에 정의된 강력한 XML 처리 표준을 구현합니다.

정규화된 식별자는 QName 객체로 평가됩니다. 네임스페이스를 식별하지 않고 XML 요소의 QName 객체를 지정하면 관련 QName 객체의 uri 속성이 전역 기본 네임스페이스로 설정됩니다. 네임스페이스를 식별하지 않고 XML 특성의 QName 객체를 지정하면 uri 속성이 빈 문자열로 설정됩니다.

예제 보기

추가 정보

ECMAScript for XML (E4X) specification (ECMA-357 edition 2)

	속성	정의 주체
		constructor : Object 지정된 객체 인스턴스의 클래스 객체 또는 생성자 함수에 대한 참조입니다.	Object
		localName : String [읽기 전용] QName 객체의 로컬 이름입니다.	QName
		uri : String [읽기 전용] QName 객체의 URI(Uniform Resource Identifier)입니다.	QName

	메서드	정의 주체
		QName(qname:QName) 다른 QName 객체의 복사본인 QName 객체를 만듭니다.	QName
		QName(uri:Namespace, localName:QName) Namespace 객체의 URI와 QName 객체의 localName을 사용하여 QName 객체를 만듭니다.	QName
		hasOwnProperty(name:String):Boolean 지정된 속성이 객체에 정의되어 있는지 여부를 나타냅니다.	Object
		isPrototypeOf(theClass:Object):Boolean Object 클래스의 인스턴스가 매개 변수로 지정된 객체의 프로토타입 체인에 있는지 여부를 나타냅니다.	Object
		propertyIsEnumerable(name:String):Boolean 지정된 속성이 존재하고 열거 가능한지 여부를 나타냅니다.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 루프 작업에서 동적 속성을 사용할 수 있는지 여부를 설정합니다.	Object
		toLocaleString():String 로캘별 규칙에 따라 서식이 지정된 이 객체의 문자열 표현을 반환합니다.	Object
		toString():String URI와 QName 객체의 로컬 이름이 "::"으로 구분되어 구성된 문자열을 반환합니다.	QName
		valueOf():QName QName 객체를 반환합니다.	QName

localName

속성

localName:String [읽기 전용]

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9

QName 객체의 로컬 이름입니다.

구현
public function get localName():String

uri

속성

uri:String [읽기 전용]

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9

QName 객체의 URI(Uniform Resource Identifier)입니다.

구현
public function get uri():String

생성자 세부 정보

()

생성자

public function QName(qname:QName)

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9

다른 QName 객체의 복사본인 QName 객체를 만듭니다. 생성자에 전달된 매개 변수가 QName 객체이면 QName 객체의 복사본이 만들어집니다. 매개 변수가 QName 객체가 아니면 매개 변수가 문자열로 변환되어 새 QName 인스턴스의 localName 속성에 할당됩니다. 매개 변수가 undefined이거나 지정되지 않은 경우에는 localName 속성이 빈 문자열로 설정된 새 QName 객체가 만들어집니다.

참고: 이 클래스에는 서로 다른 매개 변수를 받는 두 가지 형태의 생성자 항목이 있습니다. 생성자는 전달된 매개 변수의 유형과 개수에 따라 각 항목에서 설명하는 대로 다르게 동작합니다. ActionScript 3.0에서는 메서드 또는 생성자 오버로드가 지원되지 않습니다.

매개 변수

qname:QName — 복사할 QName 객체입니다. 다른 모든 유형의 객체는 문자열로 변환되어 새 QName 객체의 localName 속성에 할당됩니다.

QName

()

생성자

public function QName(uri:Namespace, localName:QName)

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9

Namespace 객체의 URI와 QName 객체의 localName을 사용하여 QName 객체를 만듭니다. 매개 변수의 데이터 유형이 예상과 다르면 매개 변수가 문자열로 변환되어 새 QName 객체의 해당 속성에 할당됩니다. 예를 들어 두 매개 변수가 모두 문자열이면 반환되는 새 QName 객체의 uri 속성은 첫 번째 매개 변수로, localName 속성은 두 번째 매개 변수로 설정됩니다. 즉, 다음을 비롯한 여러 가지 조합을 생성자에 사용할 수 있습니다.

QName (uri:Namespace, localName:String);
QName (uri:String, localName: QName);
QName (uri:String, localName: String);

uri 매개 변수에 null을 전달하면 새 QName 객체의 uri 속성이 null로 설정됩니다.

매개 변수

	`uri:Namespace` — `uri` 값을 복사할 원본 Namespace 객체입니다. 다른 유형의 매개 변수는 문자열로 변환됩니다.

	`localName:QName` — `localName` 값을 복사할 원본 QName 객체입니다. 다른 유형의 매개 변수는 문자열로 변환됩니다.

메서드 세부 정보

toString

()

메서드

AS3 function toString():String

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9

URI와 QName 객체의 로컬 이름이 "::"으로 구분되어 구성된 문자열을 반환합니다.

문자열의 형식은 QName 객체의 uri 속성에 따라 다릅니다.

If uri == "" 
		toString returns localName
	else if uri == null
		toString returns *::localName 
	else
		toString returns uri::localName

반환값

String — 정규화된 이름을 나타내는 문자열입니다.

valueOf

()

메서드

AS3 function valueOf():QName

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9

QName 객체를 반환합니다.

반환값

QName — QName 인스턴스의 프리미티브 값입니다.

예제 예제 사용 방법

QNameExample.as

다음 예제에서는 QName 인스턴스를 만든 후 이 인스턴스를 사용하여 XML 요소를 선택하는 방법을 보여 줍니다. 여기에는 QName을 만드는 두 가지 방법이 나와 있습니다.

Namespace 인스턴스를 만든 다음 QName 생성자에 대한 입력으로 사용합니다. 이 방법은 Namespace.prefix 속성을 나중에 다른 용도로 사용하려는 경우에 적합합니다.
QName 생성자의 uri 매개 변수에 간단한 문자열 값을 사용하여 QName 인스턴스를 만듭니다.

이 코드는 다음과 같은 작업을 수행합니다.

rssXML이라는 XML 변수를 정의합니다.
접두어 dc를 사용하여 새 Namespace 객체를 만듭니다.
Namespace 객체와 로컬 이름 creator를 사용하여 새 QName 객체를 만듭니다.
showDescendants() 메서드를 호출합니다. 이 메서드는 XML.descendants() 메서드를 사용하여 정규화된 이름이 지정된 QName 인스턴스와 일치하는 모든 자손 요소가 포함된 XMLList 인스턴스를 가져옵니다.
for each 루프를 사용하여 목록에 있는 각 요소의 정규화된 이름과 텍스트 값을 표시합니다.
uri 매개 변수의 문자열 값과 로컬 이름 date를 사용하여 다른 QName 객체를 만듭니다.
showDescendants() 메서드를 다시 호출하여 자손 요소의 이름과 텍스트 값을 표시합니다.

package
{
    import flash.display.Sprite;
    
    public class QNameExample extends Sprite
    {
        public function QNameExample()
        {
            var rssXML:XML =  <rdf:RDF
              xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
              xmlns="http://purl.org/rss/1.0/"
              xmlns:dc="http://purl.org/dc/elements/1.1/">
              <channel rdf:about="http://www.xml.com/cs/xml/query/q/19">
                <title>Test RSS</title>
                <link>http://www.adobe.com/</link>
                <description>This is a test RSS document.</description>
                <language>en-us</language>
                <items>
                  <rdf:Seq>
                <rdf:li rdf:resource="http://www.adobe.com/devnet/flash/"/>
                <rdf:li rdf:resource="http://www.adobe.com/devnet/flex/"/>
                  </rdf:Seq>
                </items>
              </channel>
              <item rdf:about="http://www.adobe.com/devnet/flash/">
                <title>Flash Developer Center</title>
                <link>http://www.adobe.com/devnet/flash/</link>
                <description>Welcome to the Flash Developer Center</description>
                <dc:creator>Adobe</dc:creator>
                <dc:date>2005-08-08</dc:date>    
              </item>
              <item rdf:about="http://www.adobe.com/devnet/flex/">
                <title>Flex Developer Center</title>
                <link>http://www.adobe.com/devnet/flex/</link>
                <description>Welcome to the Flex Developer Center</description>
                <dc:creator>Adobe</dc:creator>
                <dc:date>2005-10-16</dc:date>    
              </item>
            </rdf:RDF>;
            
            var dcNamespace:Namespace = new Namespace("dc", "http://purl.org/dc/elements/1.1/");
            var creatorQName:QName = new QName(dcNamespace, "creator");
            trace(creatorQName.uri); // http://purl.org/dc/elements/1.1/
            trace(creatorQName.localName); // creator
            
            showDescendants(rssXML, creatorQName);
            
            var dateQName:QName = new QName("http://purl.org/dc/elements/1.1/", "date");
            trace(dateQName.uri); // http://purl.org/dc/elements/1.1/
            trace(dateQName.localName); // date
            
            showDescendants(rssXML, dateQName);
        }
        
        public function showDescendants(xmlData:XML, qualifiedName:QName):void
        {
            var decendantList:XMLList = xmlData.descendants(qualifiedName);
            
            for each (var element:XML in decendantList)
            {
                trace(element.name()); // the fully qualified name, 
                                       // like "http://purl.org/dc/elements/1.1/::creator"
                trace(element); // the simple text value of each element, like "Adobe"
            }                
        }
    }
}

법적 고지 사항 | 온라인 개인 정보 보호 정책

QName - AS3

클래스 x

localName

uri

QName

QName

toString

valueOf