Descodificación asíncrona de imágenes de mapa de bits

Cuando se trabaja con imágenes de mapa de bits, se puede descodificar de forma asíncrona y cargar imágenes de mapa de bits con el fin de mejorar el rendimiento percibido de la aplicación. La descodificación de una imagen de mapa de bits puede tardar el mismo tiempo que de la descodificación sincrónica de imágenes en muchos casos. Sin embargo, la imagen de mapa de bits se descodifica en un subproceso independiente antes de que el objeto Loader asociado envíe el evento COMPLETE . Por lo tanto, es posible descodificar de forma asíncrona imágenes de mayor tamaño tras cargarlas.

La clase ImageDecodingPolicy del paquete flash.system , permite especificar el esquema de carga de mapa de bits. El esquema de carga predeterminado es sincrónico.

El siguiente código muestra el uso de la clase ImageDecodingPolicy :

var loaderContext:LoaderContext = new LoaderContext(); 
loaderContext.imageDecodingPolicy = ImageDecodingPolicy.ON_LOAD 
var loader:Loader = new Loader(); 
loader.load(new URLRequest("http://www.adobe.com/myimage.png"), loaderContext);

Aún se puede utilizar la descodificación ON_DEMAND con los métodos Loader.load() y Loader.loadBytes() . Sin embargo, todos los demás métodos que obtengan un objeto LoaderContext como argumento, omitirán todos los valores ImageDecodingPolicy transmitidos.

En el siguiente ejemplo se muestra la diferencia en la descodificación de una imagen de mapa de bits de forma sincrónica y asíncrona:

package 
{ 
    import flash.display.Loader;   
    import flash.display.Sprite;  
    import flash.events.Event; 
    import flash.net.URLRequest; 
    import flash.system.ImageDecodingPolicy; 
    import flash.system.LoaderContext; 
 
    public class AsyncTest extends Sprite 
    { 
        private var loaderContext:LoaderContext; 
        private var loader:Loader; 
        private var urlRequest:URLRequest;         
        public function AsyncTest() 
        { 
            //Load the image synchronously 
            loaderContext = new LoaderContext(); 
            //Default behavior. 
            loaderContext.imageDecodingPolicy = ImageDecodingPolicy.ON_DEMAND;             
            loader = new Loader();     
            loadImageSync();                     
             
            //Load the image asynchronously 
            loaderContext = new LoaderContext(); 
            loaderContext.imageDecodingPolicy = ImageDecodingPolicy.ON_LOAD;             
            loader = new Loader(); 
            loadImageASync();     
        } 
         
        private function loadImageASync():void{ 
            trace("Loading image asynchronously...");             
            urlRequest = new URLRequest("http://www.adobe.com/myimage.png");     
            urlRequest.useCache = false; 
            loader.load(urlRequest, loaderContext);                     
            loader.contentLoaderInfo.addEventListener 
                (Event.COMPLETE, onAsyncLoadComplete); 
        } 
         
        private function onAsyncLoadComplete(event:Event):void{             
            trace("Async. Image Load Complete"); 
        }     
     
        private function loadImageSync():void{             
            trace("Loading image synchronously...");             
            urlRequest = new URLRequest("http://www.adobe.com/myimage.png");     
            urlRequest.useCache = false; 
            loader.load(urlRequest, loaderContext); 
            loader.contentLoaderInfo.addEventListener 
                (Event.COMPLETE, onSyncLoadComplete); 
        } 
         
        private function onSyncLoadComplete(event:Event):void{             
            trace("Sync. Image Load Complete"); 
        } 
    } 
}

Para ver una demostración del efecto de las distintas políticas de descodificación, consulte Thibaud Imbert: Asynchronous bitmap decoding in the Adobe Flash runtimes

Los términos de Creative Commons no cubren las publicaciones en Twitter™ y Facebook.