StorageVolume

Paquete	flash.filesystem
Clase	public class StorageVolume
Herencia	StorageVolume Object

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 2

Un objeto StorageVolume incluye propiedades que definen una volumen de almacenamiento masivo. Esta clase se utiliza de dos formas:

La propiedad storageVolume de un objeto StorageVolumeChangeEvent es un objeto StorageVolume. Este objeto representa el volumen de almacenamiento que se ha montado o desmontado.
El método estático StorageVolumeInfo.storageVolumeInfo.getStorageVolumes() devuelve un vector de objetos StorageVolume. Cada uno de estos objetos StorageVolume representa un volumen de almacenamiento montado.

Ver los ejemplos

Elementos de API relacionados

flash.filesystem.StorageVolumeInfo.getStorageVolumes()
flash.events.StorageVolumeChangeEvent.storageVolume

Propiedades públicas

Ocultar propiedades públicas heredadas

Mostrar propiedades públicas heredadas

	Propiedad		Definido por
		constructor : Object Una referencia a la clase de objeto o función constructora para una instancia de objeto determinada.	Object
		drive : String [solo lectura] La letra de la unidad del volumen en Windows.	StorageVolume
		fileSystemType : String [solo lectura] El tipo de sistema de archivos del volumen de almacenamiento (por ejemplo, "FAT", "NTFS", "HFS" o "UFS").	StorageVolume
		isRemovable : Boolean [solo lectura] Si el sistema operativo considera el volumen de almacenamiento extraíble (true) o no (false).	StorageVolume
		isWritable : Boolean [solo lectura] Si un volumen es de escritura (true) o no (false).	StorageVolume
		name : String [solo lectura] El nombre del volumen.	StorageVolume
		rootDirectory : File [solo lectura] Un objeto File correspondiente al directorio raíz del volumen.	StorageVolume

Métodos públicos

Ocultar métodos públicos heredados

Mostrar métodos públicos heredados

	Método		Definido por
		StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String) La función del constructor.	StorageVolume
		hasOwnProperty(name:String):Boolean Indica si un objeto tiene definida una propiedad especificada.	Object
		isPrototypeOf(theClass:Object):Boolean Indica si hay una instancia de la clase Object en la cadena de prototipo del objeto especificado como parámetro.	Object
		propertyIsEnumerable(name:String):Boolean Indica si existe la propiedad especificada y si es enumerable.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Establece la disponibilidad de una propiedad dinámica para operaciones de bucle.	Object
		toLocaleString():String Devuelve la representación de cadena de este objeto, con formato según las convenciones específicas de configuración regional.	Object
		toString():String Devuelve la representación de cadena del objeto especificado.	Object
		valueOf():Object Devuelve el valor simple del objeto especificado.	Object

Información sobre propiedades

drive

propiedad

drive:String [solo lectura]

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 2

La letra de la unidad del volumen en Windows. En otras plataformas, esta propiedad se establece en null.

Implementación
public function get drive():String

fileSystemType

propiedad

fileSystemType:String [solo lectura]

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 2

El tipo de sistema de archivos del volumen de almacenamiento (por ejemplo, "FAT", "NTFS", "HFS" o "UFS").

Implementación
public function get fileSystemType():String

Ejemplo ( Cómo utilizar este ejemplo )

El siguiente código muestra la ruta nativa para el directorio raíz y el tipo de sistema de archivo de cada volumen de almacenamiento montado:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath, "(" + volumes[i].fileSystemType + ")");
}

isRemovable

propiedad

isRemovable:Boolean [solo lectura]

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 2

Si el sistema operativo considera el volumen de almacenamiento extraíble (true) o no (false).

En la siguiente tabla se enumeran los valores de la propiedad StorageVolume.isRemovable para distintos tipos de dispositivos:

Tipo de dispositivo	Mac OS	Windows	Linux
CD/DVD (fijo)	true	true	true
Unidad flash USB	true	true	true
Disco duro USB	false	false	true
Disco duro FireWire	false	false	true
Volumen compartido	true	false	- ¹
Unidad de red	false	false	false
Lector de tarjetas de almacenamiento (vacío)	- ²	false	- ²
Lector de tarjetas de almacenamiento (con tarjeta SD/CF)	true	true	true

¹ En Linux no existe el concepto de volumen compartido.

² En Windows una lector de tarjetas vacío se muestra como un dispositivo no extraíble. En Mac OS y Linux, los lectores de tarjetas vacíos no figuran como volúmenes de almacenamiento.

Implementación
public function get isRemovable():Boolean

Ejemplo ( Cómo utilizar este ejemplo )

El siguiente código genera una lista de volúmenes de almacenamiento no extraíbles, seguida de una lista de volúmenes de almacenamiento extraíbles:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();

