FileReference  - AS3

Das Erstellungsdatum der Datei auf der lokalen Festplatte. Falls das Objekt keine Daten enthält, gibt der Aufruf dieser Eigenschaft null zurück.

Hinweis: Wenn ein Betriebssystem nicht creationDate als Eigenschaft hat, ist in solchen Fällen CreationDate gleich lastModifiedDate.

Verwandte API-Elemente

Der Macintosh-Erstellertyp der Datei, der nur in Mac OS-Versionen vor Mac OS X verwendet wird. In Windows oder Linux ist diese Eigenschaft null. Falls das FileReference-Objekt noch keine Daten enthält, gibt der Aufruf dieser Eigenschaft null zurück.

Verwandte API-Elemente

Das ByteArray-Objekt, das die Daten aus der geladenen Datei nach einem erfolgreichen Aufruf der load()-Methode repräsentiert.

Verwandte API-Elemente

Die Dateinamenerweiterung.

Eine Dateierweiterung ist der Teil des Namens, der hinter dem letzten Punkt („.“) steht. Der Punkt selbst gehört nicht zur Erweiterung. Wenn der Dateiname keinen Punkt enthält, ist die Erweiterung null.

Hinweis: Sie sollte den Dateityp mit der extension-Eigenschaft bestimmen; verwenden Sie nicht die Eigenschaften creator oder type. Sie können die Eigenschaften creator und type als veraltet betrachten. Sie gelten für ältere Mac OS-Versionen.

Das Datum, an dem die Datei auf der lokalen Festplatte zuletzt geändert wurde. Falls das FileReference-Objekt noch keine Daten enthält, gibt der Aufruf dieser Eigenschaft null zurück.

Verwandte API-Elemente

Der Name der Datei auf der lokalen Festplatte. Wenn das FileReference-Objekt keine Daten enthält (aus einem Aufruf von FileReference.download() oder FileReference.browse()), löst Flash Player einen Fehler aus, wenn Sie versuchen, den Wert diese Eigenschaft abzurufen.

Den Eigenschaften eines FileReference-Objekts werden durch einen Aufruf der Methode browse() Werte zugewiesen. Im Unterschied zu anderen FileReference-Eigenschaften wird beim Aufruf der Methode download() die Eigenschaft name erst bei Auslösung des Ereignisses select mit Daten aktualisiert.

Verwandte API-Elemente

Bestimmen Sie, ob der Anwendung die Berechtigung zum Zugriff auf das Dateisystem erteilt wurde.

Verwandte API-Elemente

Die Größe der Datei auf der lokalen Festplatte in Byte.

Hinweis: In der ersten Version von ActionScript 3.0 wurde die size-Eigenschaft als uint-Objekt definiert, das Dateigrößen bis zu ca. 4 GB unterstützt. Sie wird jetzt als Number-Objekt implementiert, um größere Dateien zu unterstützen.

Verwandte API-Elemente

Der Dateityp.

In Windows oder Linux ist diese Eigenschaft die Dateierweiterung. Auf Macintosh-Systemen ist diese Eigenschaft der vierbuchstabige Dateityp, der nur in Mac OS-Versionen, die älter als Mac OS X sind, verwendet wird. Wenn das FileReference-Objekt keine Daten enthält, gibt ein Aufruf zum Abrufen des Werts diese Eigenschaft null zurück.

Für Windows, Linux und Mac OS X die Dateierweiterung, also der Teil der name-Eigenschaft, der auf das letzte Vorkommen des Punkts (.) folgt. Zeichen - identifiziert den Dateityp.

Verwandte API-Elemente

Erstellt ein neues FileReference-Objekt. Sobald dieses Objekt mit Daten versehen ist, wird ein FileReference-Objekt zu einer Datei auf der lokalen Festplatte eines Benutzers.

Verwandte API-Elemente

Zeigt ein Dialogfeld für die Dateisuche an, in dem der Benutzer eine Datei für einen Upload-Vorgang auswählen kann. Das Dialogfeld stammt vom Betriebssystem des Benutzers. Der Benutzer kann eine Datei aus dem lokalen System oder aus anderen Systemen auswählen, z. B. über einen UNC-Pfad (Windows).

Hinweis: Die in Adobe AIR verfügbare File-Klasse enthält Methoden für den Zugriff auf spezifischere Dialogfelder für die Auswahl von Systemdateien. Diese Methoden sind File.browseForDirectory(), File.browseForOpen(), File.browseForOpenMultiple() und File.browseForSave().

Wenn diese Methode aufgerufen wird und der Benutzer erfolgreich eine Datei auswählt, werden die Eigenschaften dieses FileReference-Objekts mit den Eigenschaftendaten der Datei aktualisiert. Bei jedem nachfolgenden Aufruf der Methode FileReference.browse() werden die Eigenschaften des FileReference-Objekts auf die vom Benutzer im Dialogfeld ausgewählte Datei zurückgesetzt. Es kann immer nur eine browse()- oder download()-Sitzung durchgeführt werden (da immer nur ein Dialogfeld aufgerufen werden kann).

