File  - AS3

Der Ordner mit den installierten Dateien der Anwendung.

Die url-Eigenschaft für dieses Objekt verwendet das URL-Schema app (nicht das URL-Schema file). Dies bedeutet, dass der url-String mit "app:" beginnt (nicht mit "file:"). Wenn Sie ein File-Objekt relativ zum File.applicationDirectory-Ordner erstellen (mit der resolvePath()-Methode), verwendet die url-Eigenschaft des File-Objekts ebenfalls das app-URL-Schema.

Hinweis: Sie können nicht in Dateien oder Ordner schreiben, die Pfade mit dem app:-URL-Schema aufweisen. Es ist auch nicht möglich, Dateien oder Ordner zu löschen oder zu erstellen, für deren Pfad das app:-URL-Schema verwendet wird. Aus Sicherheitsgründen wird davon abgeraten, Inhalt im Anwendungsverzeichnis zu ändern, dies ist bei den Betriebssystemen einiger Plattformen auch gar nicht möglich. Wenn Sie anwendungsspezifische Daten speichern möchten, sollten Sie das Anwendungsspeicherverzeichnis (File.applicationStorageDirectory) verwenden. Wenn Sie möchten, dass Inhalte im Anwendungsspeicherordner Zugriff auf anwendungsberechtigte Funktionen (AIR-APIs) haben, können Sie diese Funktionen mithilfe einer Sandbox-Brücke bereitstellen.

Die applicationDirectory-Eigenschaft stellt eine Möglichkeit zum Verweisen auf den Anwendungsordner bereit, die auf allen Plattformen funktioniert. Wenn Sie ein File-Objekt mithilfe der nativePath- oder url-Eigenschaft so einrichten, dass es auf den Anwendungsordner verweist, funktioniert dies nur auf der Plattform, auf der der Pfad gültig ist.

Unter Android ist die nativePath-Eigenschaft eines File-Objekts, das auf das Anwendungsverzeichnis zeigt, ein leerer String. Verwenden Sie die url-Eigenschaft, um auf Anwendungsdateien zuzugreifen.

Verwandte API-Elemente

Das private Speicherverzeichnis der Anwendung.

Jede AIR-Anwendung verfügt über einen eindeutigen, dauerhaften Anwendungsspeicherordner, der erstellt wird, wenn Sie zum ersten Mal auf File.applicationStorageDirectory zugreifen. Dieses Verzeichnis ist für jede Anwendung und jeden Benutzer eindeutig. Dieses Verzeichnis ist ein praktischer Speicherort für benutzer- oder anwendungsspezifische Daten.

Beim Deinstallieren einer AIR-Anwendung ist es von der Plattform abhängig, ob das Deinstallationsprogramm das Anwendungsspeicherverzeichnis und die Dateien darin löscht.

Die url-Eigenschaft für dieses Objekt verwendet das URL-Schema app-storage (nicht das URL-Schema file). Dies bedeutet, dass der url-String mit "app-storage:" beginnt (nicht mit "file:"). Wenn Sie ein File-Objekt relativ zum File.applicationStoreDirectory-Ordner erstellen (mit der resolvePath()-Methode), verwendet die url des File-Objekts ebenfalls das app-storage-URL-Schema (wie im Beispiel).

Die applicationStorageDirectory-Eigenschaft stellt eine Möglichkeit zum Verweisen auf den Anwendungsordner bereit, die auf allen Plattformen funktioniert. Wenn Sie ein File-Objekt mithilfe der nativePath- oder url-Eigenschaft so einrichten, dass es auf den Anwendungsspeicherordner verweist, funktioniert dies nur auf der Plattform, auf der der Pfad gültig ist.

Hinweis (nur Mac OS): Um den Anforderungen des Mac App Store zu entsprechen, wurde der physische Speicherort dieses Verzeichnisses zwischen AIR 3.2 und AIR 3.3 geändert:

• 3.2 Namespace und früher: ~/Library/Preferences/appid/Local Store/
• 3.3 Namespace und neuer: Pfad/Library/Application Support/appid/Local Store/, wobei Pfad entweder ~/Library/Containers/bundle-id/Data (Sandbox-Umgebung) oder ~ ist (bei Ausführung außerhalb einer Sandbox-Umgebung)

import flash.filesystem.File;

var tempFiles:File = File.applicationStorageDirectory;
tempFiles = tempFiles.resolvePath("images/");
trace(tempFiles.url); // app-storage:/images

Der Cache-Ordner der Anwendung.

Die cacheDirectory-Eigenschaft stellt eine Möglichkeit zum Verweisen auf den Anwendungsordner bereit, die auf allen Plattformen funktioniert. Ihre Anwendung sollte den Cache-Ordner verwenden, um Dateien zu speichern, die von einem Server heruntergeladen wurden oder die erneut erstellt werden können. Sie sollten beispielsweise Datenbank-Cachedateien und herunterladbare Inhalte wie die, die von Zeitschriften-, Zeitungs- und Kartenanwendungen verwendet werden, in den Cache-Ordner legen.

Wenn Sie ein File-Objekt mithilfe der nativePath- oder url-Eigenschaft so einrichten, dass es auf den Cache-Ordner verweist, funktioniert dies nur auf Plattformen, auf denen der Pfad gültig ist.

Wenn das Betriebssystem keine Cache-Ordner unterstützt, ist cacheDirectory null.

Das Desktopverzeichnis des Benutzers.

