StyleManager

Paquete	fl.managers
Clase	public class StyleManager
Herencia	StyleManager Object

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

La clase StyleManager proporciona métodos estáticos que se pueden utilizar para obtener y definir estilos de una instancia de componente, de un tipo completo de componente o de todos los componentes de la interfaz de usuario en un documento de Flash. Los estilos se definen como valores que influyen en la visualización de un componente, incluido el relleno, los formatos de texto y los aspectos.

Ver los ejemplos

Propiedades públicas

Ocultar propiedades públicas heredadas

Mostrar propiedades públicas heredadas

	Propiedad		Definido por
		constructor : Object Una referencia a la clase de objeto o función constructora para una instancia de objeto determinada.	Object

Métodos públicos

Ocultar métodos públicos heredados

Mostrar métodos públicos heredados

	Método		Definido por
		StyleManager() Crea un nuevo objeto StyleManager.	StyleManager
		clearComponentStyle(component:Object, name:String):void [estática] Quita un estilo del componente especificado.	StyleManager
		clearStyle(name:String):void [estática] Quita un estilo global de todos los componentes de la interfaz de usuario de un documento.	StyleManager
		getComponentStyle(component:Object, name:String):Object [estática] Obtiene un estilo que existe en un componente concreto.	StyleManager
		getStyle(name:String):Object [estática] Obtiene un estilo global por nombre.	StyleManager
		hasOwnProperty(name:String):Boolean Indica si un objeto tiene definida una propiedad especificada.	Object
		isPrototypeOf(theClass:Object):Boolean Indica si hay una instancia de la clase Object en la cadena de prototipo del objeto especificado como parámetro.	Object
		propertyIsEnumerable(name:String):Boolean Indica si existe la propiedad especificada y si es enumerable.	Object
		registerInstance(instance:UIComponent):void [estática] Registra una instancia de componente con Style Manager.	StyleManager
		setComponentStyle(component:Object, name:String, style:Object):void [estática] Define un estilo en todas las instancias de un tipo de componente, por ejemplo, en todas las instancias de un componente Button o de un componente ComboBox.	StyleManager
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Establece la disponibilidad de una propiedad dinámica para operaciones de bucle.	Object
		setStyle(name:String, style:Object):void [estática] Define un estilo global para todos los componentes de la interfaz de usuario de un documento.	StyleManager
		toLocaleString():String Devuelve la representación de cadena de este objeto, con formato según las convenciones específicas de configuración regional.	Object
		toString():String Devuelve la representación de cadena del objeto especificado.	Object
		valueOf():Object Devuelve el valor simple del objeto especificado.	Object

Información sobre constructores

()

Información sobre

public function StyleManager()

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Crea un nuevo objeto StyleManager.

Información sobre métodos

clearComponentStyle

()

método

public static function clearComponentStyle(component:Object, name:String):void

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Quita un estilo del componente especificado.

Parámetros

	`component:Object` — Nombre del componente del que se va a quitar el estilo.

	`name:String` — Nombre del estilo que se va a quitar.

Elementos de API relacionados

clearStyle()
getComponentStyle()
setComponentStyle()

clearStyle

()

método

public static function clearStyle(name:String):void

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Quita un estilo global de todos los componentes de la interfaz de usuario de un documento.

Parámetros

name:String — Nombre del estilo global que se va a quitar.

Elementos de API relacionados

clearComponentStyle()
getStyle()
setStyle()

getComponentStyle

()

método

public static function getComponentStyle(component:Object, name:String):Object

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Obtiene un estilo que existe en un componente concreto.

Parámetros

	`component:Object` — Nombre de la instancia del componente en el que se va a buscar el estilo requerido.

	`name:String` — Nombre del estilo que se va a recuperar.

Valor devuelto

Object — Estilo solicitado del componente especificado. Esta función devuelve un valor null si no se encuentra el estilo especificado.

Elementos de API relacionados

clearComponentStyle()
getStyle()
setComponentStyle()

getStyle

()

método

public static function getStyle(name:String):Object

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Obtiene un estilo global por nombre.

Parámetros

name:String — Nombre del estilo que se va a recuperar.

Valor devuelto

Object — Valor del estilo global recuperado.

Elementos de API relacionados

clearStyle()
getComponentStyle()
setStyle()

registerInstance

()

método

public static function registerInstance(instance:UIComponent):void

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Registra una instancia de componente con Style Manager. Tras crear una instancia de un componente, ésta se puede registrar con Style Manager para que se notifiquen los cambios de estilo. Las instancias de componente se pueden registrar para recibir notificaciones sobre los cambios de estilo generales o basados en componentes.

Parámetros

instance:UIComponent — Instancia de componente que se va a registrar en la administración de estilos.

setComponentStyle

()

método

