Timer  - AS3

Die Gesamtzahl der Ereignisse, die der Timer ausgelöst hat, seit er bei 0 gestartet wurde. Wenn der Timer zurückgesetzt wurde, werden nur die seitdem erfolgten Ereignisse gezählt.

Die Dauer zwischen den Timerereignissen in Millisekunden. Wenn Sie das Zeitintervall festlegen, während der Timer ausgeführt wird, wird der Timer mit derselben repeatCount-Iteration neu gestartet.

Hinweis: Ein Wert von weniger als 20 Millisekunden für delay wird nicht empfohlen. Die Timer-Frequenz ist auf 60 Bilder pro Sekunde begrenzt. Eine Verzögerung unter 16,6 Millisekunden führt zu Laufzeitproblemen.

Die Gesamtzahl der für den Timer festgelegten Ausführungen. Wenn der Wiederholungstimer auf 0 gesetzt ist, fährt der Timer bis zu einem Maximum von 24,86 Tagen, bis zum Aufrufen der stop()-Methode oder bis zum Beenden des Programms fort. Wenn als Anzahl der Wiederholungen ein Wert ungleich 0 festgelegt ist, wird der Timer entsprechend oft ausgeführt. Wenn für repeatCount ein Wert angegeben ist, der gleich oder kleiner dem Wert von currentCount ist, wird der Timer angehalten und löst keine Ereignisse mehr aus.

Der aktuelle Zustand des Timers. Wird der Timer ausgeführt, ist dieser Wert true, sonst false.

Erstellt ein neues Timerobjekt mit den angegebenen Zuständen für delay und repeatCount.

Der Timer startet nicht automatisch. Sie müssen dazu die start()-Methode aufrufen.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldType;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.Event;

    public class Timer_constructorExample extends Sprite {
            private var statusTextField:TextField = new TextField();        
            private var inputTextField:TextField = new TextField();
            private var delay:uint = 30000;
            private var repeat:uint = 3;
            private var myTimer:Timer = new Timer(delay, repeat);
            
        public function Timer_constructorExample() {
            inputTextField.x = 10;
            inputTextField.y = 10;
            inputTextField.border = true;
            inputTextField.background = true;
            inputTextField.height = 200;
            inputTextField.width = 200;
            inputTextField.multiline = true;
            inputTextField.wordWrap = true;
            inputTextField.type = TextFieldType.INPUT;

            statusTextField.x = 10;
            statusTextField.y = 220;
            statusTextField.background = true;
            statusTextField.autoSize = TextFieldAutoSize.LEFT;   

            myTimer.start(); 
            statusTextField.text = "You have " + ((delay * repeat) / 1000) 
                                 + " seconds to enter your response.";

            myTimer.addEventListener(TimerEvent.TIMER, timerHandler);
            myTimer.addEventListener(TimerEvent.TIMER_COMPLETE, completeHandler);

            addChild(inputTextField);
            addChild(statusTextField);
        }

        private function timerHandler(e:TimerEvent):void{
            repeat--;
            statusTextField.text = ((delay * repeat) / 1000) + " seconds left.";
        }

        private function completeHandler(e:TimerEvent):void {
            statusTextField.text = "Times Up.";
            inputTextField.type = TextFieldType.DYNAMIC;    
        }
    }
}

Hält den Timer an, wenn dieser ausgeführt wird, und setzt die currentCount-Eigenschaft (wie der Reset-Knopf einer Stoppuhr) wieder auf 0. Wird anschließend start() aufgerufen, wird die Timer-Instanz die mit dem repeatCount-Wert festgelegte Anzahl an Wiederholungen ausgeführt.

Verwandte API-Elemente

Startet den Timer, sofern dieser noch nicht ausgeführt wird.

Hält den Timer an. Wird nach der start()-Methode die stop()-Methode aufgerufen, wird die Timer-Instanz die mit dem repeatCount-Wert festgelegte verbleibende Anzahl an Wiederholungen ausgeführt.

Verwandte API-Elemente

Wird ausgelöst, sobald ein Timerobjekt das in der Timer.delay-Eigenschaft festgelegte Intervall erreicht hat.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Wird ausgelöst, sobald die Anzahl der in Timer.repeatCount festgelegten Anforderungen ausgeführt wurde.

Dieses Ereignis verfügt über die folgenden Eigenschaften: