TextFlowTextLineFactory

Paquete	flashx.textLayout.factory
Clase	public class TextFlowTextLineFactory
Herencia	TextFlowTextLineFactory TextLineFactoryBase Object

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

Flash Player 10, AIR 1.5

La clase TextFlowTextLineFactory ofrece un modo sencillo de creación de objetos TextLine para visualizar texto de un flujo de texto.

Las líneas de texto son estáticas y se crean para ajustarse a un solo rectángulo delimitador, pero pueden tener varios párrafos y formatos, así como gráficos de línea. Para crear objetos TextLine directamente desde una cadena, utilice StringTextLineFactory.

Nota: si utiliza gráficos de línea, la propiedad source del objeto InlineGraphicElement debe ser una instancia de DisplayObject o un objeto Class que represente un activo incorporado. No se pueden utilizar objetos URLRequest. La anchura y la altura del gráfico de línea en el momento de crear la línea se utiliza para componer el flujo.

Ver los ejemplos

Elementos de API relacionados

TextFlow
StringTextLineFactory

Propiedades públicas

Ocultar propiedades públicas heredadas

Mostrar propiedades públicas heredadas

	Propiedad		Definido por
		compositionBounds : Rectangle El rectángulo en el que se crean las líneas.	TextLineFactoryBase
		constructor : Object Una referencia a la clase de objeto o función constructora para una instancia de objeto determinada.	Object
		horizontalScrollPolicy : String Especifica cómo se crean las líneas cuando los límites de la composición no son lo suficientemente grandes.	TextLineFactoryBase
		isTruncated : Boolean [solo lectura] Indica si el texto se ha truncado al crear las últimas líneas.	TextLineFactoryBase
		swfContext : ISWFContext La instancia de ISWFContext utilizada para hacer llamadas FTE según sea necesario.	TextLineFactoryBase
		truncationOptions : flashx.textLayout.factory:TruncationOptions Especifica las opciones para truncar el texto si no se ajusta a los límites de la composición.	TextLineFactoryBase
		verticalScrollPolicy : String Especifica cómo se crean las líneas cuando los límites de la composición no son lo suficientemente grandes.	TextLineFactoryBase

Métodos públicos

Ocultar métodos públicos heredados

Mostrar métodos públicos heredados

	Método		Definido por
		TextFlowTextLineFactory() Crea un objeto TextFlowTextLineFactory.	TextFlowTextLineFactory
		createTextLines(callback:Function, textFlow:flashx.textLayout.elements:TextFlow):void Crea objetos TextLine a partir del flujo de texto especificado.	TextFlowTextLineFactory
		getContentBounds():Rectangle El rectángulo más pequeño en el que se ajusta el contenido diseñado.	TextLineFactoryBase
		hasOwnProperty(name:String):Boolean Indica si un objeto tiene definida una propiedad especificada.	Object
		isPrototypeOf(theClass:Object):Boolean Indica si hay una instancia de la clase Object en la cadena de prototipo del objeto especificado como parámetro.	Object
		propertyIsEnumerable(name:String):Boolean Indica si existe la propiedad especificada y si es enumerable.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Establece la disponibilidad de una propiedad dinámica para operaciones de bucle.	Object
		toLocaleString():String Devuelve la representación de cadena de este objeto, con formato según las convenciones específicas de configuración regional.	Object
		toString():String Devuelve la representación de cadena del objeto especificado.	Object
		valueOf():Object Devuelve el valor simple del objeto especificado.	Object

Información sobre constructores

()

Información sobre

public function TextFlowTextLineFactory()

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

Flash Player 10, AIR 1.5

Crea un objeto TextFlowTextLineFactory.

Información sobre métodos

createTextLines

()

método

public function createTextLines(callback:Function, textFlow:flashx.textLayout.elements:TextFlow):void

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

Flash Player 10, AIR 1.5

Crea objetos TextLine a partir del flujo de texto especificado.

Las líneas de texto están compuestas para ajustarse a los límites asignados por la propiedad compositionBounds. A medida que se crea cada línea, la fábrica llama a la función especificada en el parámetro callback. Esta función se transfiere al objeto TextLine y es responsable de representar la línea. Si una línea tiene color de fondo, la fábrica también llama a la función callback con un objeto Shape que contiene un rectángulo del color de fondo.

Tenga en cuenta que las políticas de desplazamiento de fábrica controlarán el número de líneas generadas.

Parámetros

	`callback:Function` — función para llamar con cada objeto TextLine generado. Se devolverá la llamada con un objeto Shape que representa cualquier color de fondo (si lo hay) y con objetos TextLine para el texto.

	`textFlow:flashx.textLayout.elements:TextFlow` — Objeto TextFlow desde el que se crean las líneas.

Ejemplos Cómo utilizar este ejemplo

TextFlowTextLineFactory_example.as

El siguiente ejemplo utiliza TextFlowTextLineFactory para crear un conjunto de líneas de texto. Se llama dos veces al método de fábrica, createTextLines(), con la misma frase. Las propiedades de fábrica y los formatos del flujo se ajustan entre las llamadas para crear un efecto de "sombra".

package flashx.textLayout.factory.examples
{
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.geom.Rectangle;
    import flash.text.engine.TextLine;
    
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.factory.TextFlowTextLineFactory;
    import flashx.textLayout.formats.TextLayoutFormat;

    public class TextFlowTextLineFactory_example extends Sprite
    {
        public function TextFlowTextLineFactory_example()
        {
            var factory:TextFlowTextLineFactory = new TextFlowTextLineFactory();
            factory.compositionBounds = new Rectangle( 100, 100, 200, 130 );
            
            var flow:TextFlow = new TextFlow();

            var format:TextLayoutFormat = new TextLayoutFormat();
            format.fontFamily = "LilyUPC, Verdana, _sans";
            format.fontSize = 32;
            format.color = 0x000000;
            format.textAlpha = .5;
            
            var span:SpanElement = new SpanElement();
            span.text = "The quick brown fox jumped over the lazy dog.";            
            span.format = format;
            
            var para:ParagraphElement = new ParagraphElement();
            para.addChild( span );
            
            flow.addChild( para );
            
            factory.createTextLines( useTextLines, flow );
            
            factory.compositionBounds = new Rectangle( 99, 99, 200, 130 );
            format.color = 0x990000;
            format.textAlpha = 1;
            span.format = format;
            factory.createTextLines( useTextLines, flow );
            
            graphics.beginFill(0x555555,.5);
            graphics.drawRect( 99, 99, 201, 131 );
            graphics.endFill();

        }
        
        private function useTextLines( lineOrShape:DisplayObject ):void
        {
            this.addChild( lineOrShape );
        }
        
    }
}

Avisos legales | Política de privacidad en línea

TextFlowTextLineFactory - AS3

Clases x

TextFlowTextLineFactory

createTextLines