TextLineMetrics  - AS3

El valor ascendente del texto es la longitud desde la línea base hasta la altura máxima de la línea, expresada en píxeles. Consulte la medida "Ascendente" en el diagrama de información general de esta clase.

Elementos de API relacionados

El valor descendente del texto es la longitud desde la línea base hasta la profundidad máxima de la línea, expresada en píxeles. Consulte la medida "Descendente" en el diagrama de información general de esta clase.

Elementos de API relacionados

El valor de altura del texto de las líneas seleccionadas (no necesariamente todo el texto), expresada en píxeles. La altura de la línea de texto no incluye la altura de espacio. Consulte la medida "Altura de la línea" en el diagrama de información general de esta clase.

Elementos de API relacionados

El valor de interlineado es la medida de la distancia vertical entre las líneas de texto. Consulte la medida "Interlineado" en el diagrama de información general de esta clase.

Elementos de API relacionados

El valor de anchura del texto es la anchura de las líneas seleccionadas (no necesariamente todo el texto), expresada en píxeles. La anchura de la línea de texto no es la misma que la del campo de texto. La anchura de la línea de texto está relacionada con la anchura del campo de texto: debe restársele la anchura de espacio de 4 píxeles (2 a cada lado). Consulte la medida "Anchura de la línea de texto" en el diagrama de información general de esta clase.

Elementos de API relacionados

El valor x es la posición izquierda del primer carácter, expresada en píxeles. Este valor incluye la anchura de los márgenes, las sangrías (si tiene) y los espacios. Consulte la "Posición x de la línea de texto" en el diagrama de información general de esta clase.

Elementos de API relacionados

Crea un objeto TextLineMetrics. El objeto TextLineMetrics contiene información sobre las medidas de texto de una línea de texto dentro de un campo de texto. Los objetos de esta clase se devuelven mediante el método flash.text.TextField.getLineMetrics().

Consulte el diagrama de información general de esta clase para ver las propiedades en contexto.

Elementos de API relacionados

1. Cree una propiedad denominada label de tipo TextField.
2. El constructor llama a configureAssets(), que realiza lo siguiente:
   • Establece la alineación del escenario como superior izquierda y sin escala.
   • Crea un nuevo objeto TextField denominado label.
   • Habilita el fondo de label y establece el color en blanco.
   • Permite que el texto de label abarque varias líneas con el ajuste de texto automático.
   • Asigna el resultado de una llamada a getLabelText() a la propiedad text de label. El método getLabelText() crea una variable de tipo XML y la asigna a un nodo XML denominado body, que se rellena con una frase larga.
   • Añade label a la lista de visualización mediante addChild().
3. A continuación, se añade un método que detecta eventos resize realizados en el escenario denominado resizeHandler(). Cada vez que cambia el tamaño de la ventana de Flash Player, se distribuye un evento RESIZE y ocurre lo siguiente:
   • Se llama a draw() para garantizar que label aparezca en el centro del escenario rodeado de un búfer de 10 píxeles.
   • setTimeout() ejecuta showMetrics() tras una breve demora. La demora se añade debido a que las medidas de línea no se actualizan hasta que finaliza el evento RESIZE y se dibuja de nuevo y por completo el escenario.
   • showMetrics() asigna una variable TextLineMetrics denominada metrics al resultado de una llamada a getLineMetrics() y esta variable se transfiere a continuación a una nueva instancia de LineMetricsReader denominada reader. Las dos variables se utilizan después en las llamadas a trace() para imprimir la primera (y única) línea de label e información proporcionada por la instancia de LineMetricsReader a través del método toString().
4. El constructor fuerza una única distribución del evento resize para hacer que label se dibuje correctamente cuando se cargue el archivo SWF por primera vez.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.*;
    import flash.text.TextField;
    import flash.text.TextLineMetrics;
    import flash.utils.setTimeout;

    public class TextLineMetricsExample extends Sprite {
        private var gutter:int = 10;
        private var label:TextField;

        public function TextLineMetricsExample() {
            configureAssets();
            configureListeners();
            resizeHandler(new Event(Event.RESIZE));
        }

        private function showMetrics():void {
            var metrics:TextLineMetrics = label.getLineMetrics(0);
            var reader:LineMetricsReader = new LineMetricsReader(metrics);
            trace("lineText: " + label.getLineText(0));
            trace("metrics: " + reader);
        }

        private function configureAssets():void {
            stage.align = StageAlign.TOP_LEFT;
            stage.scaleMode = StageScaleMode.NO_SCALE;

            label = new TextField();
            label.background = true;
            label.backgroundColor = 0xFFFFFF;
            label.multiline = true;
            label.wordWrap = true;
            label.text = getLabelText();
            addChild(label);
        }

        private function configureListeners():void {
            stage.addEventListener(Event.RESIZE, resizeHandler);
        }

        private function resizeHandler(event:Event):void {
            draw();
            setTimeout(showMetrics, 100);
        }

        private function draw():void {
            label.x = gutter;
            label.y = gutter;
            label.width = stage.stageWidth - (gutter * 2);
            label.height = stage.stageHeight - (gutter * 2);
        }

        private function getLabelText():String {
            var text:XML = <body>The Flex product line enables developers to build rich Internet applications that blend the responsiveness of desktop software, the cross-platform reach of the web, and the expressiveness of the Flash Platform.</body>
            return text.toString();
        }
    }
}

import flash.text.TextLineMetrics;

class LineMetricsReader {
    private var metrics:TextLineMetrics;

    public function LineMetricsReader(metrics:TextLineMetrics) {
        this.metrics = metrics;
    }

    public function toString():String {
        return "[TextLineMetrics ascent:" + metrics.ascent
            + ", descent:" + metrics.descent
            + ", leading:" + metrics.leading
            + ", width:" + metrics.width
            + ", height:" + metrics.height
            + ", x:" + metrics.x
            + "]";
    }
}