Gemeinsame Objekte

Gemeinsame Objekte funktionieren wie Cookies. Mit der SharedObject -Klasse können Sie Daten auf der lokalen Festplatte des Benutzers speichern und diese Daten während derselben Sitzung oder in einer späteren Sitzung aufrufen. Anwendungen können nur auf ihre eigenen SharedObject-Daten zugreifen und dies nur, wenn sie auf derselben Domäne ausgeführt werden. Die Daten werden nicht an den Server geschickt und sind für andere Anwendungen, die in anderen Domänen ausgeführt werden, nicht zugänglich. Sie können jedoch den Anwendungen in derselben Domäne den Zugang ermöglichen.

Zum Erstellen eines SharedObject -Objekts verwenden Sie die SharedObject.getLocal() -Methode. Für diese Methode gilt folgende Syntax:

SharedObject.getLocal("objectName" [, pathname]): SharedObject

Im nachstehenden Beispiel wird ein gemeinsames Objekt mit dem Namen mySO erstellt:

public var mySO:SharedObject; 
mySO = SharedObject.getLocal("preferences");

Dies erstellt auf dem Client eine Datei mit dem Namen „preferences.sol“.

Der Begriff lokal bezieht sich auf den Speicherort des gemeinsamen Objekts. In diesem Fall speichert Adobe®Flash® Player die SharedObject-Datei lokal im Stammverzeichnis des Clients.

Wenn Sie ein gemeinsames Objekt erstellen, legt Flash Player in der Sandbox einen neuen Ordner für die Anwendung und die Domäne an. Flash Player erstellt auch eine *.sol-Datei, in der die SharedObject-Daten gespeichert werden. Der Standardspeicherort dieser Datei ist ein Unterverzeichnis des Stammverzeichnisses des Benutzers. In der nachstehenden Tabelle sind die Standardspeicherorte dieses Verzeichnisses aufgeführt:

c:/Documents and Settings/username/Application Data/Macromedia/Flash Player/#SharedObjects

c:/Users/username/AppData/Roaming/Macromedia/Flash Player/#SharedObjects

/Users/username/Library/Preferences/Macromedia/Flash Player/#SharedObjects/web_domain/path_to_application/application_name/object_name.sol

/home/username/.macromedia/Flash_Player/#SharedObjects/web_domain/path_to_application/application_name/object_name.sol

Unter dem Verzeichnis #SharedObjects befindet sich ein nach dem Zufallsprinzip benanntes Verzeichnis. Darunter liegt ein weiteres Verzeichnis, das den Hostnamen, den Pfad der Anwendung und schließlich den Namen der *.sol-Datei enthält.

Wenn Sie zum Beispiel eine Anwendung mit dem Namen MyApp.swf auf dem lokalen Host in einem Unterverzeichnis namens /sos anfordern, legt Flash Player die *.sol-Datei in Windows XP am folgenden Speicherort ab:

c:/Documents and Settings/fred/Application Data/Macromedia/Flash Player/#SharedObjects/KROKWXRK/#localhost/sos/MyApp.swf/data.sol

Standardmäßig kann Flash permanente SharedObject-Objekte von bis zu 100 KB pro Domäne lokal speichern. Der Benutzer kann diesen Wert ändern. Wenn die Anwendung versucht, Daten in einem gemeinsamen Objekt zu speichern, und dabei die 100-KB-Grenze überschritten wird, zeigt Flash Player das Dialogfeld zum lokalen Speichern an. Hier kann der Benutzer die Zuteilung von mehr Speicherplatz für die anfordernde Domäne genehmigen oder verweigern.

Wenn Sie mit getLocal() oder getRemote() ein lokales oder entferntes SharedObject erstellen, gibt es einen optionalen Parameter namens secure , mit dem festgelegt werden kann, ob der Zugriff auf dieses gemeinsame Objekt auf SWF-Dateien beschränkt ist, die über eine HTTPS-Verbindung bereitgestellt werden. Wenn dieser Parameter auf true eingestellt ist und Ihre SWF-Datei über HTTPS bereitgestellt wird, erstellt Flash Player ein neues sicheres gemeinsames Objekt oder ruft einen Verweis auf ein vorhandenes sicheres gemeinsames Objekt ab. Dieses sichere gemeinsame Objekt kann nur durch SWF-Dateien gelesen oder geschrieben werden, die über HTTPS bereitgestellt werden und die SharedObject.getLocal() mit der Einstellung true für den secure-Parameter aufrufen. Wenn dieser Parameter auf false eingestellt ist und Ihre SWF-Datei über HTTPS bereitgestellt wird, erstellt Flash Player ein neues gemeinsames Objekt oder ruft einen Verweis auf ein vorhandenes gemeinsames Objekt ab.