trace("Non-removeable volumes:");
for (var i:int = 0; i < volumes.length; i++)
{
    if (!volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

trace("\nRemoveable volumes:");
for (i = 0; i < volumes.length; i++)
{
    if (volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

isWritable

propiedad

isWritable:Boolean [solo lectura]

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 2

Si un volumen es de escritura (true) o no (false).

Nota: puede determinar la cantidad de espacio disponible en un volumen llamando a la propiedad rootDirectory.spaceAvailble del objeto StorageVolume.

Implementación
public function get isWritable():Boolean

Elementos de API relacionados

flash.fileSystem.File.spaceAvailable

Ejemplo ( Cómo utilizar este ejemplo )

El siguiente código genera una lista de volúmenes de almacenamiento de de escritura y el espacio disponible en cada uno de ellos:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();

for (var i:int = 0; i < volumes.length; i++)
{
    if(volumes[i].isWritable)
    {         
        trace(volumes[i].rootDirectory.nativePath, volumes[i].rootDirectory.spaceAvailable);
    }
}

name

propiedad

name:String [solo lectura]

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 2

El nombre del volumen. Si no hay ningún nombre, esta propiedad se establece como null.

Implementación
public function get name():String

Ejemplo ( Cómo utilizar este ejemplo )

El código siguiente muestra la ruta nativa al directorio raíz y el nombre del sistema de archivos (si existe) de cada volumen de almacenamiento montado:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    var name:String = new String();
    if (volumes[i].name)
    {
        name = "(" + volumes[i].name + ")";
    }
    trace(volumes[i].rootDirectory.nativePath, name);
}

rootDirectory

propiedad

rootDirectory:File [solo lectura]

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 2

Un objeto File correspondiente al directorio raíz del volumen.

Implementación
public function get rootDirectory():File

Ejemplo ( Cómo utilizar este ejemplo )

El siguiente código muestra la ruta nativa para el directorio raíz de cada volumen de almacenamiento montado:

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath);
}

Información sobre constructores

()

Información sobre

public function StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String)

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 2

La función del constructor. Generalmente no se llama a esta función directamente (para crear nuevos objetos StorageVolume). Más bien se hace referencia a objetos StorageVolume accediendo a la propiedad storageVolume de un objeto StorageVolumeChangeEvent o se llama a StorageVolumeInfo.storageVolumeInfo.getStorageVolumes().

Parámetros

	`rootDirPath:File`

	`name:String`

	`writable:Boolean`

	`removable:Boolean`

	`fileSysType:String`

	`drive:String`

Ejemplos Cómo utilizar este ejemplo

StorageVolumeExample.as

El siguiente código enumera las propiedades de cada volumen de almacenamiento montado:

package
{
    import flash.display.Sprite;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeExample extends Sprite
    {
        public function StorageVolumeExample()
        {
            var volumes:Vector.<StorageVolume> = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
            for (var i:int = 0; i < volumes.length; i++)
            {
                var volume:StorageVolume = volumes[i];
                trace("nativePath:", volume.rootDirectory.nativePath);
                trace("fileSystemType:", volume.fileSystemType);
                trace("isRemovable:", volume.isRemovable);
                trace("isWritable:", volume.isWritable);
                trace("drive:", volume.drive);
                trace("name:", volume.name);
                trace("________________________________________________________");
            }
        }
    }
}

StorageVolumeChangeEventExample.as

El siguiente código enumera las propiedades de cada volumen de almacenamiento que se convierte en montado o desmontado. Tenga en cuenta que la propiedad storageVolume de StorageVolumeChangeEvent sólo se define para el evento storageVolumeMount; es null para el evento storageVolumeUnmount:

package
{
    import flash.display.Sprite;
    import flash.events.StorageVolumeChangeEvent;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeChangeEventExample extends Sprite
    {
        public function StorageVolumeChangeEventExample()
        {
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_MOUNT, mountEventHandler);
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_UNMOUNT, unmountEventHandler);
        }
        public function mountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            var volume:StorageVolume = event.storageVolume;
            trace("VOLUME MOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace("fileSystemType:", volume.fileSystemType);
            trace("isRemovable:", volume.isRemovable);
            trace("isWritable:", volume.isWritable);
            trace("drive:", volume.drive);
            trace("name:", volume.name);
            trace();
        }
        public function unmountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            trace("VOLUME UNMOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace();
        }        
    }
}

Avisos legales | Política de privacidad en línea

StorageVolume - AS3

Paquetesx

Elementos del lenguaje

Apéndices

Paquete flash.filesystem

drive

fileSystemType

isRemovable

isWritable

name

rootDirectory

StorageVolume