Die desktopDirectory-Eigenschaft stellt eine Möglichkeit zum Verweisen auf den Anwendungsordner bereit, die auf allen Plattformen funktioniert. Wenn Sie ein File-Objekt mithilfe der nativePath- oder url-Eigenschaft so einrichten, dass es auf den Desktopordner verweist, funktioniert dies nur auf der Plattform, auf der der Pfad gültig ist.

Wenn ein Betriebssystem kein Desktopverzeichnis unterstützt, wird stattdessen ein geeignetes Verzeichnis im Dateisystem verwendet.

Geräte mit AIR für TV verfügen nicht über das Konzept eines Benutzerdesktopverzeichnisses. Deshalb verweist die desktopDirectory-Eigenschaft auf denselben Verzeichnisort wie die File.userDirectory-Eigenschaft. Das Benutzerverzeichnis ist in der Anwendung eindeutig.

import flash.filesystem.File;
var desktop:File = File.desktopDirectory;

var files:Array = desktop.getDirectoryListing();

for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

Das Dokumentverzeichnis des Benutzers.

Unter Windows ist dies der Ordner „Eigene Dateien“ (zum Beispiel C:\Dokumente und Einstellungen\Benutzername\Eigene Dateien). Unter Mac OS ist dies standardmäßig /Benutzer/Benutzername/Dokumente. Unter Linux lautet der Standardspeicherort auf einem deutschen System „/home/Benutzername/Dokumentes“ und die Eigenschaft berücksichtigt die xdg-user-dirs-Einstellung.

Die documentsDirectory-Eigenschaft stellt eine Möglichkeit zum Verweisen auf den Anwendungsordner bereit, die auf allen Plattformen funktioniert. Wenn Sie ein File-Objekt mithilfe der nativePath- oder url-Eigenschaft so einrichten, dass es auf den Dokumentordner verweist, funktioniert dies nur auf der Plattform, auf der der Pfad gültig ist.

Wenn ein Betriebssystem kein Dokumentverzeichnis unterstützt, wird stattdessen ein geeignetes Verzeichnis im Dateisystem verwendet.

Geräte mit AIR für TV verfügen nicht über das Konzept eines Benutzerdokumentverzeichnisses. Deshalb verweist die documentsDirectory-Eigenschaft auf denselben Verzeichnisort wie die File.userDirectory-Eigenschaft. Das Benutzerverzeichnis ist in der Anwendung eindeutig.

import flash.filesystem.File;

var directory:File = File.documentsDirectory;
directory = directory.resolvePath("AIR Test");

File.createDirectory(directory);
trace(directory.exists); // true

Gibt an, ob die referenzierte Datei bzw. das referenzierte Verzeichnis (aus dem Internet) heruntergeladen wurde oder nicht.

Diese Eigenschaft ist nur unter Betriebssystemen, in denen Dateien als heruntergeladen gekennzeichnet werden können, von Bedeutung:

• Windows XP Service Pack 2 und höher und Windows Vista
• Mac OS 10.5 und höher

Bei Systemen, die heruntergeladene Dateien nicht kennzeichnen, zum Beispiel Linux, hat diese Eigenschaft keine Bedeutung (und wird auf false gesetzt).

Verwandte API-Elemente

Gibt an, ob die Datei bzw. der Ordner, auf die/den verwiesen wird, vorhanden ist. Der Wert ist true, wenn das File-Objekt auf eine vorhandene Datei oder einen vorhandenen Ordner verweist; andernfalls ist er false.

import flash.filesystem.*;

var temp:File = File.createTempFile();
trace(temp.exists); // true
temp.deleteFile();
trace(temp.exists); // false

Ein Icon-Objekt, das die für diese Datei definierten Symbole enthält. Ein Icon-Objekt ist ein Array von BitmapData-Objekten, die den verschiedenen Zuständen des Symbols entsprechen. Unter Linux enthält das Icon-Objekt keine Symbole. Unter Android hat die icon-Eigenschaft den Wert null.

import flash.filesystem.File;
import flash.display.*;

var directory:File = File.documentsDirectory;
var bitmaps:Array = directory.icon.bitmaps;
var bmpData:BitmapData = new BitmapData(1, 1);
for (var i:uint = 0; i < bitmaps.length; i++) {
    if (bitmaps[i].height > bmpData.height) {
        bmpData = directory.icon.bitmaps[i];
    }
}
var iconBmp:Bitmap = new Bitmap(bmpData);

Gibt an, ob auf einen Ordner verwiesen wird. Der Wert ist true, wenn das File-Objekt auf ein Verzeichnis verweist; andernfalls false.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isDirectory) {
        trace(userDirFiles[i].nativePath);
    }
}    

Gibt an, ob die Datei bzw. der Ordner, auf die bzw. den verwiesen wird, versteckt ist. Der Wert ist true, wenn die Datei/der Ordner, auf die/den verwiesen wird, ausgeblendet ist, andernfalls ist er false.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isHidden) {
        trace(userDirFiles[i].nativePath);
    }
}    

Gibt an, ob der Ordner, auf den verwiesen wird, ein Paket ist.

Der Wert ist true, wenn der Ordner ein Paket ist, andernfalls ist er false. Beachten Sie, dass die File-Klasse das direkte Erstellen von Paketen nicht zulässt.

• Unter Mac OS können Verzeichnisse als Pakete gekennzeichnet werden und erscheinen dann im Finder als einzelne Dateien, nicht als Verzeichnisse. Diese Eigenschaft ist auf true gesetzt, wenn der Ordner, auf den verwiesen wird, ein Paket ist. Der Wert false wird zurückgegeben, wenn die Datei kein Ordner, nicht vorhanden oder kein Paket ist.
• Unter anderen Betriebssystemen ist diese Eigenschaft immer auf false gesetzt.

