XMLSocket  - AS3

Gibt an, ob dieses XMLSocket-Objekt zurzeit verbunden ist. Sie können sich auch für die Ereignisse connect und ioError registrieren, um zu überprüfen, ob die Verbindung erfolgreich hergestellt werden konnte.

Verwandte API-Elemente

Gibt die Anzahl der Millisekunden an, die auf eine Verbindung gewartet werden soll.

Wenn die Verbindung nicht innerhalb der festgelegten Zeit hergestellt werden kann, schlägt der Verbindungsaufbau fehl. Der Standardwert ist 20.000 (zwanzig Sekunden).

Erstellt ein neues XMLSocket-Objekt. Wenn keine Parameter angegeben werden, wird ein Socket mit getrennter Verbindung erstellt. Wenn Parameter angegeben werden, wird versucht, eine Verbindung zu dem angegebenen Host und Port herzustellen.

Hinweis: Es wird unbedingt empfohlen, das Konstruktor-Formular ohne Parameter zu verwenden, danach die Ereignis-Listener hinzuzufügen und danach die connect-Methode mit host- und port-Parametern aufzurufen. Diese Abfolge stellt sicher, dass alle Ereignis-Listener ordnungsgemäß funktionieren.

Verwandte API-Elemente

Schließt die durch das XMLSocket-Objekt angegebene Verbindung. Das Ereignis close wird nur ausgelöst, wenn der Server die Verbindung schließt. Es wird nicht ausgelöst, wenn Sie die Methode close() aufrufen.

Verwandte API-Elemente

Stellt über den angegebenen TCP-Port eine Verbindung zum angegebenen Internet-Host her.

Wenn Sie für den Parameter host den Wert null angeben, wird der Host kontaktiert, auf dem die Datei gespeichert ist, die XMLSocket.connect() aufgerufen hat. Wenn die aufrufende Datei z. B. von www.adobe.com heruntergeladen wurde und für den host-Parameter null angegeben wurde, bedeutet das, dass Sie eine Verbindung zu www.adobe.com herstellen.

Sie können eine Datei daran hindern, diese Methode aufzurufen, indem Sie auf der HTML-Seite, die den SWF-Inhalt enthält, den Parameter allowNetworking der Tags object und embed festlegen.

Weitere Informationen finden Sie im Flash Player Developer Center im Abschnitt Sicherheit.

Parameter

Verwandte API-Elemente

Wandelt das mit dem Parameter object angegebene XML-Objekt bzw. die angegebenen Daten in einen String um und übermittelt diesen gefolgt von einem Null-Byte (0) an den Server. Wenn es sich bei object um ein XML-Objekt handelt, enthält der String die XML-Textdarstellung des XML-Objekts. Die send-Operation ist asynchron; es erfolgt zwar sofort eine Rückgabe, die Daten werden aber möglicherweise zu einem späteren Zeitpunkt gesendet. Die Methode XMLSocket.send() gibt keinen Wert zurück, der angibt, ob die Daten erfolgreich übermittelt wurden.

Wenn Sie das XMLSocket-Objekt nicht über XMLSocket.connect() mit dem Server verbinden, schlägt der XMLSocket.send()-Vorgang fehl.

Parameter

Verwandte API-Elemente

Wird ausgelöst, wenn der Server die Socketverbindung schließt. Das Ereignis close wird nur ausgelöst, wenn der Server die Verbindung schließt. Es wird nicht ausgelöst, wenn Sie die Methode XMLSocket.close() aufrufen.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Wird nach dem erfolgreichen Aufruf der Methode XMLSocket.connect() ausgelöst.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Wird nach dem Senden oder Empfangen von unformatierten Daten ausgelöst.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Wird beim Auftreten eines I/O-Fehlers ausgelöst, durch den ein Sende- oder Empfangsvorgang fehlschlägt.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Wird ausgelöst, wenn mit einem Aufruf der Methode XMLSocket.connect() versucht wird, eine Verbindung zu einem Server außerhalb der Sicherheitssandbox des Aufrufers oder zu einem Port mit einer niedrigeren Nummer als 1024 herzustellen.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

1. Der XMLSocketExample-Konstruktor erstellt eine XMLSocket-Instanz mit dem Namen socket, übergibt socket an ConfigureListeners() (siehe unten) und ruft dann die Methode connect() für die XMLSocket-Verbindung auf, wobei der Hostname „localhost“ und die Portnummer 8080 verwendet werden.
2. Daraufhin wird die Methode configureListeners() aufgerufen, die für jedes unterstützte XMLSocket-Ereignis Listener hinzufügt:
   • closeHandler(): Listener für das Ereignis close, das nach dem Schließen der Netzwerkverbindung ausgelöst wird.
   • connectHandler(): Listener für das Ereignis connect, das nach dem Herstellen der Netzwerkverbindung ausgelöst wird.
   • dataHandler(): Listener für die data-Ereignisse, die jedes Mal ausgelöst werden, wenn über die XMLSocket-Verbindung neue Daten empfangen werden.
   • progressHandler(): Listener für die progress-Ereignisse, die beim Aufruf von send() und während des Sendevorgangs ausgelöst werden.
   • securityErrorHandler(): Listener für securityError-Ereignisse, die bei dem Versuch ausgelöst werden, mit der falschen Sicherheitseinstellung für die lokale Wiedergabe oder über einen Port mit einer niedrigeren Nummer als 1024 auf den XMLSocket-Server zuzugreifen.
   • ioErrorHandler(): Listener für ioError-Ereignisse, die ausgelöst werden, wenn das Senden oder Empfangen von Daten fehlschlägt.

Hinweise:

• Sie müssen zur Kompilierung der SWF-Datei die Option „Sicherheit bei lokaler Wiedergabe“ auf „Nur auf Netzwerk zugreifen“ setzen.
• Damit dieses Beispiel funktioniert, benötigen Sie einen Server, der in Ihrer Domäne über Port 8080 läuft.
• Wenn Sie Flash Player 9.0.124.0 oder höher ausführen, müssen Sie auf Ihrem Server eine Socket-Richtliniendatei ablegen, die Socket-Verbindungen von Ihrer Domäne zu Port 8080 zulässt. Informationen zum Bereitstellen von Socket-Richtliniendateien finden Sie im Flash Player Developer Center im Abschnitt Einrichten eines Servers für Socket-Richtliniendateien.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.XMLSocket;

    public class XMLSocketExample extends Sprite {
        private var hostName:String = "localhost";
        private var port:uint = 8080;
        private var socket:XMLSocket;

        public function XMLSocketExample() {
            socket = new XMLSocket();
            configureListeners(socket);
            if (hostName && port) {
                socket.connect(hostName, port);
            }
        }

        public function send(data:Object):void {
            socket.send(data);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CLOSE, closeHandler);
            dispatcher.addEventListener(Event.CONNECT, connectHandler);
            dispatcher.addEventListener(DataEvent.DATA, dataHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
        }

        private function closeHandler(event:Event):void {
            trace("closeHandler: " + event);
        }

        private function connectHandler(event:Event):void {
            trace("connectHandler: " + event);
        }

        private function dataHandler(event:DataEvent):void {
            trace("dataHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
    }
}