Mit dem Parameter typeFilter können Sie festlegen, welche Dateien im Dialogfeld angezeigt werden.

In Flash Player 10 und Flash Player 9 mit Update 5 können Sie diese Methode nur als Reaktion auf ein Benutzerereignis erfolgreich aufrufen, z. B. in einer Ereignisprozedur für ein Mausklick- oder Tastendruckereignis. Andernfalls führt das Aufrufen dieser Methode dazu, dass Flash Player einen Ausnahmefehler ausgibt.

Beachten Sie, dass aufgrund neuer zusätzlicher Funktionalität von Flash Player beim Veröffentlichen in Flash Player 10 immer nur einer der folgenden Vorgänge aktiv sein kann: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Ansonsten gibt Flash Player einen Laufzeitfehler (Code 2174) aus. Stoppen Sie den laufenden Vorgang mithilfe von FileReference.cancel(). Diese Einschränkung betrifft lediglich Flash Player 10. Ältere Versionen von Flash Player sind von den Einschränkungen bezüglich gleichzeitig ausgeführter Vorgänge nicht betroffen.

In Adobe AIR wird das Dialogfeld zur Dateiauswahl nicht immer vor Fenstern angezeigt, die „Eigentum“ eines anderen Fensters sind (Fenster, deren owner-Eigenschaft nicht null ist). Um Probleme mit der Anordnung von Fenstern zu vermeiden, blenden Sie Fenster aus, die Eigentum eines anderen Fensters sind, bevor Sie diese Methode aufrufen.

Parameter

Verwandte API-Elemente

Bricht alle laufenden Upload- bzw. Download-Vorgänge dieses FileReference-Objekts ab. Durch Aufruf dieser Methode wird nicht das Ereignis cancel ausgelöst. Dieses Ereignis wird nur ausgelöst, wenn der Benutzer den Vorgang abbricht, indem er das Dialogfeld für den Upload- bzw. Download-Vorgang schließt.

Öffnet ein Dialogfeld, mit dem der Benutzer eine Datei von einem Remote-Server herunterladen kann. In Flash Player ist kein Grenzwert für die Größe der Dateien für Upload- und Download-Vorgänge festgelegt. Offiziell unterstützt der Player Dateigrößen von bis zu 100 MB.

Mit der Methode download() wird zunächst ein Dialogfeld des Betriebssystems geöffnet, in dem der Benutzer aufgefordert wird, einen Dateinamen einzugeben und einen Ordner zum Speichern der Datei auf dem lokalen Computer auszuwählen. Wenn der Benutzer den Speicherort auswählt und den Download-Vorgang bestätigt (z. B. durch Klicken auf „Speichern“), wird der Download vom Remote-Server gestartet. Listener erhalten Ereignisdaten und zeigen den Fortschritt, den Erfolg oder den Fehlschlag des Downloads an. Um den Status des Dialogfelds und des Download-Vorgangs nach dem download-Aufruf ermitteln zu können, muss der Code Listener für Ereignisse wie cancel, open, progress und complete enthalten.

Die Funktionen FileReference.upload() und FileReference.download() sind ungeblockt. Die Funktionsrückgaben erfolgen nach dem Aufruf vor Abschluss der Dateiübertragung. Wenn bei einem FileReference-Objekt der Gültigkeitsbereich verlassen wird, werden alle zu dem Zeitpunkt noch nicht abgeschlossenen Upload- bzw. Download-Vorgänge für dieses Objekt abgebrochen. Stellen Sie sicher, dass das FileReference-Objekt während der gesamten Dauer des Upload- bzw. Download-Vorgangs den Gültigkeitsbereich nicht verlässt.

Nach erfolgreich abgeschlossenem Download-Vorgang werden die Eigenschaften des FileReference-Objekts mit den Eigenschaften der lokalen Datei aktualisiert. Bei erfolgreichem Abschluss des Download-Vorgangs wird das Ereignis complete ausgelöst.

Es kann immer nur eine browse()- oder download()-Sitzung durchgeführt werden (da immer nur ein Dialogfeld aufgerufen werden kann).

Diese Methode unterstützt den Download jedes Dateityps mit HTTP oder HTTPS.

Eine Verbindung mit normalerweise reservierten Ports ist nicht möglich. Eine vollständige Liste der gesperrten Ports finden Sie unter „Beschränken von Netzwerk-APIs“ im ActionScript 3.0 Entwicklerhandbuch.

Hinweis: Wenn der Server eine Benutzerauthentifizierung erfordert, kann der Benutzer nur bei SWF-Dateien, die in einem Browser (also mit einem Browser-Plug-In oder einer ActiveX-Steuerung) ausgeführt werden, in einem Dialogfeld zur Eingabe eines Benutzernamens und eines Kennworts zur Authentifizierung aufgefordert werden. Dies gilt darüber hinaus nur für Download-Vorgänge. Upload-Vorgänge mit Plug-Ins oder ActiveX-Steuerelementen bzw. Upload- und Download-Vorgänge mit dem eigenständigen oder externen Player schlagen fehl.