Gibt an, ob der Verweis ein symbolischer Link ist.

Der Wert ist true, wenn das File-Objekt ein symbolischer Link ist; andernfalls ist er false. Beachten Sie, dass die File-Klasse das direkte Erstellen von symbolischen Links nicht zulässt.

Symbolische Links ermöglichen, dass eine Datei auf eine andere Datei oder ein Verzeichnis auf der Festplatte zeigt. Obwohl sie sich ähneln, sind symbolische Links nicht dasselbe wie Aliasnamen unter Mac OS oder Verknüpfungen unter Windows. Ein Alias oder eine Verknüpfung wird immer als Datei (nicht als Verzeichnis) betrachtet, und das Lesen und Schreiben von oder in einen Alias oder in eine Verknüpfung betrifft nie die ursprüngliche Datei oder das ursprüngliche Verzeichnis, auf die bzw. das verwiesen wird. Abgesehen davon verhält sich ein symbolischer Link genau wie die Datei bzw. der Ordner, auf die bzw. den verwiesen wird. Der symbolische Link kann als Datei oder als Verzeichnis betrachtet werden. Das Lesen von einem oder in einen symbolischen Link betrifft die Datei oder das Verzeichnis, auf die bzw. das verwiesen wird, nicht den symbolischen Link selbst. Beim Löschen eines symbolischen Links wird der Link gelöscht, nicht das Ziel des Links.

Symbolische Links werden von Mac^® OS^®, Linux und Windows^® Vista^® unterstützt. Unter Windows wird zusätzlich die isSymbolicLink-Eigenschaft für ein File-Objekt, das auf einen Verknüpfungspunkt (im NTFS-Dateisystem verwendet) verweist, mit dem Wert true belegt.

Die vom Host-Betriebssystem verwendete Zeilenende-Zeichenfolge.

Unter Mac OS und Linux ist dies das Zeilenvorschubzeichen (hexadezimaler Zeichencode 0x0A). Unter Windows ist dies das Wagenrücklaufzeichen (hexadezimaler Zeichencode 0x0D) gefolgt vom Zeilenvorschubzeichen (hexadezimaler Zeichencode 0x0A).

import flash.filesystem.*;

var str:String = "Hello\n" + 
        "World\n";
str = str.replace(/\n/g, File.lineEnding);
var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.WRITE);
fileStream.writeUTF(str);
fileStream.close();

Der vollständige Pfad in der Schreibweise des Host-Betriebssystems. Unter Mac OS und Linux wird der Schrägstrich (/) als Pfadtrennzeichen verwendet. Unter Windows setzen Sie die nativePath-Eigenschaft jedoch entweder mit dem Schrägstrich (/) oder dem umgekehrten Schrägstrich (\) als Pfadtrennzeichen. AIR ersetzt Schrägstriche (/) automatisch durch umgekehrte Schrägstriche (\).

Bevor Sie Code zum direkten Setzen der nativePath-Eigenschaft schreiben, sollten Sie überlegen, ob dies nicht plattformspezifischen Code ergibt. So ist beispielsweise der native Pfad "C:\\Dokumente und Einstellungen\\klaus\\Desktop" nur unter Windows gültig. Es ist besser, stattdessen die folgenden statischen Eigenschaften zu verwenden, die häufig verwendete Ordner repräsentieren und auf allen Plattformen gültig sind:

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Mit der resolvePath()-Methode erhalten Sie einen Pfad relativ zu diesen Ordnern.

Manche Flex-APIs, wie z. B die source-Eigenschaft der SWFLoader-Klasse, verwenden eine URL (die url-Eigenschaft eines File-Objekts) anstatt eines nativen Pfads (die nativePath-Eigenschaft).

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

Das Verzeichnis, das die Datei oder das Verzeichnis, auf die bzw. das durch dieses File-Objekt verwiesen wird, enthält.

Auch wenn die Datei oder der Ordner nicht vorhanden ist, gibt die parent-Eigenschaft das File-Objekt zurück, das auf den Ordner mit der Datei verweist (selbst wenn dieser Ordner nicht vorhanden ist).

Diese Eigenschaft ist identisch mit dem Rückgabewert für resolvePath(".."), außer dass der übergeordnete Ordner eines Stammordners null ist.

import flash.filesystem.File;

var tempFile:File = File.createTempDirectory();
trace(tempFile.parent.nativePath);
tempFile.deleteFile();

Bestimmen Sie, ob der Anwendung die Berechtigung zum Zugriff auf das Dateisystem erteilt wurde.

Verwandte API-Elemente

Gibt an, ob die Laufzeit verhindert, dass das File-Objekt in der Cloud gesichert wird.

Wenn diese Eigenschaft auf true gesetzt ist, wird es nicht automatisch in der Cloud auf Plattformen, die diesen Dienst bereitstellen, gesichert. Der Standardwert dieser Eigenschaft lautet „false“.

Das vom Betriebssystem verwendete Trennzeichen für Pfadkomponenten.

Unter Mac OS und Linux ist dies der Schrägstrich (/). Unter Windows ist dies der umgekehrte Schrägstrich (\).

Hinweis: Wenn Sie den umgekehrten Schrägstrich in einem Stringliteral verwenden, denken Sie daran, das Zeichen zweimal einzugeben (wie in "ordner\\datei.ext"). Jeder doppelte umgekehrte Schrägstrich in einem Stringliteral repräsentiert einen einzelnen umgekehrten Schrägstrich im String.

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Apollo Test");
var file:File = File.documentsDirectory.resolvePath("Apollo Test/employees/bob/test.txt");

