DataGridEvent  - AS3 Flash

Ruft den Namen des Felds oder der Eigenschaft in den Daten ab, die der Spalte zugeordnet sind, oder legt diesen fest.

Ruft den Element-Renderer des bearbeiteten Elements oder der Header-Renderer des Headers ab, auf den geklickt oder dessen Größe geändert wird.

Ruft den Grund ab, warum das itemEditEnd-Ereignis ausgelöst wurde. Diese Eigenschaft ist nur für Ereignisse des Typs DataGridEvent.ITEM_EDIT_END gültig.

Die möglichen Werte sind in der DataGridEventReason-Klasse definiert.

Verwandte API-Elemente

Erstellt ein neues DataGridEvent-Objekt mit den angegebenen Parametern.

Verwandte API-Elemente

Erstellt eine Kopie des DataGridEvent-Objekts und stellt die Werte der einzelnen Eigenschaften so ein, dass sie den Werten des Originals entsprechen.

Gibt einen String zurück, der alle Eigenschaften des DataGridEvent-Objekts enthält. Der String liegt im folgenden Format vor:

[ DataGridEvent type= value bubbles= value cancelable= value columnIndex= value rowIndex= value itemRenderer= value dataField= value reason= value]

Die Konstante DataGridEvent.COLUMN_STRETCH definiert den Wert der Eigenschaft type eines columnStretch-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var dp:DataProvider = new DataProvider();
dp.addItem({col1:"item 1.A", col2:"item 1.B", col3:"item 1.C"});
dp.addItem({col1:"item 2.A", col2:"item 2.B", col3:"item 2.C"});
dp.addItem({col1:"item 3.A", col2:"item 3.B", col3:"item 3.C"});
dp.addItem({col1:"item 4.A", col2:"item 4.B", col3:"item 4.C"});

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn("col1");
myDataGrid.addColumn("col2");
myDataGrid.addColumn("col3");
myDataGrid.dataProvider = dp;
myDataGrid.setSize(300, 200);
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.COLUMN_STRETCH, columnStretchHandler);
addChild(myDataGrid);

function columnStretchHandler(event:DataGridEvent):void {
    var dg:DataGrid = event.target as DataGrid;
    var column:DataGridColumn;
    var columnArray:Array = dg.columns;
    var dgColWidth:String;
    trace("resized column:", event.dataField);
    trace("columnIndex:", event.columnIndex);
    for each (column in columnArray) {
        dgColWidth = Number(column.width / dg.width * 100).toFixed(1);
        trace(column.dataField + ".width:", column.width + " pixels (" + dgColWidth + "%)");
    }
    trace("----------");
}

Die Konstante DataGridEvent.HEADER_RELEASE definiert den Wert der Eigenschaft type eines columnStretch-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var dp:DataProvider = new DataProvider();
dp.addItem({col1:"item 1.A", col2:"item 1.B", col3:"item 1.C"});
dp.addItem({col1:"item 2.A", col2:"item 2.B", col3:"item 2.C"});
dp.addItem({col1:"item 3.A", col2:"item 3.B", col3:"item 3.C"});
dp.addItem({col1:"item 4.A", col2:"item 4.B", col3:"item 4.C"});

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn("col1");
myDataGrid.addColumn("col2");
myDataGrid.addColumn("col3");
myDataGrid.dataProvider = dp;
myDataGrid.setSize(300, 200);
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.HEADER_RELEASE, headerReleaseHandler);
addChild(myDataGrid);

function headerReleaseHandler(event:DataGridEvent):void {
    var dg:DataGrid = event.target as DataGrid;
    trace("dataField:", event.dataField, "(columnIndex:" + event.columnIndex + ")");
    trace("sortIndex:", dg.sortIndex);
    trace("sortDescending:", dg.sortDescending);
    trace("----------");
}

Die DataGridEvent.ITEM_EDIT_BEGIN-Konstante definiert den Wert der type-Eigenschaft eines itemEditBegin-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Die DataGridEvent.ITEM__EDIT_BEGINNING-Konstante definiert den Wert der type-Eigenschaft eines itemEditBeginning-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Die DataGridEvent.ITEM_EDIT_END-Konstante definiert den Wert der type-Eigenschaft eines itemEditEnd-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Die DataGridEvent.ITEM_FOCUS_IN-Konstante definiert den Wert der type-Eigenschaft eines itemFocusIn-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Die DataGridEvent.ITEM_FOCUS_OUT-Konstante definiert den Wert der type-Eigenschaft eines itemFocusOut-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Gehen Sie wie folgt vor, um das Beispiel auszuführen:

1. Fügen Sie die DataGrid-Komponente zur Bibliothek hinzu.
2. Speichern Sie diesen Code unter DataGridEventExample.as im gleichen Verzeichnis wie die FLA-Datei.
3. Legen Sie in der FLA-Datei als Dokumentklasse den Wert "DataGridEventExample" fest.

package
{
    import fl.controls.DataGrid;
    import fl.data.DataProvider;
    import fl.events.DataGridEvent;
    import fl.events.DataGridEventReason;
    import flash.display.Sprite;
    
    public class DataGridEventExample extends Sprite
    {
        private var dg:DataGrid;
        
        public function DataGridEventExample() {
            createDataGrid();
        }
        private function createDataGrid():void {
            dg = new DataGrid();
            addChild(dg);
            dg.setSize(200,300);
            dg.editable = true;
            
            var dp:DataProvider = new DataProvider();
            var i:uint;
            var totalRows:uint = 42;
            for(i=0; i<totalRows; i++) {
                dp.addItem( {     col1:getRandomNumber(),
                                   col2:getRandomNumber(),
                                col3:getRandomNumber() } );
            }
            dg.dataProvider = dp;
            dg.addEventListener(DataGridEvent.ITEM_EDIT_BEGIN, announceEditBegin);
            dg.addEventListener(DataGridEvent.ITEM_EDIT_END, announceEditEnd);
        }
        private function announceEditBegin(e:DataGridEvent):void {
            trace("Edit Begin on row: " + e.rowIndex + " col: " + e.columnIndex);    
        }
        private function announceEditEnd(e:DataGridEvent):void {
            var reason:String;
            switch(e.reason) {
                case DataGridEventReason.CANCELLED:
                    reason = "User cancelled edit";
                    break;
                case DataGridEventReason.NEW_ROW:
                    reason = "User focused to another row";
                    break;
                case DataGridEventReason.NEW_COLUMN:
                    reason = "User focused to another column";
                    break;
                case DataGridEventReason.OTHER:
                default:
                    reason = "Edit ended for other reason";
                    reason = e.reason;
                    break;                
            }
            trace("Edit End on row: " + e.rowIndex + " col: " + e.columnIndex);
            trace("Reason: " + reason.toString());    
        }
        private function getRandomNumber():uint {
            return Math.round(Math.random()*100);
        }
    }
}