Grundlagen zu Netzwerken und Kommunikation

Mithilfe des NetworkInfo-Objekts können Sie die Hardware- und Softwareschnittstellen ermitteln, die für Ihre Anwendung zur Verfügung stehen. Das NetworkInfo-Objekt ist ein singleton -Objekt; Sie müssen kein solches Objekt erstellen. Verwenden Sie stattdessen die statische Klasseneigenschaft networkInfo , um auf das einzelne NetworkInfo-Objekt zuzugreifen. Das NetworkInfo-Objekt löst auch ein networkChange -Ereignis aus, wenn eine der verfügbaren Schnittstellen sich ändert.

Rufen Sie die findInterfaces() -Methode auf, um eine Liste der NetworkInterface-Objekte abzurufen. Jedes NetworkInterface-Objekt in der Liste beschreibt eine der verfügbaren Schnittstellen. Das NetworkInterface-Objekt bietet Informationen wie die IP-Adresse, Hardwareadresse und maximale Übertragungseinheit. Weiterhin gibt es an, ob die Schnittstelle aktiv ist.

Mit dem folgenden Codebeispiel werden die NetworkInterface-Eigenschaften jeder Schnittstelle auf dem Clientcomputer verfolgt:

package { 
import flash.display.Sprite; 
import flash.net.InterfaceAddress; 
import flash.net.NetworkInfo; 
import flash.net.NetworkInterface; 
 
public class NetworkInformationExample extends Sprite 
{ 
    public function NetworkInformationExample() 
    { 
        var networkInfo:NetworkInfo = NetworkInfo.networkInfo; 
        var interfaces:Vector.<NetworkInterface> = networkInfo.findInterfaces(); 
         
        if( interfaces != null ) 
        { 
            trace( "Interface count: " + interfaces.length ); 
            for each ( var interfaceObj:NetworkInterface in interfaces ) 
            { 
                trace( "\nname: "             + interfaceObj.name ); 
                trace( "display name: "     + interfaceObj.displayName ); 
                trace( "mtu: "                 + interfaceObj.mtu ); 
                trace( "active?: "             + interfaceObj.active ); 
                trace( "parent interface: " + interfaceObj.parent ); 
                trace( "hardware address: " + interfaceObj.hardwareAddress ); 
                if( interfaceObj.subInterfaces != null ) 
                { 
                    trace( "# subinterfaces: " + interfaceObj.subInterfaces.length ); 
                } 
                trace("# addresses: "     + interfaceObj.addresses.length ); 
                for each ( var address:InterfaceAddress in interfaceObj.addresses ) 
                { 
                    trace( "  type: "           + address.ipVersion ); 
                    trace( "  address: "         + address.address ); 
                    trace( "  broadcast: "         + address.broadcast ); 
                    trace( "  prefix length: "     + address.prefixLength ); 
                } 
            }             
        } 
    }     
} 
}

Weitere Informationen finden Sie unter:

• NetworkInfo

• NetworkInterface

• InterfaceAddress

• Flexpert: Detecting the network connection type with Flex 4.5

Die AIR-Anwendung kann in Umgebungen mit unsicheren und sich ändernden Netzwerkverbindungen ausgeführt werden. Adobe AIR unterstützt eine Anwendung bei der Verwaltung von Verbindungen zu Onlineressourcen durch Senden eines Netzwerkänderungsereignisses, wenn der Status einer Netzwerkverbindung zu verfügbar oder nicht verfügbar wechselt. Sowohl das NetworkInfo-Objekt als auch das NativeApplication-Objekt der Anwendung lösen das networkChange -Ereignis aus. Fügen Sie einen Listener hinzu, um auf dieses Ereignis reagieren zu können:

NetworkInfo.networkInfo.addEventListener(Event.NETWORK_CHANGE, onNetworkChange); 

Definieren Sie ferner eine Ereignisprozedurfunktion:

function onNetworkChange(event:Event) 
{ 
    //Check resource availability 
} 

Das networkChange -Ereignis weist nicht auf eine Änderung der gesamten Netzwerkaktivität hin, sondern nur darauf, dass sich eine einzelne Netzwerkverbindung geändert hat. AIR unternimmt keinen Versuch, die Bedeutung der Netzwerkänderung zu interpretieren. Ein vernetzter Computer kann über zahlreiche reale und virtuelle Verbindungen verfügen. Der Verlust einer Verbindung führt nicht zwangsläufig zum Verlust einer Ressource. Andererseits sind neue Verbindungen auch keine Garantie für eine bessere Ressourcenverfügbarkeit. Manchmal kann eine neue Verbindung sogar den Zugriff auf zuvor verfügbare Ressourcen blockieren (z. B. beim Zugreifen auf ein VPN).

Im Allgemeinen kann eine Anwendung nur herausfinden, ob eine Verbindung zu einer Remoteressource hergestellt werden kann, indem sie versucht, die Verbindung herzustellen. Die Dienstüberwachungsarchitektur bietet eine ereignisgestützte Methode, auf Änderungen der Netzwerkverbindung mit einem bestimmten Host zu reagieren.

DNS-Ressourcendatensätze (DNS = Domain Name System) können mithilfe der DNSResolver-Klasse ermittelt werden. DNS-Ressourcendatensätze bieten Informationen wie die IP-Adresse eines Domänennamens und den Domänennamen einer IP-Adresse. Sie können folgende Arten von DNS-Ressourcendatensätzen ermitteln:

• ARecord – IPv4-Adresse für einen Host.

• AAAARecord – IPv6-Adresse für einen Host.

• MXRecord – E-Mail-Datensatz für einen Host.

• PTRRecord – Hostname für eine IP-Adresse.

• SRVRecord – Dienstdatensatz für einen Dienst..

Zum Ermitteln eines Datensatzes übergeben Sie einen Abfragestring und das Klassenobjekt für den jeweiligen Datensatztyp an die lookup() -Methode des DNSResolver-Objekts. Der verwendete Abfragestring richtet sich nach dem Typ des Datensatzes:

Mit dem folgenden Codebeispiel wird die IP-Adresse des Hosts „example.com“ ermittelt.

package 
{ 
    import flash.display.Sprite; 
    import flash.events.DNSResolverEvent; 
    import flash.events.ErrorEvent; 
    import flash.net.dns.ARecord; 
    import flash.net.dns.DNSResolver; 
 
    public class DNSResolverExample extends Sprite 
    { 
         
        public function DNSResolverExample() 
        { 
            var resolver:DNSResolver = new DNSResolver(); 
            resolver.addEventListener( DNSResolverEvent.LOOKUP, lookupComplete ); 
            resolver.addEventListener( ErrorEvent.ERROR, lookupError ); 
 
            resolver.lookup( "example.com.", ARecord ); 
        } 
         
        private function lookupComplete( event:DNSResolverEvent ):void 
        { 
            trace( "Query string: " + event.host ); 
            trace( "Record count: " + event.resourceRecords.length ); 
            for each( var record:* in event.resourceRecords ) 
            { 
                if( record is ARecord ) trace( record.address ); 
            } 
             
        } 
 
        private function lookupError( error:ErrorEvent ):void 
        { 
            trace("Error: " + error.text ); 
        } 
    } 
}

Weitere Informationen finden Sie unter:

• DNSResolver

• DNSResolverEvent

• ARecord

• AAAARecord

• MXRecord

• PTRRecord

• SRVRecord