Paquete flash.utils 

Cancela una llamada setInterval() especificada.

Parámetros

Elementos de API relacionados

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class ClearIntervalExample extends Sprite {
        private var intervalDuration:Number = 1000; // duration between intervals, in milliseconds
        private var intervalId:uint;
        private var counter:uint     = 0;
        private var stopCount:uint     = 3;
        
        public function ClearIntervalExample() {
            intervalId = setInterval(myRepeatingFunction, intervalDuration, "Hello", "World");
        }

        public function myRepeatingFunction():void {
            trace(arguments[0] + " " + arguments[1]);

            counter++;
            if(counter == stopCount) {
                trace("Clearing Interval");
                clearInterval(intervalId);    
            }
        }
    }
}

Cancela una llamada setTimeout() especificada.

Parámetros

Elementos de API relacionados

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class ClearTimeoutExample extends Sprite {
        private var delay:Number = 1000; // delay before calling myDelayedFunction
        private var intervalId:uint;
        private var count:uint = 1000000;
        
        public function ClearTimeoutExample() {
            intervalId = setTimeout(myDelayedFunction, delay);
            startCounting();
        }

        public function startCounting():void {
            var i:uint = 0;
            do {
                if(i == count-1) {
                    clearTimeout(intervalId);
                    trace("Your computer can count to " + count + " in less than " + delay/1000 + " seconds.");    
                }
                i++;
            } while(i < count)            
        }
        
        public function myDelayedFunction():void {
            trace("Time expired.");
        }
    }
}

Produce un objeto XML que describe el objeto ActionScript asignado como parámetro del método. Este método implementa el concepto de programación conocido como reflejo para el lenguaje ActionScript.

Si el parámetro value es una instancia de un tipo, el objeto XML devuelto incluirá todas las propiedades de la instancia de dicho tipo, pero no incluirá ninguna propiedad estática. Es posible comprobar este estado al analizar el objeto XML: examine el valor del atributo isStatic de la etiqueta <type>, que será false si el parámetro value es una instancia de un tipo.

Para obtener las propiedades estáticas de un tipo, transfiera el propio tipo para el parámetro value. El objeto XML devuelto no sólo incluye las propiedades estáticas del tipo, sino también todas las propiedades de su instancia. Las propiedades de la instancia se anidan en una etiqueta denominada <factory> para distinguirlas de las propiedades estáticas. En este caso, el atributo isStatic de la etiqueta <type> es true.

Nota: si sólo es necesario recorrer la jerarquía de herencia del objeto y no se requiere ninguna otra información proporcionada por describeType(), utilice las funciones getQualifiedClassName() y getQualifiedSuperclassName().

En la siguiente tabla se describen algunas etiquetas y atributos del objeto XML generado por describeType() (todos los nombres de clase e interfaz devueltos aparecen en formato completo):

Parámetros

Elementos de API relacionados

package {
    import flash.display.Sprite;
    import flash.utils.describeType;
    
    public class DescribeTypeExample extends Sprite {
        public function DescribeTypeExample() {
            var child:Sprite = new Sprite();
            var description:XML = describeType(child);
            trace(description..accessor.@name.toXMLString());
        }
    }
}

Devuelve una copia literal de la cadena de entrada codificada como UTF-8 o como página de códigos del sistema, en función del valor de System.useCodePage. El uso de System.useCodePage permite codificar el contenido heredado en páginas de códigos locales a las que el motor de ejecución puede acceder, aunque solamente en sistemas que utilicen dicha página de códigos heredada. Por ejemplo, los datos japoneses codificados como Shift-JIS sólo se representan literalmente de forma correcta en un sistema operativo que utilice páginas de código predeterminadas para japonés.

Parámetros

Devuelve una referencia al objeto de clase de la clase especificada por el parámetro name.

Parámetros

package {
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    import flash.utils.getDefinitionByName;

    public class GetDefinitionByNameExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint = 80;

        public function GetDefinitionByNameExample() {
            var ClassReference:Class = getDefinitionByName("flash.display.Sprite") as Class;
            var instance:Object = new ClassReference();
            instance.graphics.beginFill(bgColor);
            instance.graphics.drawRect(0, 0, size, size);
            instance.graphics.endFill();
            addChild(DisplayObject(instance));
        }
    }
}

Devuelve el nombre de clase completo de un objeto.

Parámetros

Elementos de API relacionados

Devuelve el nombre de clase completo de la clase base del objeto especificado por el parámetro value. Esta función proporciona un método más rápido que describeType() para recuperar el nombre de la clase base, pero no proporciona toda la información suministrada por describeType().

Tras recuperar el nombre de una clase con esta función, puede convertir el nombre de la clase en una referencia a la clase con la función getDefinitionByName().