var relativePath:String = directory.getRelativePath(file); // employees/bob/test.txt
relativePath = relativePath.replace(/\//g, File.separator);
trace(relativePath); 

Der an diesem Dateispeicherort verfügbare Speicherplatz in Byte.

Wenn das File-Objekt auf einen Ordner verweist, gibt spaceAvailable den Speicherplatz im Ordner, der für Dateien zur Verfügung steht, an. Wenn das File-Objekt auf eine Datei verweist, gibt spaceAvailable den Speicherplatz, den die Datei einnehmen könnte, an. Wenn der Dateispeicherort nicht vorhanden ist, ist spaceAvailable auf 0 gesetzt. Wenn das File-Objekt ein symbolischer Link ist, gibt spaceAvailable den Speicherplatz an, der am Speicherort, auf den der symbolische Link verweist, zur Verfügung steht.

Normalerweise ist der verfügbare Speicherplatz für einen Ordner oder eine Datei derselbe wie der verfügbare Speicherplatz auf dem Laufwerk, auf dem sich der Ordner bzw. die Datei befindet. Der verfügbare Speicherplatz kann jedoch auch Kontenkontingente und ordnerspezifische Begrenzungen berücksichtigen.

Wenn Sie einem Laufwerk eine Datei oder einen Ordner hinzufügen, wird dabei im Allgemeinen mehr Speicherplatz benötigt, als die Datei bzw. der Inhalt des Ordners tatsächlich belegen. Das Betriebssystem kann zum Beispiel zusätzlichen Speicherplatz zum Speichern von Indexinformationen benötigen. Auch Festplattensektoren benötigen unter Umständen zusätzlichen Speicher. Der verfügbare Speicherplatz ändert sich zudem dynamisch. Sie können also nicht davon ausgehen, dass Sie den gesamten gemeldeten Speicherplatz für das Speichern von Dateien verwenden können.

Die vom Host-Betriebssystem verwendete Standardkodierung.

Mögliche Werte sind unter anderem "windows-1252" "shift-jis", "cn-gb", "iso-8859-1". Eine vollständige Liste finden Sie unter Unterstützte Zeichensätze.

Sie können diesen Wert verwenden, wenn Sie die readMultiByte()- und writeMultiByte()-Methode der FileStream-Klasse verwenden.

Verwandte API-Elemente

import flash.filesystem.File;

var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.READ);
var str:String = fileStream.readMultiByte(file.size, File.systemCharset);
trace(str);    

Die URL für diesen Dateipfad.

Wenn es sich dabei um einen Verweis auf einen Pfad im Anwendungsspeicherordner handelt, ist das URL-Schema "app-storage"; wenn es sich um einen Verweis auf einen Pfad im Anwendungsordner handelt, ist das URL-Schema "app"; andernfalls ist es "file".

Sie können Leerzeichen (anstelle von "%20") verwenden beim Zuweisen eines Werts zur url-Eigenschaft. AIR kodiert die Strings automatisch (konvertiert zum Beispiel Leerzeichen in "%20").

Verwandte API-Elemente

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

Das Verzeichnis des Benutzers.

Unter Windows ist das der Ordner, der dem Ordner „Eigene Dateien“ übergeordnet ist (z. B. C:\Dokumente und Einstellungen\Benutzername). Unter Mac OS ist dies /Benutzer/Benutzername. Unter Linux ist dies /home/Benutzername.

Die userDirectory-Eigenschaft stellt eine Möglichkeit zum Verweisen auf den Anwendungsordner bereit, die auf allen Plattformen funktioniert. Wenn Sie die nativePath- oder url-Eigenschaft eines File-Objekts direkt setzen, funktioniert sie nur auf der Plattform, auf der der Pfad gültig ist.

Wenn ein Betriebssystem kein Benutzerverzeichnis unterstützt, wird stattdessen ein geeignetes Verzeichnis im Dateisystem verwendet.

Bei Geräten mit AIR für TV verweist die userDirectory-Eigenschaft auf ein Benutzerverzeichnis, das in der Anwendung eindeutig ist.

import flash.filesystem.File;

var files:Array = File.userDirectory.listDirectory();
for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

Die Konstruktorfunktion für die File-Klasse.

Wenn Sie ein path-Argument übergeben, zeigt das File-Objekt auf den angegebenen Pfad und die Eigenschaften nativePath und url werden diesem Pfad entsprechend eingestellt.

Obwohl Sie zum Festlegen eines Dateipfads ein path-Argument übergeben können, sollten Sie überlegen, ob dadurch vielleicht plattformspezifischer Code entsteht. Beispiel: Ein nativer Pfad wie "C:\\Dokumente und Einstellungen\\klaus\\Desktop" oder eine URL wie "file:///C:/Dokumente%20und%20Einstellungen/klaus/Desktop" ist nur unter Windows gültig. Es ist besser, stattdessen die folgenden statischen Eigenschaften zu verwenden, die häufig verwendete Ordner repräsentieren und auf allen Plattformen gültig sind:

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Mit der resolvePath()-Methode erhalten Sie einen Pfad relativ zu diesen Ordnern. Beispiel: Mithilfe des folgenden Codes verweist ein File-Objekt auf die Datei „settings.xml“ im Anwendungsspeicherordner:

var file:File = File.applicationStorageDirectory.resolvePath("settings.xml");