Bedenken Sie beim Einsatz dieser Methode das Sicherheitsmodell von Flash Player:

• Ladevorgänge sind nicht zulässig, wenn die aufrufende SWF-Datei sich in einer nicht vertrauenswürdigen lokalen Sandbox befindet.
• Standardmäßig werden Sandbox-übergreifende Zugriffe nicht zugelassen. Eine Website kann den Zugriff auf eine Ressource durch das Hinzufügen einer URL-Richtliniendatei ermöglichen.
• Sie können eine SWF-Datei daran hindern, diese Methode aufzurufen, indem Sie auf der HTML-Seite, die den SWF-Inhalt enthält, den Parameter allowNetworking der Tags object und embed festlegen.
• In Flash Player 10 und Flash Player 9 mit Update 5 können Sie diese Methode nur als Reaktion auf ein Benutzerereignis erfolgreich aufrufen, z. B. in einer Ereignisprozedur für ein Mausklick- oder Tastendruckereignis. Andernfalls führt das Aufrufen dieser Methode dazu, dass Flash Player einen Ausnahmefehler ausgibt.

In Adobe AIR dagegen ist Inhalt in der Sicherheitssandbox der Anwendung (mit der AIR-Anwendung installierter Inhalt) nicht durch diese Sicherheitseinschränkungen beschränkt.

Weitere Informationen zum Thema Sicherheit finden Sie im Flash Player Developer Center im Abschnitt Sicherheit.

Wenn Sie eine Datei mit dieser Methode herunterladen, wird sie als heruntergeladen gekennzeichnet, sofern das Betriebssystem heruntergeladene Dateien kennzeichnet:

• Windows XP Service Pack 2 und höher und Windows Vista
• Mac OS 10.5 und höher

Einige Betriebssysteme, zum Beispiel Linux, kennzeichnen heruntergeladene Dateien nicht.

Beachten Sie, dass aufgrund neuer zusätzlicher Funktionalität von Flash Player beim Veröffentlichen in Flash Player 10 immer nur einer der folgenden Vorgänge aktiv sein kann: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Ansonsten gibt Flash Player einen Laufzeitfehler (Code 2174) aus. Stoppen Sie den laufenden Vorgang mithilfe von FileReference.cancel(). Diese Einschränkung betrifft lediglich Flash Player 10. Ältere Versionen von Flash Player sind von den Einschränkungen bezüglich gleichzeitig ausgeführter Vorgänge nicht betroffen.

In Adobe AIR wird das Download-Dialogfeld nicht immer vor Fenstern angezeigt, die „Eigentum“ eines anderen Fensters sind (Fenster, deren owner-Eigenschaft nicht null ist). Um Probleme mit der Anordnung von Fenstern zu vermeiden, blenden Sie Fenster aus, die Eigentum eines anderen Fensters sind, bevor Sie diese Methode aufrufen.

Parameter

Verwandte API-Elemente

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Startet das Laden einer lokalen Datei, die vom einem Benutzer ausgewählt wurde. In Flash Player bestehen zwar keine Beschränkungen bezüglich der Größe von Dateien, die hochgeladen, heruntergeladen, geladen oder gespeichert werden können, aber das Programm unterstützt offiziell Größen von bis zu 100 MB. Für Inhalt, der in Flash Player ausgeführt wird, müssen Sie die FileReference.browse()- oder die FileReferenceList.browse()-Methode aufrufen, bevor Sie die load()-Methode aufrufen. Inhalt, der in AIR in der Anwendungssandbox ausgeführt wird, kann jedoch die load()-Methode eines Dateiobjekts aufrufen, ohne zuerst die browse()-Methode aufzurufen. (Die AIR File-Klasse erweitert die FileReference-Klasse.)

Listener empfangen Ereignisse, um den Fortschritt, Erfolg oder Nichterfolg des Ladevorgangs anzuzeigen. Sie können zwar das FileReferenceList-Objekt verwenden, um Benutzer mehrere Dateien auswählen zu lassen, die geladen werden sollen, aber Sie müssen die Dateien einzeln laden. Um die Dateien einzeln zu laden, iterieren Sie durch das FileReferenceList.fileList-Array der FileReference-Objekte.

Adobe AIR enthält auch die FileStream-Klasse, die weitere Optionen zum Lesen von Dateien bereitstellt.

Die FileReference.upload()-, FileReference.download()-, FileReference.load()- und FileReference.save()-Funktionen sind nicht-blockierend. Die Funktionsrückgaben erfolgen nach dem Aufruf vor Abschluss der Dateiübertragung. Zusätzlich gilt: Wenn bei einem FileReference-Objekt der Gültigkeitsbereich verlassen wird, werden alle zu dem Zeitpunkt noch nicht abgeschlossenen Transaktionen für dieses Objekt abgebrochen. Stellen Sie sicher, dass das FileReference-Objekt während der gesamten Dauer des Upload-, Download-, Speicher- bzw. Ladevorgangs den Gültigkeitsbereich nicht verlässt.