An diesem gemeinsamen Objekt können nur SWF-Dateien Lese- oder Schreibvorgänge durchführen, die über andere Verbindungen als HTTPS bereitgestellt werden. Wenn die SWF-Datei über eine andere Verbindung als HTTPS bereitgestellt wird und Sie diesen Parameter auf true einstellen, schlägt die Erstellung des neuen gemeinsamen Objekts (bzw. der Zugriff auf ein zuvor erstelltes sicheres gemeinsames Objekt) fehl. Es wird ein Fehler ausgelöst und das gemeinsame Objekt wird auf null gesetzt. Wenn Sie versuchen, den folgenden Codeausschnitt über eine andere Verbindung als HTTPS auszuführen, löst die SharedObject.getLocal() -Methode einen Fehler aus:

try 
{ 
    var so:SharedObject = SharedObject.getLocal("contactManager", null, true); 
} 
catch (error:Error) 
{ 
    trace("Unable to create SharedObject."); 
}

Unabhängig vom Wert dieses Parameters belegen die erstellten gemeinsamen Objekte einen Teil des von einer Domäne belegten Speicherplatzes.

Werte werden in der data -Eigenschaft von gemeinsamen Objekten gespeichert. Sie können jeden Wert innerhalb einer gemeinsamen Objektinstanz durchlaufen. Verwenden Sie hierzu eine for..in -Schleife, wie im folgenden Beispiel gezeigt:

var so:SharedObject = SharedObject.getLocal("test"); 
so.data.hello = "world"; 
so.data.foo = "bar"; 
so.data.timezone = new Date().timezoneOffset; 
for (var i:String in so.data) 
{ 
    trace(i + ":\t" + so.data[i]); 
}

Sie zerstören ein SharedObject auf dem Client, indem Sie die SharedObject.clear() -Methode verwenden. Die Verzeichnisse im Standardpfad der gemeinsamen Objekte der Anwendung werden dabei nicht zerstört.

Im folgenden Beispiel wird die SharedObject-Datei auf dem Client gelöscht:

public function destroySharedObject():void { 
    mySO.clear(); 
}

Das folgende Beispiel zeigt, dass Sie einfache Objekte, wie beispielsweise Date-Objekte, in einem SharedObject -Objekt speichern können, ohne diese Objekte manuell zu serialisieren oder zu deserialisieren.

Im nachstehenden Beispiel werden Sie zunächst als neuer Besucher begrüßt. Wenn Sie auf „Abmelden“ klicken, speichert die Anwendung das aktuelle Datum in einem gemeinsamen Objekt. Wenn Sie diese Anwendung das nächste Mal starten oder die Seite aktualisieren, gibt die Anwendung die Uhrzeit Ihrer Abmeldung an.

Um zu sehen, wie die Anwendung funktioniert, starten Sie die Anwendung, klicken auf „Abmelden“ und aktualisieren anschließend die Seite. Die Anwendung zeigt das Datum und die Uhrzeit der Abmeldung bei Ihrem letzten Besuch. Sie können die gespeicherten Informationen jederzeit löschen. Klicken Sie dazu auf die Schaltfläche „Delete LSO“.

<?xml version="1.0"?> 
<!-- lsos/WelcomeMessage.mxml --> 
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" initialize="initApp()"> 
  <mx:Script><![CDATA[ 
  public var mySO:SharedObject; 
  [Bindable] 
  public var welcomeMessage:String; 
 
  public function initApp():void { 
     mySO = SharedObject.getLocal("mydata"); 
     if (mySO.data.visitDate==null) { 
        welcomeMessage = "Hello first-timer!" 
     } else { 
        welcomeMessage = "Welcome back. You last visited on " + 
           getVisitDate(); 
     } 
  } 
 
  private function getVisitDate():Date { 
     return mySO.data.visitDate; 
  } 
 
  private function storeDate():void { 
     mySO.data.visitDate = new Date(); 
     mySO.flush(); 
  } 
  
  private function deleteLSO():void { 
     // Deletes the SharedObject from the client machine. 
     // Next time they log in, they will be a 'first-timer'. 
     mySO.clear(); 
  } 
  
  ]]></mx:Script> 
  <mx:Label id="label1" text="{welcomeMessage}"/> 
  <mx:Button label="Log Out" click="storeDate()"/> 
  <mx:Button label="Delete LSO" click="deleteLSO()"/> 
</mx:Application>