保護されたコンテンツのワークフローについて

次の手順は、DRMContentData オブジェクトを使用して、保護されたメディアファイルに対して証明書を事前に読み込むためのワークフローを示しています。

1. パッケージ化されたコンテンツのバイナリメタデータを取得します。Flash Access Java Reference Packager を使用している場合、このメタデータファイルは自動的に .metadata 拡張子を使用して生成されます。例えば、URLLoader クラスを使用してこのメタデータをダウンロードできます。

2. DRMContentData オブジェクトを作成し、メタデータをコンストラクター関数に渡します。

   var drmData:DRMContentData = new DRMContentData( metadata );

3. 以降の手順は、保護されたコンテンツのワークフローについてで説明しているワークフローと同じです。

次の手順では、preloadEmbeddedMetadata() を使用して、DRM で保護されたメディアファイルの証明書を事前に読み込むためのワークフローを示します。

1. メディアファイルをダウンロードして保存します（DRM メタデータは、ローカルに保存されたファイルからのみ事前に読み込むことができます）。

2. NetConnection オブジェクトと NetStream オブジェクトを作成して、NetStream クライアントオブジェクトの onDRMContentData() コールバック関数および onPlayStatus() コールバック関数を実装します。

3. NetStreamPlayOptions オブジェクトを作成し、stream プロパティをローカルのメディアファイルの URL に設定します。

4. NetStream preloadEmbeddedMetadata() を呼び出して、解析するメディアファイルを識別する NetStreamPlayOptions オブジェクトを渡します。

5. メディアファイルに DRM メタデータが含まれている場合は、onDRMContentData() コールバック関数が呼び出されます。メタデータは、この関数に DRMContentData オブジェクトとして渡されます。

6. DRMManager loadVoucher() メソッドを使用し、DRMContentData オブジェクトを使用して証明書を取得します。

   DRMContentData オブジェクトの authenticationMethod プロパティの値が userNameAndPassword の場合は、証明書を読み込む前に Media Rights Server でユーザーを認証する必要があります。DRMContentData オブジェクトの serverURL プロパティおよび domain プロパティが、ユーザー情報と共に DRMManager authenticate() メソッドに渡されます。

7. ファイルの解析が完了すると、onPlayStatus() コールバック関数が呼び出されます。onDRMContentData() 関数が呼び出されていない場合、そのファイルには証明書の取得に必要なメタデータが含まれていません。また、この関数が呼び出されていない場合、Flash Access がこのファイルを保護していない可能性があります。

例えば、次の AIR 用のコードは、ローカルのメディアファイルの 証明書を事前に読み込む方法を示しています。

package 
{ 
import flash.display.Sprite; 
import flash.events.DRMAuthenticationCompleteEvent; 
import flash.events.DRMAuthenticationErrorEvent; 
import flash.events.DRMErrorEvent;   
import flash.ev ents.DRMStatusEvent; 
import flash.events.NetStatusEvent; 
import flash.net.NetConnection; 
import flash.net.NetStream; 
import flash.net.NetStreamPlayOptions; 
import flash.net.drm.AuthenticationMethod; 
import flash.net.drm.DRMContentData; 
import flash.net.drm.DRMManager; 
import flash.net.drm.LoadVoucherSetting;   
public class DRMPreloader extends Sprite  
{ 
     private var videoURL:String = "app-storage:/video.flv"; 
    private var userName:String = "user"; 
    private var password:String = "password";  
    private var preloadConnection:NetConnection; 
    private var preloadStream:NetStream; 
    private var drmManager:DRMManager = DRMManager.getDRMManager(); 
    private var drmContentData:DRMContentData; 
    public function DRMPreloader():void { 
        drmManager.addEventListener( 
            DRMAuthenticationCompleteEvent.AUTHENTICATION_COMPLETE, 
            onAuthenticationComplete); 
        drmManager.addEventListener(DRMAuthenticationErrorEvent.AUTHENTICATION_ERROR, 
            onAuthenticationError);             
        drmManager.addEventListener(DRMStatusEvent.DRM_STATUS, onDRMStatus); 
        drmManager.addEventListener(DRMErrorEvent.DRM_ERROR, onDRMError); 
        preloadConnection = new NetConnection(); 
        preloadConnection.addEventListener(NetStatusEvent.NET_STATUS, onConnect); 
        preloadConnection.connect(null);            
    } 
 
    private function onConnect( event:NetStatusEvent ):void 
    { 
        preloadMetadata(); 
    } 
    private function preloadMetadata():void 
    { 
        preloadStream = new NetStream( preloadConnection ); 
        preloadStream.client = this; 
        var options:NetStreamPlayOptions = new NetStreamPlayOptions(); 
        options.streamName = videoURL; 
        preloadStream.preloadEmbeddedData( options );                         
    }     
    public function onDRMContentData( drmMetadata:DRMContentData ):void 
    { 
        drmContentData = drmMetadata; 
        if ( drmMetadata.authenticationMethod == AuthenticationMethod.USERNAME_AND_PASSWORD ) 
        { 
            authenticateUser(); 
        } 
        else 
            { 
                getVoucher(); 
            } 
    } 
    private function getVoucher():void 
    { 
        drmManager.loadVoucher( drmContentData, LoadVoucherSetting.ALLOW_SERVER ); 
    } 
 
    private function authenticateUser():void 
    { 
        drmManager.authenticate( drmContentData.serverURL, drmContentData.domain, userName, password ); 
    } 
    private function onAuthenticationError( event:DRMAuthenticationErrorEvent ):void 
    { 
        trace( "Authentication error: " + event.errorID + ", " + event.subErrorID ); 
    } 
 
    private function onAuthenticationComplete( event:DRMAuthenticationCompleteEvent ):void 
    { 
        trace( "Authenticated to: " + event.serverURL + ", domain: " + event.domain ); 
        getVoucher(); 
    } 
    private function onDRMStatus( event:DRMStatusEvent ):void 
    { 
        trace( "DRM Status: " + event.detail); 
        trace("--Voucher allows offline playback = " + event.isAvailableOffline ); 
        trace("--Voucher already cached          = " + event.isLocal ); 
        trace("--Voucher required authentication = " + !event.isAnonymous ); 
    } 
    private function onDRMError( event:DRMErrorEvent ):void 
    { 
        trace( "DRM error event: " + event.errorID + ", " + event.subErrorID + ", " + event.text ); 
    } 
    public function onPlayStatus( info:Object ):void 
    { 
        preloadStream.close(); 
    } 
} 
}