Wenn die Datei erfolgreich geladen wurde, wird ihr Inhalt als ein Bytearray in der data-Eigenschaft des FileReference-Objekts gespeichert.

Bezüglich der Sicherheit sind folgende Punkte zu beachten:

• Ladevorgänge sind nicht zulässig, wenn die aufrufende SWF-Datei sich in einer nicht vertrauenswürdigen lokalen Sandbox befindet.
• Standardmäßig werden Sandbox-übergreifende Zugriffe nicht zugelassen. Bei einer Website kann der Zugriff auf eine Ressource durch eine Cross-Domain-Richtliniendatei ermöglicht werden.
• Sie können eine Datei daran hindern, diese Methode aufzurufen, indem Sie auf der HTML-Seite, die den SWF-Inhalt enthält, den Parameter allowNetworking der Tags object und embed festlegen.

Die genannten Punkte gelten nicht für AIR-Inhalt in der Anwendungssandbox.

Hinweis: Wenn Sie eine Anwendung für Flash Player 10 oder AIR 1.5 veröffentlichen, kann jeweils nur eine der folgenden Methoden aktiv sein: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Andernfalls gibt die Anwendung einen Laufzeitfehler zurück (Code 2174). Stoppen Sie den laufenden Vorgang mithilfe von FileReference.cancel(). Diese Beschränkung bezieht sich nur auf Flash Player 10 und AIR 1.5. Für frühere Version von Flash Player oder AIR gilt diese Beschränkung bezüglich mehrerer Methoden nicht.

In Adobe AIR wird das Dialogfeld zur Dateiauswahl nicht immer vor Fenstern angezeigt, die „Eigentum“ eines anderen Fensters sind (Fenster, deren owner-Eigenschaft nicht null ist). Um Probleme mit der Anordnung von Fenstern zu vermeiden, blenden Sie Fenster aus, die Eigentum eines anderen Fensters sind, bevor Sie diese Methode aufrufen.

Verwandte API-Elemente

var buttonShape:Shape = new Shape();
buttonShape.graphics.beginFill(0x336699);
buttonShape.graphics.drawCircle(50, 50, 25);
var button = new SimpleButton(buttonShape, buttonShape, buttonShape, buttonShape);
addChild(button);

var fileRef:FileReference= new FileReference();
button.addEventListener(MouseEvent.CLICK, onButtonClick);

function onButtonClick(e:MouseEvent):void {
fileRef.browse([new FileFilter("Images", "*.jpg;*.gif;*.png")]);
fileRef.addEventListener(Event.SELECT, onFileSelected);
}

function onFileSelected(e:Event):void {
fileRef.addEventListener(Event.COMPLETE, onFileLoaded);
fileRef.load();
}

function onFileLoaded(e:Event):void {
var loader:Loader = new Loader();
loader.loadBytes(e.target.data);
addChild(loader);
}

Fordert die Berechtigung zum Zugriff auf das Dateisystem an.

Öffnet ein Dialogfeld, das es dem Benutzer ermöglicht, eine Datei in ein lokales Dateisystem zu speichern. In Flash Player bestehen zwar keine Beschränkungen bezüglich der Größe von Dateien, die hochgeladen, heruntergeladen, geladen oder gespeichert werden können, aber der Player unterstützt offiziell Größen von bis zu 100 MB.

Die save()-Methode öffnet zuerst ein Betriebssystem-Dialogfeld, das den Benutzer zur Eingabe eines Dateinamens und zur Auswahl eines Ordners auf dem lokalen Computer auffordert, in dem die Datei gespeichert werden soll. Wenn der Benutzer einen Ordner auswählt und den Speichervorgang bestätigt (z. B. indem er auf „Speichern“ klickt), wird die Datei gespeichert. Listener empfangen Ereignisse, um den Fortschritt, Erfolg oder Nichterfolg des Speichervorgangs anzuzeigen. Um den Status des Dialogfelds und des Speichervorgangs nach dem Aufrufen von save() ermitteln zu können, muss Ihr Code Ereignisse wie cancel, open, progress und complete überwachen.

Adobe AIR enthält auch die FileStream-Klasse, die weitere Optionen zum lokalen Speichern von Dateien bereitstellt.

Die FileReference.upload()-, FileReference.download()-, FileReference.load()- und FileReference.save()-Funktionen sind nicht-blockierend. Die Funktionsrückgaben erfolgen nach dem Aufruf vor Abschluss der Dateiübertragung. Zusätzlich gilt: Wenn bei einem FileReference-Objekt der Gültigkeitsbereich verlassen wird, werden alle zu dem Zeitpunkt noch nicht abgeschlossenen Transaktionen für dieses Objekt abgebrochen. Stellen Sie sicher, dass das FileReference-Objekt während der gesamten Dauer des Upload-, Download-, Speicher- bzw. Ladevorgangs den Gültigkeitsbereich nicht verlässt.