Wichtig: Wenn Sie im path-Parameter einen URL-String übergeben, wird die URL dekodiert, um den Dateipfad aufzulösen. Die Anweisung new File("file:///c:/test/demo%20file%201%2e0.txt") erstellt zum Beispiel ein File-Objekt mit dem nativen Pfad "c:\test\demo file 1.0.txt". (Eine URL verwendet das Schemapräfix „file:“, „app:“ oder „app-storage:“.) Wenn die gültigen URL-Präfixe ausgelassen werden, wird der Pfadstring wie ein nativer Pfad behandelt und es findet keine Dekodierung statt. Sie müssen dieses Verhalten beim Validieren von Pfaden, die aus potenziell nicht vertrauenswürdigen Quellen stammen, berücksichtigen. Wenn Sie einfach den Eingabestring validieren, kann ein Angreifer Ihre Validierungsüberprüfungen mithilfe der URL-Dekodierung möglicherweise umgehen. Validieren Sie immer den endgültigen Pfad des instanziierten File-Objekts:

     var file:File = new File( taintedString );
     validate( file.nativePath ); //where validate() is your path validation function
     

Verwandte API-Elemente

Zeigt ein Dialogfeld zur Ordnerauswahl an, in dem der Benutzer einen Ordner auswählen kann. Wenn der Benutzer den Ordner auswählt, wird das select-Ereignis ausgelöst. Die target-Eigenschaft des select-Ereignisses ist das File-Objekt, das auf den ausgewählten Ordner weist.

Das Dialogfeld für die Ordnerauswahl wird nicht immer vor Fenstern angezeigt, die das „Eigentum“ eines anderen Fensters sind (Fenster, deren owner-Eigenschaft nicht null ist). Um Probleme mit der Anordnung von Fenstern zu vermeiden, blenden Sie Fenster aus, die Eigentum eines anderen Fensters sind, bevor Sie diese Methode aufrufen.

Hinweis: Bei Android-Geräten wird browseForDirectory() nicht unterstützt. Das File-Objekt setzt sofort ein cancel-Ereignis ab.

Parameter

Verwandte API-Elemente

import flash.filesystem.File;
import flash.events.Event;

var directory:File = File.documentsDirectory;

