Zwei verschiedene Ereignistypen liefern wichtige Nutzungsdaten:
netStatus
und
mediaTypeData
. Außerdem kann ein Timer verwendet werden, um die Position des NetStream-Abspielkopfs regelmäßig aufzuzeichnen.
netStatus
-Ereignisse stellen Informationen zur Verfügung, über die Sie feststellen können, welchen Teil eines Streams ein Benutzer betrachtet hat. Die transition-Ereignisse für Puffer- und RTMFP-Streams führen ebenfalls zu einem
netStatus
-Ereignis.
mediaTypeData
-Ereignisse liefern Informationen zu Metadaten und XMP-Daten. Das Netstream.Play.Complete-Ereignis wird als
mediaTypeData
-Ereignis ausgelöst. Auch andere im Stream eingebettete Daten sind über
mediaTypeData
-Ereignisse verfügbar, wie Cue-Points, Text und Bilder.
Das folgende Beispiel veranschaulicht die Erstellung einer Klasse, die status- und data-Ereignisse von aktiven NetStream-Objekten in einer Anwendung überwacht. Normalerweise lädt eine solche Klasse die zu analysierenden Daten zur Erfassung auf einen Server.
package com.adobe.example
{
import flash.events.NetDataEvent;
import flash.events.NetMonitorEvent;
import flash.events.NetStatusEvent;
import flash.net.NetMonitor;
import flash.net.NetStream;
public class NetStreamEventMonitor
{
private var netmon:NetMonitor;
private var heartbeat:Timer = new Timer( 5000 );
public function NetStreamEventMonitor()
{
//Create NetMonitor object
netmon = new NetMonitor();
netmon.addEventListener( NetMonitorEvent.NET_STREAM_CREATE, newNetStream );
//Start the heartbeat timer
heartbeat.addEventListener( TimerEvent.TIMER, onHeartbeat );
heartbeat.start();
}
//On new NetStream
private function newNetStream( event:NetMonitorEvent ):void
{
trace( "New Netstream object");
var stream:NetStream = event.netStream;
stream.addEventListener(NetDataEvent.MEDIA_TYPE_DATA, onStreamData);
stream.addEventListener(NetStatusEvent.NET_STATUS, onStatus);
}
//On data events from a NetStream object
private function onStreamData( event:NetDataEvent ):void
{
var netStream:NetStream = event.target as NetStream;
trace( "Data event from " + netStream.info.uri + " at " + event.timestamp );
switch( event.info.handler )
{
case "onMetaData":
//handle metadata;
break;
case "onXMPData":
//handle XMP;
break;
case "onPlayStatus":
//handle NetStream.Play.Complete
case "onImageData":
//handle image
break;
case "onTextData":
//handle text
break;
default:
//handle other events
}
}
//On status events from a NetStream object
private function onStatus( event:NetStatusEvent ):void
{
trace( "Status event from " + event.target.info.uri + " at " + event.target.time );
//handle status events
}
//On heartbeat timer
private function onHeartbeat( event:TimerEvent ):void
{
var streams:Vector.<NetStream> = netmon.listStreams();
for( var i:int = 0; i < streams.length; i++ )
{
trace( "Heartbeat on " + streams[i].info.uri + " at " + streams[i].time );
//handle heartbeat event
}
}
}
}
