JSON  - AS3

Akzeptiert einen String im JSON-Format und gibt ein ActionScript-Objekt zurück, das diesen Wert darstellt. JSON-Objekte, -Arrays, -Strings, -Zahlen, -Booleans sowie Null werden entsprechenden ActionScript-Werten zugeordnet, wie unten aufgeführt:

Der reviver-Parameter ist eine Funktion, der zwei Parameter verwendet: einen Schlüssel und einen Wert. Sie können diese Funktion verwenden, um jedes Schlüssel/Wert-Paar beim Parsen zu transformieren oder zu filtern. Wenn Sie eine reviver-Funktion angeben, wird in der Ausgabe der parse()-Funktion für jedes Paar der transformierte oder gefilterte Wert anstatt des Standardparsings zurückgegeben. Wenn die reviver-Funktion für ein Paar undefined zurückgibt, wird die Eigenschaft aus dem endgültigen Ergebnis gelöscht.

Wenn das an den reviver-Parameter übergebene Argument keine Funktion ist, gibt ActionScript einen TypeError mit der Fehler-ID kJSONInvalidReviver aus. Außerdem wird eine lokalisierte Fehlermeldung angezeigt.

Wenn die parse()-Funktion innerhalb eines Objekts doppelt vorhandene Schlüssel erkennt, stellt das zuletzt gefundene Duplikat des Schlüssels den Wert für alle vorhergehenden Vorkommnisse des Schlüssels bereit.

Parameter

Gibt einen String im JSON-Format zurück, der einen ActionScript-Wert darstellt. Die stringify-Methode kann drei Parameter akzeptieren.

Der value-Parameter ist erforderlich. Dieser Parameter ist ein ActionScript-Wert. Normalerweise handelt es sich um ein Objekt oder ein Array, es kann aber auch ein String, ein boolescher Ausdruck, eine Zahl oder null sein.

Der optionale replacer-Parameter kann eine Funktion oder ein Array von Strings oder Zahlen sein. Wenn es sich um eine Funktion handelt, verwendet diese zwei Parameter: einen Schlüssel und einen Wert. Sie können diese Funktion verwenden, um jedes Schlüssel/Wert-Paar beim Parsen zu transformieren oder zu filtern. Wenn Sie eine replacer-Funktion angeben, wird in der Ausgabe der parse()-Funktion für jedes Paar der transformierte oder gefilterte Wert anstatt des Standardparsings zurückgegeben. Wenn die replacer-Funktion für ein Paar undefined zurückgibt, wird die Eigenschaft aus dem endgültigen Ergebnis gelöscht. Wenn es sich bei replacer um ein Array handelt, wird dieses als Filter verwendet, um zu bestimmen, welche Eigenschaften in der Ausgabe enthalten sind.

Wenn das an den replacer-Parameter übergebene Argument weder ein Array noch eine Funktion ist, gibt ActionScript einen TypeError mit der Fehler-ID kJSONInvalidReplacer aus. Außerdem wird eine lokalisierte Fehlermeldung angezeigt.

Der optionale space-Parameter ist ein String oder eine Zahl, der/die es zulässt, dass Leerraum in den zurückgegebenen String eingefügt wird, um die Lesbarkeit zu verbessern. Einträge in generierten JSON-Objekten und JSON-Arrays werden durch eine Lücke getrennt, die aus dem space-Parameter abgeleitet wird. Die Lücke ist immer 0 bis 10 Zeichen breit. Wenn es sich bei „space“ um einen String handelt, besteht die abgeleitete Lücke aus den ersten zehn Zeichen dieses Strings. Wenn es sich bei „space“ um eine nicht negative Zahl x handelt, beträgt die Lücke x Leerzeichen, jedoch maximal zehn Leerzeichen. Wenn es sich bei dem an den space-Parameter übergebenen Argument nicht um einen String oder eine Zahl handelt, wird es in einen String konvertiert, der als Lücke in der Ausgabe verwendet wird. Die Ausführung wird dann fortgesetzt.

Wenn die stringify()-Methode eine zyklische Struktur erkennt, wird ein TypeError mit der Fehler-ID kJSONCyclicStructure ausgegeben. Außerdem wird eine lokalisierte Fehlermeldung angezeigt.

Parameter