Wenn die Datei erfolgreich gespeichert wurde, werden die Eigenschaften des FileReference-Objekts mit den Eigenschaften der lokalen Datei gefüllt. Das complete-Ereignis wird ausgelöst, wenn der Speichervorgang erfolgreich war.

Es kann jeweils nur eine browse()- oder save()-Sitzung durchgeführt werden (weil jeweils nur ein Dialogfeld aufgerufen werden kann).

In Flash Player können Sie diese Methode nur erfolgreich als Antwort auf ein Benutzerereignis (z. B. in einer Ereignisprozedur für ein Mausklick- oder Tastendruckereignis) aufrufen. Andernfalls führt das Aufrufen dieser Methode dazu, dass Flash Player einen Ausnahmefehler ausgibt. Diese Beschränkung gilt nicht für AIR-Inhalt in der Anwendungssandbox.

In Adobe AIR wird das Speichern-Dialogfeld nicht immer vor Fenstern angezeigt, die „Eigentum“ eines anderen Fensters sind (Fenster, deren owner-Eigenschaft nicht null ist). Um Probleme mit der Anordnung von Fenstern zu vermeiden, blenden Sie Fenster aus, die Eigentum eines anderen Fensters sind, bevor Sie diese Methode aufrufen.

Parameter

Verwandte API-Elemente

var MyTextField:TextField = new TextField();
var MyButtonField:TextField = new TextField();
var MyFile:FileReference = new FileReference();

MyTextField.border = true;
MyTextField.type = TextFieldType.INPUT;

MyButtonField.background = true;
MyButtonField.backgroundColor = 0x339933;
MyButtonField.x = 150;
MyButtonField.height = 20;
MyButtonField.text = "Click here to save";

addChild(MyTextField);
addChild(MyButtonField);
MyButtonField.addEventListener(MouseEvent.CLICK, clickhandler);

function clickhandler(e:MouseEvent): void {
    MyFile.save(MyTextField.text);
}

Startet den Upload der Datei auf einen Remote-Server. In Flash Player ist kein Grenzwert für die Größe der Dateien für Upload- und Download-Vorgänge festgelegt. Offiziell unterstützt der Player Dateigrößen von bis zu 100 MB. Vor dem Aufruf dieser Methode müssen Sie die Methode FileReference.browse() oder FileReferenceList.browse() aufrufen.

Für die File-Klassen von Adobe AIR, die die FileReference-Klasse erweitern, können Sie die upload()-Methode zum Hochladen beliebiger Dateien verwenden. Bei der FileReference-Klasse (in Flash Player verwendet) muss der Benutzer zuerst eine Datei auswählen.

Listener erhalten Ereignisdaten und zeigen den Fortschritt, den Erfolg oder den Fehlschlag des Uploads an. Sie können Benutzern mit dem Objekt „FileReferenceList“ zwar die Auswahl mehrerer Dateien zum Upload ermöglichen, die Dateien müssen jedoch einzeln hochgeladen werden. Verwenden Sie hierzu das Array FileReferenceList.fileList der FileReference-Objekte.

Die Funktionen FileReference.upload() und FileReference.download() sind ungeblockt. Die Funktionsrückgaben erfolgen nach dem Aufruf vor Abschluss der Dateiübertragung. Wenn bei einem FileReference-Objekt der Gültigkeitsbereich verlassen wird, werden alle zu dem Zeitpunkt noch nicht abgeschlossenen Upload- bzw. Download-Vorgänge für dieses Objekt abgebrochen. Stellen Sie sicher, dass das FileReference-Objekt während der gesamten Dauer des Upload- bzw. Download-Vorgangs den Gültigkeitsbereich nicht verlässt.

Die betreffenden Dateien werden zu der im Parameter url angegebenen jeweiligen URL hochgeladen. Bei der URL sollte es sich um ein Serverskript handeln, das für Uploads konfiguriert ist. In Flash Player werden Dateien mit der HTTP POST-Methode hochgeladen. Das den Upload verwaltende Serverskript sollte eine POST-Anforderung mit den folgenden Elementen erwarten:

• Content-Type mit dem Wert multipart/form-data
• Content-Disposition mit einem standardmäßig auf "Filedata" gesetzten name-Attribut und einem filename-Attribut, das auf den Namen der ursprünglichen Datei gesetzt ist.
• Die Binärdaten der Datei

Eine Verbindung mit normalerweise reservierten Ports ist nicht möglich. Eine vollständige Liste der gesperrten Ports finden Sie unter „Beschränken von Netzwerk-APIs“ im ActionScript 3.0 Entwicklerhandbuch.

Ein Beispiel für eine POST-Anforderung finden Sie in der Beschreibung zum Parameter uploadDataFieldName. Sie können POST- oder GET-Parameter mit der Methode upload() an den Server senden. Nähere Informationen finden Sie in der Beschreibung zum Parameter request.