try
{
    directory.browseForDirectory("Select Directory");
    directory.addEventListener(Event.SELECT, directorySelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function directorySelected(event:Event):void 
{
    directory = event.target as File;
    var files:Array = directory.getDirectoryListing();
    for(var i:uint = 0; i < files.length; i++)
    {
        trace(files[i].name);
    }
}

Zeigt das Dialogfeld „Datei öffnen“ an, in dem der Benutzer eine Datei zum Öffnen auswählen kann.

Wenn der Benutzer die Datei auswählt, wird das select-Ereignis ausgelöst. Die target-Eigenschaft des select-Ereignisses ist das File-Objekt, das auf die ausgewählte Datei weist.

Das Dialogfeld zum Öffnen von Dateien wird nicht immer vor Fenstern angezeigt, die das „Eigentum“ eines anderen Fensters sind (Fenster, deren owner-Eigenschaft nicht null ist). Um Probleme mit der Anordnung von Fenstern zu vermeiden, blenden Sie Fenster aus, die Eigentum eines anderen Fensters sind, bevor Sie diese Methode aufrufen.

Hinweis: Bei Android-Geräten kann der Dateidialogtitel nicht festgelegt werden. Der title-Parameter wird ignoriert.

Parameter

Verwandte API-Elemente

import flash.filesystem.*;
import flash.events.Event;
import flash.net.FileFilter;

var fileToOpen:File = new File();
var txtFilter:FileFilter = new FileFilter("Text", "*.as;*.css;*.html;*.txt;*.xml");

try 
{
    fileToOpen.browseForOpen("Open", [txtFilter]);
    fileToOpen.addEventListener(Event.SELECT, fileSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function fileSelected(event:Event):void 
{
    var stream:FileStream = new FileStream();
    stream.open(event.target, FileMode.READ);
    var fileData:String = stream.readUTFBytes(stream.bytesAvailable);
    trace(fileData);
}

Zeigt ein Dialogfeld „Datei öffnen“ an, in dem der Benutzer eine oder mehrere Dateien zum Öffnen auswählen kann.

Wenn der Benutzer die Dateien auswählt, wird das selectMultiple-Ereignis ausgelöst. Die target-Eigenschaft des select-Ereignisses ist dieses File-Objekt. Anders als bei browseForOpen() wird mit der browseForOpenMultiple()-Methode dieses File-Objekt nicht aktualisiert, um auf eine der ausgewählten Dateien zu verweisen. Stattdessen enthält das daraus resultierende selectMultiple-Ereignis ein Array mit den ausgewählten Dateien.

Das Dialogfeld zum Öffnen von Dateien wird nicht immer vor Fenstern angezeigt, die das „Eigentum“ eines anderen Fensters sind (Fenster, deren owner-Eigenschaft nicht null ist). Um Probleme mit der Anordnung von Fenstern zu vermeiden, blenden Sie Fenster aus, die Eigentum eines anderen Fensters sind, bevor Sie diese Methode aufrufen.

Hinweis: Bei Android-Geräten kann der Dateidialogtitel nicht festgelegt werden. Der title-Parameter wird ignoriert.

Parameter

Verwandte API-Elemente

import flash.filesystem.*;
import flash.events.FileListEvent;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForOpenMultiple("Select Files");
    docsDir.addEventListener(FileListEvent.SELECT_MULTIPLE, filesSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function filesSelected(event:FileListEvent):void 
{
    for (var i:uint = 0; i < event.files.length; i++) 
    {
        trace(event.files[i].nativePath);
    }
}

Zeigt ein Dialogfeld zum Speichern der Datei an, in dem der Benutzer einen Speicherort auswählen kann.

Wenn der Benutzer die Datei auswählt, wird das select-Ereignis ausgelöst. Die target-Eigenschaft des select-Ereignisses ist das File-Objekt, das auf das ausgewählte Save-Ziel weist.

Das Dialogfeld zum Speichern von Dateien wird nicht immer vor Fenstern angezeigt, die das „Eigentum“ eines anderen Fensters sind (Fenster, deren owner-Eigenschaft nicht null ist). Um Probleme mit der Anordnung von Fenstern zu vermeiden, blenden Sie Fenster aus, die Eigentum eines anderen Fensters sind, bevor Sie diese Methode aufrufen.

Hinweis: Bei Android-Geräten kann der Dateidialogtitel nicht festgelegt werden. Der title-Parameter wird ignoriert.

Parameter

Verwandte API-Elemente

import flash.filesystem.*;
import flash.events.Event;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForSave("Save As");
    docsDir.addEventListener(Event.SELECT, saveData);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function saveData(event:Event):void 
{
    var newFile:File = event.target as File;
    var str:String = "Hello.";
    if (!newFile.exists)
    {
        var stream:FileStream = new FileStream();
        stream.open(newFile, FileMode.WRITE);
        stream.writeUTFBytes(str);
        stream.close();
    }
}

Bricht alle ausstehenden asynchronen Vorgänge ab.

Kanonisiert den File-Pfad (macht ihn vorschriftsmäßig).

Wenn das File-Objekt eine vorhandene Datei oder einen vorhandenen Ordner repräsentiert, wird der Pfad bei der Kanonisierung korrigiert, sodass die Groß- und Kleinschreibung dem tatsächlichen Datei- oder Ordnernamen entspricht. Wenn es sich bei dem File-Objekt um einen symbolischen Link handelt, wird er Pfad bei der Kanonisierung so korrigiert, dass er der Datei oder dem Ordner entspricht, auf den der Link zeigt, unabhängig davon, ob die Datei oder der Ordner tatsächlich vorhanden ist. Bei Dateisystemen, die die Groß-/Kleinschreibung berücksichtigen (z. B. unter Linux), passt die canonicalize()-Methode im Fall von mehreren Dateien mit den gleichen Dateinamen, die sich nur in der Groß-/Kleinschreibung unterscheiden, den Pfad auf die erste gefundene Datei an (die Reihenfolge wird durch das Dateisystem bestimmt).

Zusätzlich werden bei der Kanonisierung unter Windows kurze Dateinamen in lange umgewandelt.

import flash.filesystem.*;

var path:File = File.desktopDirectory.resolvePath("air test");
trace(path.nativePath); 
path.canonicalize();
trace(path.nativePath); // ...\AIR Test

import flash.filesystem.*;

var path:File = new File();
path.nativePath = "C:\\AIR~1";
path.canonicalize();
trace(path.nativePath); // C:\AIR Test

Gibt eine Kopie dieses File-Objekts zurück. Ereignisregistrierungen werden nicht kopiert.

Hinweis: Diese Methode kopiert nicht die Datei selbst. Sie erstellt lediglich eine Kopie der Instanz des ActionScript --File-Objekts. Verwenden Sie die copyTo()-Methode, um eine Datei zu kopieren.

Kopiert die Datei oder den Ordner vom Speicherort, der durch dieses File-Objekt festgelegt ist, an den Speicherort, der im newLocation-Parameter festgelegt ist. Beim Kopieren werden die erforderlichen übergeordneten Verzeichnisse erstellt (falls möglich). Wenn sie Dateien mithilfe von copyTo () überschreiben, werden die Dateiattribute auch überschrieben.

Parameter

Verwandte API-Elemente

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:FileReference = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:FileReference = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

if (sourceFile.copyTo(destination, true)) {
    trace("Done.");
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

try 
{
    sourceFile.copyTo(destination, true);
}
catch (error:Error)
{
    trace("Error:", error.message);
}

Beginnt mit dem Kopieren der Datei oder des Verzeichnisses am Speicherort, der durch dieses File-Objekt angegeben wird, an den Speicherort, der durch den destination-Parameter angegeben wird.

Nach dem Abschluss wird entweder ein complete-Ereignis (erfolgreich) oder ein ioError-Ereignis (nicht erfolgreich) ausgelöst. Beim Kopieren werden die erforderlichen übergeordneten Verzeichnisse erstellt (falls möglich).

Parameter

Verwandte API-Elemente

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

sourceFile.copyToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileCopiedHandler);

function fileCopiedHandler(event:Event):void {
    trace("Done.");
}

Erstellt den angegebenen Ordner und alle erforderlichen übergeordneten Ordner. Wenn der Ordner bereits vorhanden ist, wird keine Aktion ausgeführt.

import flash.filesystem.*;

var source:File = File.desktopDirectory.resolvePath("test.txt");
var target:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var targetParent:File = target.parent;
targetParent.createDirectory();
source.moveTo(target, true);

Gibt einen Verweis auf einen neuen temporären Ordner zurück. Dies ist ein neuer Ordner im temporären Ordner des Systems.

Mit dieser Methode können Sie einen neuen, eindeutigen Ordner identifizieren, ohne dass Sie das System abfragen müssen, ob der Ordner neu und eindeutig ist.

Sie sollten in Betracht ziehen, den temporären Ordner zu löschen, bevor Sie die Anwendung schließen, da er auf einigen Geräten nicht automatisch gelöscht wird.

Verwandte API-Elemente

import flash.File;

var temp:File = File.createTempDirectory();
trace(temp.nativePath);

Gibt einen Verweis auf eine neue temporäre Datei zurück. Dies ist eine neue Datei im temporären Ordner des Systems.

Mit dieser Methode können Sie eine neue, eindeutige Datei identifizieren, ohne dass Sie das System abfragen müssen, ob die Datei neu und eindeutig ist.

Da die Datei nicht automatisch gelöscht wird, sollten Sie sie evtl. löschen, bevor Sie die Anwendung schließen.

Verwandte API-Elemente

import flash.File;

var temp:File = File.createTempFile();
trace(temp.nativePath);

Löscht das Verzeichnis. Wenn diese Datei ein symbolischer Link auf einen Ordner ist, wird dieser Link entfernt, nicht der Ordner.

Parameter

Verwandte API-Elemente

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Empty Junk Directory/");
File.createDirectory(directory);
trace(directory.exists); // true
directory.deleteDirectory();
trace(directory.exists); // false

Löscht das Verzeichnis asynchron. Wenn diese Datei ein symbolischer Link auf einen Ordner ist, wird dieser Link entfernt, nicht der Ordner.

Parameter

Verwandte API-Elemente

Löscht die Datei. Wenn diese Datei ein symbolischer Link ist, wird dieser Link entfernt, nicht die Zieldatei.

Verwandte API-Elemente

import flash.filesystem.*;

var file:File = File.createTempFile();
trace(file.exists); // true
file.deleteFile();
trace(file.exists); // false

Löscht die Datei asynchron. Wenn diese Datei ein symbolischer Link ist, wird dieser Link entfernt, nicht die Zieldatei.

Verwandte API-Elemente

Gibt ein Array von File-Objekten zurück, die Dateien und Verzeichnissen im durch dieses File-Objekt repräsentierten Verzeichnis entsprechen. Diese Methode untersucht nicht den Inhalt der Unterverzeichnisse.

Verwandte API-Elemente

import flash.filesystem.File;

var directory:File = File.userDirectory;
var list:Array = directory.getDirectoryListing();
for (var i:uint = 0; i < list.length; i++) {
    trace(list[i].nativePath);
}

Ruft asynchron ein Array von File-Objekten ab, die dem Inhalt des durch dieses File-Objekt repräsentierten Verzeichnisses entsprechen.

Verwandte API-Elemente

import flash.filesystem.File;
import flash.events.FileListEvent;

var directory:File = File.userDirectory;
directory.getDirectoryListingAsync();
directory.addEventListener(FileListEvent.DIRECTORY_LISTING, directoryListingHandler);

function directoryListingHandler(event:FileListEvent):void {
    var list:Array = event.files;
    for (var i:uint = 0; i < list.length; i++) {
        trace(list[i].nativePath);
    }
}

Sucht den relativen Pfad zwischen zwei Dateipfaden.

Der relative Pfad ist die Liste der Komponenten, die an diesen Verweis angehängt werden können, um den zweiten (Parameter-)Verweis zu suchen. Der relative Pfad wird mit dem Trennzeichen „/“ zurückgegeben.

Relative Pfade können optional „..“-Verweise enthalten, sie überschreiten jedoch keine offensichtlichen Datenträgergrenzen.

Parameter

Gibt ein Array von File-Objekten zurück, wobei die Stammverzeichnisse des Dateisystems aufgelistet werden.

Unter Windows ist dies zum Beispiel eine Liste der Datenträger wie Laufwerk C: und Laufwerk D:. Ein leeres Laufwerk, z. B. ein CD- oder DVD-Laufwerk, das keinen Datenträger enthält, ist nicht im Array enthalten. Unter Mac OS und Linux gibt diese Methode immer den eindeutige Stammordner des Geräts zurück (den „/“-Ordner).

Bei Dateisystemen, für die der Stammordner nicht lesbar ist, zum Beispiel beim Android-Dateisystem, spiegeln die Eigenschaften des zurückgegebenen File-Objekts nicht immer den richtigen Wert wieder. Bei Android meldet die spaceAvailable-Eigenschaft zum Beispiel 0.

import flash.filesystem.File;
var rootDirs:Array = File.getRootDirectories();

for (var i:uint = 0; i < rootDirs.length; i++) {
    trace(rootDirs[i].nativePath);
}

Verschiebt die Datei oder das Verzeichnis am Speicherort, der durch dieses File-Objekt angegeben wird, an den Speicherort, der durch den destination-Parameter angegeben wird.

Um eine Datei umzubenennen, stellen Sie den destination-Parameter so ein, dass er auf einen Pfad zeigt, der sich im Verzeichnis der Datei befindet, jedoch einen anderen Dateinamen verwendet.

Beim Verschieben werden die erforderlichen übergeordneten Verzeichnisse erstellt (falls möglich).

Parameter

Verwandte API-Elemente

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

try  
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/Results/test1.txt");

try 
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

Beginnt mit dem Verschieben der Datei oder des Verzeichnisses am Speicherort, der durch dieses File-Objekt angegeben wird, an den Speicherort, der durch den newLocation-Parameter angegeben wird.

Um eine Datei umzubenennen, stellen Sie den destination-Parameter so ein, dass er auf einen Pfad zeigt, der sich im Verzeichnis der Datei befindet, jedoch einen anderen Dateinamen verwendet.

Beim Verschieben werden die erforderlichen übergeordneten Verzeichnisse erstellt (falls möglich).

Parameter

Verwandte API-Elemente

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("Apollo Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

sourceFile.moveToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileMoveCompleteHandler);

function fileMoveCompleteHandler(event:Event):void 
{
    trace("Done.")
}

Verschiebt eine Datei oder ein Verzeichnis in den Papierkorb.

Hinweis: Bei Betriebssystemen, die keinen wiederherstellbaren Papierkorb haben, werden die Dateien sofort gelöscht.

Verwandte API-Elemente

Verschiebt eine Datei oder einen Ordner asynchron in den Papierkorb.

Hinweis: Bei Betriebssystemen, die keinen wiederherstellbaren Papierkorb haben, werden die Dateien sofort gelöscht.

Verwandte API-Elemente

Öffnet die Datei in der Anwendung, die im Betriebssystem für das Öffnen von Dateien dieses Typs registriert ist.

AIR verhindert, dass Sie bestimmte Dateien mit der File.openWithDefaultApplication()-Methode öffnen. Unter Windows verhindert AIR, dass Sie Dateien bestimmter Dateitypen öffnen (Dateien mit bestimmten Erweiterungen, die unten aufgeführt sind). Unter Mac OS und Linux verhindert AIR, dass Sie Dateien öffnen, die in bestimmten, unten aufgeführten Anwendungen gestartet werden. Wenn Sie versuchen, eine dieser Dateien mit der openWithDefaultApplication()-Methode zu öffnen, wird ein Ausnahmefehler ausgegeben. Für AIR-Anwendungen, die mit einem nativen Installationsprogramm installiert wurden (Anwendungen mit dem Profil „erweiterter Desktop“) gelten diese Einschränkungen jedoch nicht; sie können Dateien aller Typen öffnen.

Sie können keine Dokumente aus dem Anwendungsverzeichnis öffnen.

In der folgenden Tabelle sind Dateierweiterungen, die unter Windows unzulässig sind, sowie die nicht zulässigen Anwendungen unter Mac OS und Linux aufgeführt:

Verwandte API-Elemente

import flash.filesystem.File;
import flash.net.FileFilter;

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

Fordert die Berechtigung zum Zugriff auf das Dateisystem an.

Erstellt ein neues File-Objekt mit einem Pfad relativ zum Pfad dieses File-Objekts, basierend auf dem path-Parameter (ein String).

Sie können wie beim path-Parameter einen relativen oder absoluten Pfad verwenden.

Wenn Sie einen relativen Pfad festlegen, wird der festgelegte path an den Pfad des File-Objekts angehängt. Die Verwendung von „..“ im path kann jedoch einen Ergebnispfad zurückgeben, der kein untergeordnetes Element des File-Objekts ist. Der resultierende Verweis muss nicht auf einen tatsächlichen Speicherort in einem Dateisystem verweisen.

Wenn Sie einen absoluten Dateiverweis festlegen, gibt die Methode das File-Objekt, das auf diesen Pfad verweist, zurück. Der absolute Dateiverweis sollte eine gültige Syntax für native Pfade des Betriebssystems des Benutzers verwenden (z. B. "C:\\test" unter Windows). Verwenden Sie keine URLs (z. B. "file:///c:/test") als path-Parameter.

Alle resultierenden Pfade werden wie folgt normalisiert:

• Jedes „.“-Element wird ignoriert.
• Alle „..“-Elemente konsumieren den übergeordneten Eintrag.
• Kein „..“-Verweis, der den Stammordner des Dateisystems oder den anwendungspersistenten Speicherstamm erreicht, passiert diesen Knoten; solche Verweise werden ignoriert.

Als Pfadtrennzeichen sollten Sie immer den Schrägstrich (/) verwenden. Unter Windows können Sie auch den umgekehrten Schrägstrich (\) verwenden, sollten dies allerdings vermeiden. Wenn Sie den umgekehrten Schrägstrich verwenden, funktionieren Ihre Anwendungen auf anderen Plattformen möglicherweise nicht.

Unter Linux muss bei Datei- und Ordnernamen die Groß-/Kleinschreibung berücksichtigt werden.

Parameter

Wird ausgelöst, wenn ein ausstehender asynchroner Vorgang abgebrochen wird.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Wird ausgelöst, wenn ein asynchroner Vorgang abgeschlossen ist.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Wird ausgelöst, wenn eine Ordnerliste als Ergebnis eines Aufrufs der getDirectoryListingAsync()-Methode verfügbar ist.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Wird ausgelöst, wenn während eines asynchronen Dateivorgangs ein Fehler auftritt.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Wird abgesetzt, wenn die Anwendung die Berechtigung zum Zugriff auf das Dateisystem anfordert. Überprüfen Sie den Wert der Eigenschaft Status, um festzustellen, ob die Berechtigung gewährt oder verweigert wurde.

Verwandte API-Elemente

Wird ausgelöst, wenn ein Vorgang eine Sicherheitsbeschränkung verletzt.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Wird ausgelöst, wenn der Benutzer eine Datei oder einen Ordner aus einem Dialogfeld zur Datei- oder Ordnernavigation auswählt.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Wird ausgelöst, wenn der Benutzer Dateien aus einem Dialogfeld auswählt, das durch den Aufruf der browseForOpenMultiple()-Methode geöffnet wurde.

Verwandte API-Elemente