Méthodes d’utilisation d’expressions régulières avec des chaînes

Flash Player 9 et les versions ultérieures, Adobe AIR 1.0 et les versions ultérieures

La classe RegExp comprend deux méthodes : exec() et test() .

Outre les méthodes exec() et test() de la classe RegExp, la classe String comprend les méthodes suivantes qui vous permettent d’établir une correspondance avec des expressions régulières dans des chaînes : match() , replace() , search() et splice() .

La méthode test()

La méthode test() de la classe RegExp vérifie si la chaîne fournie contient une correspondance pour l’expression régulière, comme l’indique l’exemple suivant :

var pattern:RegExp = /Class-\w/; 
var str = "Class-A"; 
trace(pattern.test(str)); // output: true

La méthode exec()

La méthode exec() de la classe RegExp vérifie si la chaîne fournie contient une correspondance pour l’expression régulière et renvoie un tableau avec les éléments suivants :

  • La sous-chaîne correspondante

  • Les correspondances de sous-chaîne pour les groupes entre parenthèses dans l’expression régulière

Le tableau inclut également une propriété index qui indique la position d’index du début de la correspondance de sous-chaîne.

Considérons par exemple le code qui suit :

var pattern:RegExp = /\d{3}\-\d{3}-\d{4}/; //U.S phone number 
var str:String = "phone: 415-555-1212"; 
var result:Array = pattern.exec(str); 
trace(result.index, " - ", result); 
// 7-415-555-1212

Utilisez la méthode exec() plusieurs fois pour établir une correspondance avec plusieurs sous-chaînes lorsque l’indicateur g ( global ) est défini pour l’expression régulière :

var pattern:RegExp = /\w*sh\w*/gi; 
var str:String = "She sells seashells by the seashore"; 
var result:Array = pattern.exec(str); 
     
while (result != null) 
{ 
    trace(result.index, "\t", pattern.lastIndex, "\t", result); 
    result = pattern.exec(str); 
} 
//output:  
// 0      3      She 
// 10      19      seashells 
// 27      35      seashore

Méthodes de chaîne utilisant des paramètres RegExp

Les méthodes suivantes de la classe String prennent des expressions régulières comme paramètres : match() , replace() , search() et split() . Pour plus d’informations sur ces méthodes, voir Recherche de modèles dans des chaînes et remplacement de sous-chaînes .