Wenn der Parameter testUpload den Wert true aufweist und die hochzuladende Datei größer ist als etwa 10 KB, sendet Flash Player unter Windows vor dem Hochladen der tatsächlichen Datei zunächst einen Test-Upload ohne Inhalt mit der POST-Methode, um sicherzustellen, dass die Übertragung erfolgreich durchgeführt werden kann. Anschließend wird ein zweiter POST-Vorgang mit dem tatsächlichen Dateiinhalt gesendet. Bei Dateien, die kleiner sind als 10 KB, führt Flash Player nur einen POST-Vorgang mit dem tatsächlichen Inhalt der hochzuladenden Datei durch. Auf Macintosh-Plattformen werden keine POST-Vorgänge für Test-Uploads durchgeführt.

Hinweis: Wenn der Server eine Benutzerauthentifizierung erfordert, kann der Benutzer nur bei SWF-Dateien, die in einem Browser (also mit einem Browser-Plug-In oder einer ActiveX-Steuerung) ausgeführt werden, in einem Dialogfeld zur Eingabe eines Benutzernamens und eines Kennworts zur Authentifizierung aufgefordert werden. Dies gilt darüber hinaus nur für Download-Vorgänge. Upload-Vorgänge mit Plug-Ins oder ActiveX-Steuerelementen bzw. Upload- und Download-Vorgänge mit dem eigenständigen oder externen Player schlagen fehl.

Bedenken Sie beim Einsatz dieser Methode das Sicherheitsmodell von Flash Player:

• Ladevorgänge sind nicht zulässig, wenn die aufrufende SWF-Datei sich in einer nicht vertrauenswürdigen lokalen Sandbox befindet.
• Standardmäßig werden Sandbox-übergreifende Zugriffe nicht zugelassen. Eine Website kann den Zugriff auf eine Ressource durch das Hinzufügen einer URL-Richtliniendatei ermöglichen.
• Sie können eine SWF-Datei daran hindern, diese Methode aufzurufen, indem Sie auf der HTML-Seite, die den SWF-Inhalt enthält, den Parameter allowNetworking der Tags object und embed festlegen.

In Adobe AIR unterliegt Inhalt in der Sicherheitssandbox der Anwendung (Inhalt, der mit der AIR-Anwendung installiert wird) nicht diesen Sicherheitseinschränkungen.

Weitere Informationen zum Thema Sicherheit finden Sie im Flash Player Developer Center im Abschnitt Sicherheit.

Beachten Sie, dass aufgrund neuer zusätzlicher Funktionalität von Flash Player beim Veröffentlichen in Flash Player 10 immer nur einer der folgenden Vorgänge aktiv sein kann: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Ansonsten gibt Flash Player einen Laufzeitfehler (Code 2174) aus. Stoppen Sie den laufenden Vorgang mithilfe von FileReference.cancel(). Diese Einschränkung betrifft lediglich Flash Player 10. Ältere Versionen von Flash Player sind von den Einschränkungen bezüglich gleichzeitig ausgeführter Vorgänge nicht betroffen.

Parameter

    Content-Type: multipart/form-data; boundary=AaB03x
    --AaB03x 
    Content-Disposition: form-data; name="Filedata"; filename="example.jpg" 
    Content-Type: application/octet-stream
    ... contents of example.jpg ... 
    --AaB03x-- 
    

Verwandte API-Elemente

Leiten Sie das Hochladen einer Datei auf eine URL ohne Kodierung ein. Während die upload()-Methode die Datei in einem Formulardatenumschlag kodiert, übergibt die uploadUnencoded()-Methode den Dateiinhalt wie er ist im HTTP-Anforderungshauptteil. Verwenden Sie die uploadUnencoded()-Methode, wenn die Daten, die Sie senden möchten, bereits in einem Format kodiert sind, dass der empfangende Server akzeptiert. Normalerweise wird die uploadeUnencoded()-Methode mit der HTTP/WebDAV PUT-Methode.

Parameter

Verwandte API-Elemente

Wird ausgelöst, wenn der Benutzer eine Upload- oder Download-Vorgang über das Dialogfeld zum Suchen von Dateien abbricht. Flash Player löst dieses Ereignis nicht aus, wenn der Benutzer einen Upload bzw. Download auf andere Weise abbricht (durch Schließen des Browsers oder anhalten der aktuellen Anwendung).

Dieses Ereignis verfügt über die folgenden Eigenschaften:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_cancel extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_cancel() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(Event.CANCEL, cancelHandler);
            file.download(downloadURL, fileName);
        }
        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }
    }
}