1. Der Konstruktor für JSONExample weist dem text-Mitglied der übergeordneten Klasse einen String zu und initialisiert einen internen Zähler.
2. Zusätzlich definiert die Klasse ein Array, das JSONExample-Objekte enthalten kann, die nach JSON exportiert wurden.
3. JSONExample definiert außerdem eine toJSON()-Methode und eine revive()-Methode. Die toJSON()-Methode wird von JSON.stringify() aufgerufen, um JSONExample-Objekte für JSON zu serialisieren. Die revive()-Methode kann von JSON.parse()-Methoden aufgerufen werden, um das vollständige JSONExample-Objekt wiederherzustellen. Diese Wiederherstellung wird erreicht, indem eine gegebene ID verwendet wird, um das Originalobjekt aus dem Array mit wiederherstellbaren Objekten abzurufen.
4. Das Skript, das die Klassendefinition verwendet, erstellt ein Objekt, das zwei TextField-Objekte und ein JSONExample-Objekt enthält. Es erstellt auch ein Array für wiederherstellbare Objekte zum Speichern von TextField-Objekten, die nach JSON exportiert wurden.
5. Die replacer-Funktion von JSON.stringify() filtert TextField-Objekte aus dem JSON-String. Als Ersatz für jedes entfernte Objekt stellt replacer einen Marker mit einer ID bereit, mit dem sich das betreffende Objekt später abrufen lässt. JSONExample-Objekte passieren dagegen entsprechend ihrer nativen JSON-Kodierung.
6. Die reviver-Funktion der parse()-Methode stellt das Originalobjekt wieder her, indem alle referenzierten TextField- und JSONExample-Objekte abgerufen werden.

 
 package {
    import flash.text.TextField;
    public class JSONExample extends TextField
    {
        static var nextId = 10000;
        static var revivable_objects:Array = [];
            public var id;

        public function JSONExample(s:String){
            super.text = s;
            id = ++nextId;
        }
        public function toJSON(k):*
        {
            // To be called internally by the JSON.stringify() method.
            // Save the original object internally.
            // Write out only a generated ID and the text value.
            revivable_objects[id] = this;
            return {"classJSONExample":{"reviveId":id,"contents":this.text}};
        }
        public static function revive(id:int):JSONExample
        {
            // For explicit use in the JSON.parse() method.
            // Revives the object using the ID obtained from the JSON string.
            return revivable_objects[id];
        }
    }
}

import flash.text.TextField;

var lastId = 20000;
var tf1:TextField = new TextField();
tf1.text = "Lorem ipsum";
var tf2:TextField = new TextField();
tf2.text = "Laughing cows";
var nt:JSONExample = new JSONExample("It was the best of times; it was the worst of times.");

var obj:Object = {a:tf1, b:nt, c:tf2};
var revivable_objects:Array = new Array();

var json_out = JSON.stringify(obj, function(k,v){
        if (v is JSONExample)
        {
            // Send JSONExample objects to the JSON output.
            // Note that stringify() calls JSONExample.toJSON() to serialize this object.
            return v;
        }
        if (v is TextField)
        {
            // Remove TextField objects from the JSON output.
            // Save the original object for reviving later.
            // Return a new object containing an identification marker
            // and the original object's revival ID.
            revivable_objects[++lastId] = v;
            return {"classTextField":{"reviveId":lastId}};
        }
        return v;
    }
);
               
trace("json_out: " + json_out);

var json_in = JSON.parse(json_out, function(k,v) {
        if ("classTextField" in v) { // special marker tag from stringify() replacer code
            // Retrieve the original object based on the ID stored in the stringify() replacer function.
            var id = v["classTextField"].reviveId;
            return revivable_objects[id];
        } else if ("classJSONExample" in v){
            // Retrieve the original object based on the ID generated in JSONExample.toJSON().
            return JSONExample.revive(v["classJSONExample"].reviveId);
        }
        return v;
    }
);

if (json_in.a)
{
    if (json_in.a.hasOwnProperty("text"))
        {
            trace("json_in.a: " + json_in.a.text);
        }
}
if (json_in.b)
{
    if (json_in.b.hasOwnProperty("text"))
        {
            trace("json_in.b: " + json_in.b.text);
        }
}

if (json_in.c)
{
    if (json_in.c.hasOwnProperty("text"))
        {
            trace("json_in.c: " + json_in.c.text);
        }
}