Nota: esta función se limita a las jerarquías de instancias, mientras que la función describeType() utiliza jerarquías de objetos de clase si el parámetro value es un tipo de datos. Al llamar a describeType() en un tipo de datos, se devuelve la superclase basada en la jerarquía del objeto de clase, en la que todos los objetos de clase se heredan de la clase Class. Sin embargo, la función getQualifiedSuperclassName() omite la jerarquía del objeto de clase y devuelve la superclase basada en la jerarquía de instancias más familiar. Por ejemplo, al llamar a getQualifiedSuperclassName(String) se devuelve Object, aunque técnicamente el objeto de clase String hereda de la clase Class. Es decir, los resultados son los mismos utilice una instancia de un tipo o el propio tipo.

Parámetros

Elementos de API relacionados

Se utiliza para calcular el tiempo relativo. En un motor de ejecución de Flash que procesa ActionScript 3.0, este método devuelve el número de milisegundos transcurridos desde el inicio de la máquina virtual del motor de ejecución de Flash para ActionScript 3.0 (AVM2). En un motor de ejecución de Flash que procesa ActionScript 2.0, este método devuelve el número de milisegundos transcurridos desde la inicialización del motor de ejecución de Flash. Los motores de ejecución de Flash utilizan dos máquinas virtuales para procesar ActionScript. AVM1 es la máquina virtual de ActionScript que se utiliza para ejecutar ActionScript 1.0 y 2.0. AVM2 es la máquina virtual de ActionScript que se utiliza para ejecutar ActionScript 3.0. El comportamiento del método getTimer() para AVM1 es diferente del comportamiento para AVM2.

En una fecha de calendario (timestamp), consulte el objeto Date.

Elementos de API relacionados

package {
    import flash.utils.getTimer;
    import flash.display.Sprite;

    public class GetTimerExample extends Sprite {
        public function GetTimerExample() {
            var duration:uint = getTimer();
            trace("duration: " + duration);
        }
    }
}

Ejecuta una función en un intervalo especificado (en milisegundos).

En lugar de utilizar el método setInterval(), considere la posibilidad de crear un objeto Timer, con el intervalo especificado, utilizando 0 como el parámetro repeatCount (que definirá el temporizador para que se repita indefinidamente).

Si pretende utilizar el método clearInterval() para cancelar la llamada a setInterval(), es importante que asigne la llamada setInterval() a una variable (a la que la función clearInterval() hará referencia más tarde). Si no llama a la función clearInterval() para cancelar la llamada a setInterval(), el objeto con la función de cierre de tiempo de espera definida no entrará en el proceso de recolección de datos innecesarios.

Parámetros

Elementos de API relacionados

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class SetIntervalExample extends Sprite {
        private var intervalDuration:Number = 1000; // duration between intervals, in milliseconds
        
        public function SetIntervalExample() {
            var intervalId:uint = setInterval(myRepeatingFunction, intervalDuration, "Hello", "World");
        }

        public function myRepeatingFunction():void {
            trace(arguments[0] + " " + arguments[1]);
        }
    }
}

Ejecuta una función concreta tras una demora especificada (en milisegundos).

En lugar de utilizar este método, considere la posibilidad de crear un objeto Timer, con el intervalo especificado, utilizando 1 como el parámetro repeatCount (que definirá el temporizador para que se repita una sola vez).

Si pretender utilizar el método clearTimeout() para cancelar la llamada setTimeout(), es importante que asigne la llamada setTimeout() a una variable (a la que hará referencia más adelante la función clearTimeout()) Si no llama a la función clearTimeout() para cancelar la llamada a setTimeout(), el el objeto que contiene la función de cierre de tiempo de espera definida no entrará en el proceso de recolección de datos innecesarios.

Parámetros

Elementos de API relacionados

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class SetTimeoutExample extends Sprite {
        private var delay:Number = 1000; // delay before calling myDelayedFunction
        
        public function SetTimeoutExample() {
            var intervalId:uint = setTimeout(myDelayedFunction, delay, "Hello", "World");
        }

        public function myDelayedFunction():void {
            trace(arguments[0] + " " + arguments[1]);
        }
    }
}

Devuelve una copia no literal de la cadena de entrada, que se descodifica desde la página de códigos del sistema o a partir de UTF-8, en función del valor de System.useCodePage. El uso de System.useCodePage permite codificar el contenido heredado en páginas de códigos locales a las que el motor de ejecución puede acceder, aunque solamente en sistemas que utilicen dicha página de códigos heredada. Por ejemplo, los datos japoneses codificados como Shift-JIS sólo se representan literalmente de forma correcta en un sistema operativo que utilice páginas de código predeterminadas para japonés.

Parámetros