public static function setComponentStyle(component:Object, name:String, style:Object):void

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Define un estilo en todas las instancias de un tipo de componente, por ejemplo, en todas las instancias de un componente Button o de un componente ComboBox.

Parámetros

	`component:Object` — Tipo de componente, por ejemplo, Button o ComboBox. Este parámetro también acepta una clase o instancia de componente que se pueda utilizar para identificar todas las instancias de un tipo de componente.

	`name:String` — Nombre del estilo que se va a definir.

	`style:Object` — Objeto de estilo que describe el estilo que se va a definir.

Elementos de API relacionados

clearComponentStyle()
getComponentStyle()
setStyle()

setStyle

()

método

public static function setStyle(name:String, style:Object):void

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Define un estilo global para todos los componentes de la interfaz de usuario de un documento.

Parámetros

	`name:String` — Valor de cadena que asigna un nombre al estilo que se va a definir.

	`style:Object` — Objeto de estilo que se va a definir. El valor de esta propiedad depende del estilo que define el usuario. Por ejemplo, si el estilo se define como "textFormat", la propiedad de estilo se debería definir como un objeto TextFormat. Discrepancia entre el nombre del estilo y el valor de la propiedad de estilo puede provocar que el componente actúe de forma incorrecta.

Elementos de API relacionados

clearStyle()
getStyle()
setComponentStyle()

Ejemplos Cómo utilizar este ejemplo

StyleManagerExample.as

Este ejemplo muestra cómo crear de forma dinámica un componente DataGrid y detectar sus eventos.

Para realizar el ejemplo, siga estos pasos:

Añada los componentes DataGrid, Button, Label y TextArea a la biblioteca.
Guarde este código como StyleManagerExample.as en el mismo directorio que el archivo FLA.
Defina la clase Document como StyleManagerExample en el archivo FLA.

