FocusManager  - AS3 Flash

Gets or sets the current default button.

The default button is the button on a form that dispatches a click event when the Enter key is pressed, depending on where focus is at the time.

Gets or sets a value that indicates whether the default button is enabled. If this value is set to true, the focus manager monitors the Enter key and dispatches a click event on the default button if the Enter key is pressed when a component that is not a Button component has focus. If this value is set to false, the focus manager does not monitor the Enter key. Components that use the Enter key set this property to false to prevent a click event from being dispatched on the default button, if one exists, when a user presses the Enter key.

Base DisplayObjectContainer for the IFocusManager, usually the stage.

Gets the next unique tab index to use in this tab loop.

Gets or sets a value that indicates whether a component that has focus should be marked with a visual indicator of focus.

Creates a new FocusManager instance.

A focus manager manages focus within the children of a DisplayObjectContainer object.

Activates the FocusManager instance.

The FocusManager instance adds event handlers that allow it to monitor focus-related keyboard and mouse activity.

Deactivates the FocusManager.

The FocusManager removes the event handlers that allow it to monitor focus-related keyboard and mouse activity.

Retrieves the interactive object that contains the given object, if any. The player can set focus to a subcomponent of a Flash component; this method determines which interactive object has focus from the component perspective.

Parameters

Gets the interactive object that currently has focus. Adobe recommends calling this method instead of using the Stage object because this method indicates which component has focus. The Stage might return a subcomponent in that component.

Retrieves the interactive object that would receive focus if the user pressed the Tab key to navigate to the next object. This method retrieves the object that currently has focus if there are no other valid objects in the application.

Parameters

Sets the showFocusIndicator value to false and removes the visual focus indicator from the object that has focus, if any.

Sets focus on an IFocusManagerComponent component. This method does not check for component visibility, enabled state, or other conditions.

Parameters

Sets the showFocusIndicator value to true and draws the visual focus indicator on the object with focus, if any.

To run the example, follow these steps:

1. Add the TextInput component to the library.
2. Save this code as FocusManagerExample.as in the same directory as your FLA file.
3. Set the Document class in the FLA file to FocusManagerExample.

package
{
    import fl.controls.TextInput;
    import fl.managers.FocusManager;
    import flash.display.InteractiveObject;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.utils.Timer;

    public class FocusManagerExample extends Sprite 
    {
        private var fm:FocusManager;
        
        public function FocusManagerExample() {
            buildGridOfTextInputs();

            fm = new FocusManager(this);
            var t:Timer = new Timer(1000);
            t.addEventListener(TimerEvent.TIMER,secondPassed);
            t.start();
        }
        private function buildGridOfTextInputs():void {
            var rowSpacing:uint = 30;
            var colSpacing:uint = 110;
            var totalRows:uint = 4;
            var totalCols:uint = 3;
            var i:uint;
            
            for(i = 0; i < totalRows * totalCols; i++) {
                var ti:TextInput = new TextInput()
                ti.name = "component"+i.toString();
                ti.addEventListener(FocusEvent.FOCUS_IN,focusChange);
                ti.setSize(100,20);
                ti.x = 10 + ((i % totalCols) * colSpacing);
                ti.y = 10 + (Math.floor(i / totalCols) * rowSpacing);
                ti.tabEnabled = true;
                addChild(ti);
            }
        }
        private function secondPassed(e:TimerEvent):void {
            var nextComponent:InteractiveObject = fm.getNextFocusManagerComponent();
            fm.setFocus(nextComponent);    
        }
        
        private function focusChange(e:FocusEvent):void {
            trace("Focus change: " + e.target.name);
        }
    }
}