Wird ausgelöst, wenn der Download-Vorgang abgeschlossen ist oder wenn beim Upload-Vorgang der HTTP-Statuscode 200 generiert wird. Bei Download-Vorgängen wird dieses Ereignis ausgelöst, wenn Flash Player oder Adobe AIR den Download der gesamten Datei auf die Festplatte abgeschlossen hat. Bei Upload-Vorgängen wird dieses Ereignis ausgelöst, nachdem Flash Player oder Adobe AIR vom empfangenden Server den HTTP-Statuscode 200 empfangen hat.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_complete extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_complete() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Verwandte API-Elemente

Wird ausgelöst, wenn ein Aufruf der upload()- oder uploadUnencoded()-Methode versucht, über HTTP auf Daten zuzugreifen und Adobe AIR den Statuscode für die Anforderung erkennen und zurückgeben kann.

Die HTTPStatusEvent.HTTP_RESPONSE_STATUS-Konstante definiert den Wert der type-Eigenschaft eines httpResponseStatus-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Wird ausgelöst, wenn ein Upload-Vorgang fehlschlägt und HTTP-Statuscode zur Beschreibung des Fehlers verfügbar ist. Das Ereignis httpStatus wird gefolgt von einem ioError-Ereignis ausgelöst.

Das Ereignis httpStatus wird nur bei Upload-Fehlern ausgelöst. Bei Inhalt, der im Flash Player ausgeführt wird, gilt dieses Ereignis nicht für fehlgeschlagene Downloads. Wenn ein Download mit einem HTTP-Fehler abbricht, wird dieser Fehler als I/O-Fehler gemeldet.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Wird ausgelöst, wenn der Upload- bzw. Download-Vorgang fehlschlägt. Das Fehlschlagen einer Dateiübertragung kann folgende Ursachen haben:

• Während des Lese-, Schreib- oder Übertragungsvorgangs der Datei ist ein I/O-Fehler aufgetreten.
• Die SWF-Datei versucht, eine Datei auf einen Server hochzuladen, der eine Authentifizierung (z. B. anhand eines Benutzernamens und eines Kennworts) erfordert. Während des Uploads stellt Flash Player bzw. die Adobe AIR-Anwendung keine Möglichkeit für die Eingabe von Kennwörtern durch die Benutzer bereit. Wenn eine SWF-Datei versucht, eine Datei auf einen Server hochzuladen, der eine Authentifizierung erfordert, schlägt dieser Upload fehl.
• Die SWF-Datei versucht, im Standalone- oder externen Player eine Datei von einem Server herunterzuladen, der eine Authentifizierung erfordert. Während des Downloads stellt der eigenständige bzw. externe Player keine Möglichkeit für die Eingabe von Kennwörtern durch die Benutzer bereit. Wenn mit einer SWF-Datei versucht wird, innerhalb dieser Player eine Datei von einem Server herunterzuladen, der eine Authentifizierung erfordert, schlägt dieser Download fehl. Der Datei-Download kann nur in der ActiveX-Steuerung, in Browser-Plug-In-Playern und in der Adobe AIR-Laufzeitumgebung erfolgen.
• Der an den Parameter url in der Methode upload() übergebene Wert enthält ein ungültiges Protokoll. Die zulässigen Protokolle sind HTTP und HTTPS.

Wichtig: Dialogfelder zur Eingabe eines Benutzernamens und Kennworts zur Benutzerauthentifizierung für anschließende Download-Vorgänge (und nichts anderes) können nur von Anwendungen, die in einem Browser ausgeführt werden (also Anwendungen, die das Browser-Zusatzmodul oder das ActiveX-Steuerelement verwenden) und von Inhalt angezeigt werden, der in Adobe AIR ausgeführt wird. Upload-Vorgänge mit der Zusatzmodul- oder ActiveX-Steuerelementversion bzw. Upload- und Download-Vorgänge mit dem eigenständigen oder externen Player schlagen fehl.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Wird beim Start eines Upload- bzw. Download-Vorgangs ausgelöst.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Verwandte API-Elemente

Wird abgesetzt, wenn die Anwendung die Berechtigung zum Zugriff auf das Dateisystem anfordert. Überprüfen Sie den Wert der Eigenschaft Status, um festzustellen, ob die Berechtigung gewährt oder verweigert wurde.

Verwandte API-Elemente

Wird regelmäßig während des Upload- bzw. Download-Vorgangs ausgelöst. Das Ereignis progress wird ausgelöst, während Flash Player Byte an einen Server sendet. Im Verlauf der Übertragung wird das Ereignis in regelmäßigen Abständen auch dann aufgerufen, wenn die Übertragung am Ende nicht erfolgreich abgeschlossen werden kann. Wenn Sie feststellen möchten, ob und zu welchem Zeitpunkt die Dateiübertragung erfolgreich abgeschlossen wird, verwenden Sie einen Listener für das complete-Ereignis.

In einigen Fällen werden keine progress-Ereignisse empfangen. Wenn die übertragene Datei beispielsweise sehr klein ist oder der Upload- bzw. Download-Vorgang in sehr kurzer Zeit erfolgt, wird möglicherweise kein progress-Ereignis ausgelöst.

