WorkerDomain  - AS3

Die WorkerDomain-Instanz, in der der Code zurzeit ausgeführt wird. Dies ist die einzige WorkerDomain in der Anwendung.

Gibt an, ob die aktuelle Laufzeitumgebung die WorkerDomain und Worker-Objekte für die gleichzeitige Codeausführung (Parallelität) unterstützt.

Wenn Parallelität unterstützt wird, hat diese Eigenschaft den Wert true.

Erstellt eine neue Worker-Instanz aus den Bytes einer SWF-Datei.

Jeder Worker wird aus einer isolierten SWF-Anwendung erstellt und wird als solche ausgeführt. Um eine Worker-Instanz zu erstellen, beziehen Sie die Bytes der SWF-Datei als ByteArray-Instanz und übergeben sie an diese Methode. Es gibt drei gebräuchliche Wege, um zu diesem Zweck auf die Bytes einer SWF-Datei zuzugreifen:

• Verwenden Sie das [Embed]-Metatag, um die SWF-Datei als ByteArray in die Anwendung einzubetten:

      // Embed the SWF file
      [Embed(source="../swfs/BgWorker.swf", mimeType="application/octet-stream")]
      private static var BgWorker_ByteClass:Class;
      
      private function createWorker():void
      {
        // create the background worker
        var workerBytes:ByteArray = new BgWorker_ByteClass();
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• Laden Sie eine externe SWF-Datei unter Verwendung eines URLLoader:

      // load the SWF file
      var workerLoader:URLLoader = new URLLoader();
      workerLoader.dataFormat = URLLoaderDataFormat.BINARY;
      workerLoader.addEventListener(Event.COMPLETE, loadComplete);
      workerLoader.load(new URLRequest("BgWorker.swf"));
      
      private function loadComplete(event:Event):void
      {
        // create the background worker
        var workerBytes:ByteArray = event.target.data as ByteArray;
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• Verwenden Sie eine einzelne SWF-Datei sowohl als ursprünglichen Worker als auch als Hintergrundworker:

      // The primordial worker's main class constructor
      public function PrimordialWorkerClass()
      {
        init();
      }
      
      private function init():void
      {
        var swfBytes:ByteArray = this.loaderInfo.bytes;
        
        // Check to see if this is the primordial worker
        if (Worker.current.isPrimordial)    
        {
          // create a background worker
          var bgWorker:Worker = WorkerDomain.current.createWorker(swfBytes);
          
          // listen for worker state changes to know when the worker is running
          bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
          
          // set up communication between workers using 
          // setSharedProperty(), createMessageChannel(), etc.
          // ... (not shown)
          
          bgWorker.start();
        }
        else // entry point for the background worker
        {
          // set up communication between workers using getSharedProperty()
          // ... (not shown)
          
          // start the background work
        }

Das Erstellen eines Worker-Objekts mit createWorker() startet nicht die Ausführung des Workers. Um die Ausführung des Codes eines Workers zu starten, rufen Sie die start()-Methode des Worker-Objekts auf.

Worker sind hilfreich, da sie die Wahrscheinlichkeit verringern, dass die Framerate aufgrund der Blockierung des Hauptrenderingthreads durch anderen Code abfällt. Auf der anderen Seite erfordern Worker zusätzlichen Systemarbeitsspeicher und CPU-Rechenleistung, was die allgemeine Anwendungsleistung verringern kann. Da jeder Worker seine eigene Instanz der virtuellen Maschine der Laufzeitumgebung verwendet, kann der Mehraufwand auch bei trivialen Workern erheblich ins Gewicht fallen. Wenn Sie Worker verwenden, testen Sie Ihren Code auf allen Zielplattformen, um sicherzustellen, dass die Anforderungen an das System nicht zu groß sind. Adobe empfiehlt, in einem typischen Szenario nicht mehr als ein oder zwei Hintergrundworker zu verwenden.

Parameter

Ermöglicht den Zugriff auf die Workergruppe in der WorkerDomain, die zurzeit ausgeführt werden (die state-Eigenschaft der Worker-Instanz ist WorkerState.RUNNING).