Captura de entradas de texto

Flash Player 9 y posterior, Adobe AIR 1.0 y posterior

De forma predeterminada, la propiedad type de un campo de texto se establece como dynamic . Si la propiedad type se establece en input mediante la clase TextFieldType, se puede obtener la entrada del usuario y guardar el valor para utilizarlo en otras partes de la aplicación. Los campos de entrada de texto resultan útiles para los formularios y cualquier aplicación que requieran que el usuario defina un valor de texto para utilizarlo en otro lugar del programa.

Por ejemplo, el código siguiente crea un campo de entrada de texto denominado myTextBox . A medida que el usuario escribe texto en el campo, se activa el evento textInput . Un controlador de eventos denominado textInputCapture captura la cadena de texto introducido y se la asigna a una variable. Flash Player o AIR muestran el nuevo texto en otro campo de texto, llamado myOutputBox .

package 
{ 
    import flash.display.Sprite; 
    import flash.display.Stage; 
    import flash.text.*; 
    import flash.events.*; 
 
    public class CaptureUserInput extends Sprite 
    { 
        private var myTextBox:TextField = new TextField(); 
        private var myOutputBox:TextField = new TextField(); 
        private var myText:String = "Type your text here."; 
 
        public function CaptureUserInput() 
        { 
            captureText(); 
        } 
         
        public function captureText():void 
        { 
            myTextBox.type = TextFieldType.INPUT; 
            myTextBox.background = true; 
            addChild(myTextBox); 
            myTextBox.text = myText; 
            myTextBox.addEventListener(TextEvent.TEXT_INPUT, textInputCapture); 
        } 
         
        public function textInputCapture(event:TextEvent):void 
        { 
            var str:String = myTextBox.text; 
            createOutputBox(str); 
        } 
             
        public function createOutputBox(str:String):void 
        { 
            myOutputBox.background = true; 
            myOutputBox.x = 200; 
            addChild(myOutputBox); 
            myOutputBox.text = str; 
        } 
         
    } 
}