package
{
    import fl.controls.Button;
    import fl.controls.DataGrid;
    import fl.controls.Label;
    import fl.controls.TextArea;
    import fl.core.UIComponent;
    import fl.managers.FocusManager;
    import fl.managers.StyleManager;
    import flash.display.InteractiveObject;
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;
    
    public class StyleManagerExample extends Sprite 
    {
        private var btn:Button;
        private var ta1:TextArea;
        private var ta2:TextArea;
        private var ta3:TextArea;
        private var ta4:TextArea;
        private var description:Label;
        private var dg:DataGrid;
        private var formatForInstance:TextFormat;
        private var formatForGlobal:TextFormat;
        
        private var testStringHTML:String = "<body><span class='heading'>Hello </span>World...</body>";
        private var testString:String = "Lorem ipsum dolor sit amet, consectetuer adipiscing elit. Fusce vitae turpis id nibh suscipit tincidunt. Quisque nulla dui, elementum eget, rutrum in, ultricies nec, erat. Donec ante turpis, lacinia eget, semper ac, consequat eget, neque. Maecenas eleifend pharetra quam. Quisque suscipit nibh a ipsum. Donec sit amet mi eu ligula volutpat imperdiet. Ut quis velit quis lectus laoreet eleifend. Aliquam pulvinar lorem. Cras ultrices felis sit amet urna. Cras viverra porttitor est. Nulla justo. Sed scelerisque."
        
        public function StyleManagerExample() {
            setupComponents();
            setupUI();
            setupStyles();
        }
        private function setupUI():void {
            var setInstanceStyleBtn:Button = new Button();
            var clearInstanceStyleBtn:Button = new Button();
            var setClassStyleBtn:Button = new Button();
            var clearClassStyleBtn:Button = new Button();
            var setGlobalStyleBtn:Button = new Button();
            var clearGlobalStyleBtn:Button = new Button();
            
            setInstanceStyleBtn.label = "Set Instance Style";
            clearInstanceStyleBtn.label = "Clear Instance Style";
            setClassStyleBtn.label = "Set Class Style";
            clearClassStyleBtn.label = "Clear Class Style";
            setGlobalStyleBtn.label = "Set Global Style";
            clearGlobalStyleBtn.label = "Clear Global Style";
            setInstanceStyleBtn.focusEnabled = false;
            clearInstanceStyleBtn.focusEnabled = false;
            setClassStyleBtn.focusEnabled = false;
            clearClassStyleBtn.focusEnabled = false;
            setGlobalStyleBtn.focusEnabled = false;
            clearGlobalStyleBtn.focusEnabled = false;
            
            setInstanceStyleBtn.move(10,310);
            clearInstanceStyleBtn.move(10,340);
            setClassStyleBtn.move(140,310);
            clearClassStyleBtn.move(140,340);
            setGlobalStyleBtn.move(270,310);
            clearGlobalStyleBtn.move(270,340);
            setInstanceStyleBtn.setSize(120,24);
            clearInstanceStyleBtn.setSize(120,24);
            setClassStyleBtn.setSize(120,24);
            clearClassStyleBtn.setSize(120,24);
            setGlobalStyleBtn.setSize(120,24);
            clearGlobalStyleBtn.setSize(120,24);
            
            setInstanceStyleBtn.addEventListener(MouseEvent.CLICK,setInstanceStyle);
            clearInstanceStyleBtn.addEventListener(MouseEvent.CLICK,clearInstanceStyle);
            setClassStyleBtn.addEventListener(MouseEvent.CLICK,setClassStyle);
            clearClassStyleBtn.addEventListener(MouseEvent.CLICK,clearClassStyle);
            setGlobalStyleBtn.addEventListener(MouseEvent.CLICK,setGlobalStyle);
            clearGlobalStyleBtn.addEventListener(MouseEvent.CLICK,clearGlobalStyle);

            description = new Label();
            description.move(10, 370);
            description.autoSize = TextFieldAutoSize.LEFT;
            description.text = "";

            addChild(setInstanceStyleBtn);
            addChild(clearInstanceStyleBtn);
            addChild(setClassStyleBtn);
            addChild(clearClassStyleBtn);
            addChild(setGlobalStyleBtn);
            addChild(clearGlobalStyleBtn);
            addChild(description);
        }
        private function setupComponents():void {
            dg = new DataGrid();
            dg.addItem( { Name:"John Alpha",     Number:"555-123-0101" } );
            dg.addItem( { Name:"Mary Bravo",     Number:"555-372-3322" } );
            dg.addItem( { Name:"Trevor Gamma", Number:"555-485-1212" } );
            dg.addItem( { Name:"Susan Delta",     Number:"555-987-3434" } );        
            dg.move(10,10);
            dg.setSize(200,290);
            dg.columns = ["Name","Number"];
            addChild(dg);
            
            ta1 = new TextArea();
            ta1.move(220,10);
            ta1.setSize(150,140);
            ta1.text = testString;
            ta1.tabEnabled = true;
            addChild(ta1);
            
            ta2 = new TextArea();
            ta2.move(380,10);
            ta2.setSize(150,140);
            ta2.text = testString;
            ta2.tabEnabled = true;
            addChild(ta2);
            
            ta3 = new TextArea();
            ta3.move(220,160);
            ta3.setSize(150,140);
            ta3.text = testString;
            ta3.tabEnabled = true;
            addChild(ta3);
            
            ta4 = new TextArea();
            ta4.move(380,160);
            ta4.setSize(150,140);
            ta4.text = testString;
            ta4.tabEnabled = true;
            addChild(ta4);
        }
        private function setupStyles():void {
            formatForGlobal = new TextFormat();
            formatForGlobal.font = "Georgia";
            formatForGlobal.size = 10;
            formatForInstance = new TextFormat();
            formatForInstance.underline = true;            
        }
        private function setInstanceStyle(e:MouseEvent):void {
            var fm:FocusManager = new FocusManager(this);
            var uiComponent:UIComponent = fm.getFocus() as UIComponent;
            if(uiComponent is TextArea) {
                uiComponent.setStyle("textFormat",formatForInstance);    
                description.text = "The TextArea object with focus is now underlined.";            
            }
        }
        private function clearInstanceStyle(e:MouseEvent):void {
            var fm:FocusManager = new FocusManager(this);
            var uiComponent:UIComponent = fm.getFocus() as UIComponent;
            if(uiComponent is TextArea) {
                uiComponent.clearStyle("textFormat");
                description.text = "The TextArea object with focus is no longer underlined.";
            }
        }
        private function setClassStyle(e:MouseEvent):void {
            var c:Class = TextArea;
            var styleName:String = "textPadding";
            var value:Number = 10;
            StyleManager.setComponentStyle(c,styleName,value);    
            description.text = "Padding for all TextArea instances is now 10.";
        }
        private function clearClassStyle(e:MouseEvent):void {
            var styleName:String = "textPadding";
            var c:Class = TextArea;
            StyleManager.clearComponentStyle(c,styleName);                    
            description.text = "TextArea padding has been reset to the default.";
        }
        private function setGlobalStyle(e:MouseEvent):void {            
            var styleName:String = "textFormat";
            var value:Object = formatForGlobal;
            StyleManager.setStyle(styleName,value);
            description.text = "All components now use font Georgia size 10.";
        }
        private function clearGlobalStyle(e:MouseEvent):void {
            var styleName:String = "textFormat";
            StyleManager.clearStyle(styleName);    
            description.text = "Font style for all components has been cleared.";
        }
    }
}

Avisos legales | Política de privacidad en línea

StyleManager - AS3 Flash

Paquetesx

Elementos del lenguaje

Apéndices

Paquete fl.managers

StyleManager

clearComponentStyle

clearStyle

getComponentStyle

getStyle

registerInstance

setComponentStyle

setStyle