Bei Macintosh-Plattformen vor Version OS X 10.3 kann der Fortschritt von Upload-Vorgängen nicht festgestellt werden. Das progress-Ereignis wird zwar während des Upload-Vorgangs aufgerufen, die Eigenschaft bytesLoaded weist jedoch stets den Wert -1 auf, was bedeutet, dass der Fortschritt nicht festgestellt werden kann.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_progress extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_progress() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.download(downloadURL, fileName);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
        
        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Verwandte API-Elemente

Wird ausgelöst, wenn mit einem Aufruf der Methode FileReference.upload() oder FileReference.download() versucht wird, eine Datei auf einen Server zu laden oder von einem Server herunterzuladen, der sich außerhalb der Sicherheitssandbox des Aufrufers befindet. Der Wert der Texteigenschaft zur Beschreibung des aufgetretenen Fehlers ist in der Regel "securitySandboxError". Mit der aufrufenden SWF-Datei wurde unter Umständen versucht, ohne entsprechende Berechtigung auf eine SWF-Datei außerhalb ihrer Domäne zuzugreifen. Sie können versuchen, diesen Fehler zu beheben, indem Sie eine URL-Richtliniendatei verwenden.

In Adobe AIR gelten diese Sicherheitseinschränkungen nicht für Inhalt in der Sicherheitssandbox der Anwendung.

In Adobe AIR gelten diese Sicherheitseinschränkungen nicht für Inhalt in der Sicherheitssandbox der Anwendung.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Wird ausgelöst, wenn der Benutzer im Dialogfeld zum Suchen von Dateien eine Datei für einen Upload- oder Download-Vorgang auswählt. (Dieses Dialogfeld wird beim Aufruf der Methode FileReferenceList.browse(), FileReference.browse() oder FileReference.download() geöffnet.) Sobald ein Benutzer eine Datei auswählt und den Vorgang bestätigt (z. B. durch Klicken auf „OK“), werden die Eigenschaftenfelder des FileReference-Objekts mit Daten gefüllt.

Bei Inhalt, der in Flash Player oderaußerhalb der Sicherheitssandbox der Anwendung in der Adobe AIR-Laufzeitumgebung ausgeführt wird, verhält sich das select-Ereignis je nachdem, welche Methode es aufgerufen hat, leicht unterschiedlich. Wenn das Ereignis select nach einem browse()-Aufruf ausgelöst wird, können sämtliche Eigenschaften des FileReference-Objekts von Flash Player oder der AIR-Anwendung gelesen werden, da sich die vom Benutzer ausgewählte Datei im lokalen Dateisystem befindet. Wenn das Ereignis select nach einem download()-Aufruf ausgelöst wird, kann Flash Player oder die AIR-Anwendung lediglich die name-Eigenschaft lesen, da die Datei zu dem Zeitpunkt der Auslösung des select-Ereignisses noch nicht in das lokale Dateisystem heruntergeladen wurde. Nachdem die Datei heruntergeladen und das complete-Ereignis ausgelöst wurde, können alle anderen Eigenschaften des FileReference-Objekts von Flash Player oder der AIR-Anwendung gelesen werden.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

 
package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_select extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReference_event_select() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            file.addEventListener(Event.SELECT, selectHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.browse();
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Wird ausgelöst, nachdem die Daten vom Server nach einem erfolgreichen Upload empfangen wurden. Das Ereignis wird nur ausgelöst, wenn Daten vom Server zurückgegeben werden.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Hinweis: Ändern Sie zur Ausführung dieses Beispiels die Eigenschaft „uploadURL.url“ so, dass sie auf eine tatsächliche URL verweist. Die URL muss auf eine Datei mit dem Namen yourUploadHandlerScript.cfm im Stammverzeichnis des Webservers der angegebenen URL verweisen. Abhängig von der Konfiguration müssen Sie außerdem ggf. die SWF-Datei unter Verwendung der Einstellung „Nur auf Netzwerk zugreifen“ für die Option „Sicherheit bei lokaler Wiedergabe“ kompilieren oder die Flash Player-Sicherheitseinstellungen ändern, um den Netzwerkzugriff für diese Datei zuzulassen.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileFilter;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReferenceExample extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReferenceExample() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            configureListeners(file);
            file.browse(getTypes());
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
            dispatcher.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA,uploadCompleteDataHandler);
        }

        private function getTypes():Array {
            var allTypes:Array = new Array(getImageTypeFilter(), getTextTypeFilter());
            return allTypes;
        }

        private function getImageTypeFilter():FileFilter {
            return new FileFilter("Images (*.jpg, *.jpeg, *.gif, *.png)", "*.jpg;*.jpeg;*.gif;*.png");
        }

        private function getTextTypeFilter():FileFilter {
            return new FileFilter("Text Files (*.txt, *.rtf)", "*.txt;*.rtf");
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function uploadCompleteDataHandler(event:DataEvent):void {
            trace("uploadCompleteData: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }
    }
}