Trabalho com objetos File no AIR

Você pode usar a classe File para o seguinte:

• Obter o caminho para diretórios especiais, incluindo o diretório do usuário, o diretório de documentos do usuário, o diretório do qual o aplicativo foi iniciado e o diretório de aplicativo.

• Cópia de arquivos e diretórios

• Movimentação de arquivos e diretórios.

• Exclusão de arquivos e diretórios (ou movimentação para a lixeira)

• Lista de arquivos e diretórios contidos em um diretório

• Criação de arquivos e pastas temporários

Depois que o objeto File aponta para um caminho de arquivo, você pode usá-lo para ler e gravar dados de arquivo, usando a classe FileStream.

O objeto File pode apontar para o caminho de um arquivo ou diretório que ainda não existe. Você pode usar esse objeto File na criação de arquivos ou diretórios.

Cada objeto File tem duas propriedades que definem cada uma o caminho do objeto:

A classe File inclui propriedades estáticas de indicação de diretórios padrão no Mac OS, no Windows e no Linux. Essas propriedades incluem:

Estas propriedades têm valores diferentes em diferentes sistemas operacionais. Por exemplo, o Mac e o Windows têm caminhos nativos diferentes para o diretório de área de trabalho do usuário. Entretanto, a propriedade File.desktopDirectory aponta para um caminho de diretório apropriado em cada plataforma. Para gravar aplicativos que funcionam bem em várias plataformas, use essas propriedades como base para fazer referência a outros diretórios e arquivos usados pelo aplicativo. Use o método resolvePath() para refinar o caminho. Por exemplo, esse código aponta para o arquivo preferences.xml no diretório de armazenamento do aplicativo:

var prefsFile:File = File.applicationStorageDirectory; 
prefsFile = prefsFile.resolvePath("preferences.xml");

Embora a classe File permita apontar para um caminho específico de arquivo, fazer isso pode levar a aplicativos que não funcionam em várias plataformas. Por exemplo, o caminho C:\Documents and Settings\joe\ só funciona no Windows. Por essas razões, é melhor usar as propriedades estáticas da classe File, como File.documentsDirectory .

Os caminhos nativos reais desses diretórios variam com base no sistema operacional e na configuração do computador. Os caminhos mostrados nesta tabela são exemplos típicos. Você deve sempre usar as propriedades estáticas apropriadas da classe File para fazer referência a esses diretórios, de modo que o seu aplicativo funcione corretamente em qualquer plataforma. No aplicativo do AIR real, os valores de applicationID e filename mostrados na tabela são obtidos do descritor do aplicativo. Se você especificar uma ID de editor no descritor do aplicativo, a ID de editor será anexada à ID do aplicativo nesses caminhos. O valor de userName é o nome da conta do usuário que faz a instalação.

Há maneiras diferentes de configurar o objeto File para apontar para um diretório.

Há maneiras diferentes de definir o arquivo para o qual o objeto File aponta.

Você também pode modificar o caminho de um objeto File existente, chamando o método resolvePath() ou modificando a propriedade nativePath ou url do objeto, conforme nos exemplos a seguir (no Windows):

var file1:File = File.documentsDirectory; 
file1 = file1.resolvePath("AIR Test"); 
trace(file1.nativePath); // C:\Documents and Settings\userName\My Documents\AIR Test 
var file2:File = File.documentsDirectory; 
file2 = file2.resolvePath(".."); 
trace(file2.nativePath); // C:\Documents and Settings\userName 
var file3:File = File.documentsDirectory; 
file3.nativePath += "/subdirectory"; 
trace(file3.nativePath); // C:\Documents and Settings\userName\My Documents\subdirectory 
var file4:File = new File(); 
file4.url = "file:///c:/AIR Test/test.txt"; 
trace(file4.nativePath); // C:\AIR Test\test.txt 

Ao usar a propriedade nativePath , use o caractere de barra invertida (/) como caractere de separação de diretório. No Windows, você também pode usar o caractere de barra invertida (\), mas você não deve fazer isso, pois ele leva a um código que não funciona em várias plataformas.

No AIR, você pode usar qualquer um dos seguintes esquemas URL na definição da propriedade url de um objeto File:

file:///c:/AIR Test/test.txt

app:/images

app-storage:/settings/prefs.xml

Determinados sistemas operacionais, sobretudo o iOS e o Mac OS X, oferecem aos usuários a capacidade de fazer backup de arquivos de aplicativo automaticamente para um armazenamento remoto. Além disso, há restrições no iOS no que diz respeito à possibilidade de os arquivos serem copiados ou não e ao local em que arquivos de diferentes propósitos podem ser armazenados.

A seção a seguir resume como cumprir as diretrizes da Apple para backup e armazenamento de arquivos. Para obter mais informações, consulte as próximas seções.

• Para determinar se um arquivo não precisa de backup e (somente para iOS) pode ser excluído pelo sistema operacional caso o espaço de armazenamento do dispositivo seja insuficiente, salve o arquivo no diretório do cache ( File.cacheDirectory ). Esse é o local de armazenamento preferencial no iOS e deve ser utilizado para a maioria dos arquivos que podem ser restaurados ou baixados novamente.

• Para determinar que um arquivo, embora não precise de backup, não deve ser excluído pelo sistema operacional, salve o arquivo em um dos diretórios da biblioteca de aplicativos, como o diretório de armazenamento de aplicativos ( File.applicationStorageDirectory ) ou o diretório de documentos ( File.documentsDirectory ). Defina a propriedade preventBackup do objeto File como true . Trata-se de uma exigência da Apple para conteúdos que possam ser restaurados ou novamente baixados, mas que constituem um requisito para o funcionamento adequado de seu aplicativo durante o uso offline.

Você pode usar o método getRelativePath() para localizar o caminho relativo entre dois arquivos:

var file1:File = File.documentsDirectory.resolvePath("AIR Test"); 
var file2:File = File.documentsDirectory 
file2 = file2.resolvePath("AIR Test/bob/test.txt"); 
 
trace(file1.getRelativePath(file2)); // bob/test.txt 

O segundo parâmetro do método getRelativePath() , o parâmetro useDotDot , permite que a sintaxe .... seja retornada nos resultados, para indicar diretórios pai:

var file1:File = File.documentsDirectory; 
file1 = file1.resolvePath("AIR Test"); 
var file2:File = File.documentsDirectory; 
file2 = file2.resolvePath("AIR Test/bob/test.txt"); 
var file3:File = File.documentsDirectory; 
file3 = file3.resolvePath("AIR Test/susan/test.txt"); 
 
trace(file2.getRelativePath(file1, true)); // ../.. 
trace(file3.getRelativePath(file2, true)); // ../../bob/test.txt 

No Windows e no Mac OS, os nomes e caminhos de arquivo não fazem distinção entre letras maiúsculas e minúsculas. No exemplo a seguir, dois objetos File apontam para o mesmo arquivo:

File.documentsDirectory.resolvePath("test.txt"); 
File.documentsDirectory.resolvePath("TeSt.TxT");

No entanto, nomes de documentos e de diretórios incluem o uso de maiúsculas e minúsculas. Por exemplo, o seguinte assume que há uma pasta com nome AIR Test no diretório de documentos, como nos exemplos a seguir:

var file:File = File.documentsDirectory.resolvePath("AIR test"); 
trace(file.nativePath); // ... AIR test 
file.canonicalize(); 
trace(file.nativePath); // ... AIR Test 

O método canonicalize() converte o objeto nativePath para usar maiúsculas e minúsculas corretas para o nome de arquivo ou de diretório. Em sistemas de arquivo que fazem distinção entre maiúsculas e minúsculas (como Linux), quando vários arquivos possuem nomes cuja distinção é somente a letra maiúscula ou minúscula, o método canonicalize() ajusta o caminho para que corresponda ao primeiro arquivo encontrado (em uma ordem determinada pelo sistema de arquivos).

Você também pode usar o método canonicalize() para converter nomes de arquivos pequenos (nomes "8,3") em nomes de arquivos longos do Windows, como nos exemplos seguintes:

var path:File = new File(); 
path.nativePath = "C:\\AIR~1"; 
path.canonicalize(); 
trace(path.nativePath); // C:\AIR Test

Vários sistemas operacionais oferecem suporte a arquivos de pacote e arquivos de link simbólico:

Pacotes – No Mac OS, os diretórios podem ser designados como pacotes e mostrados no Finder do Mac OS como um arquivo único, em vez de um diretório.

Links simbólicos — O Mac OS, o Linux e o Windows Vista oferecem suporte a links simbólicos. Os links simbólicos permitem que um arquivo aponte para outro arquivo ou diretório no disco. Embora semelhantes, os links simbólicos não são o mesmo que alias. O alias é sempre reportado como arquivo (em vez de diretório), e ler ou gravar em um alias ou atalho nunca afeta o diretório ou arquivo original para o qual ele aponta. Por outro lado, o link simbólico se comporta exatamente como o arquivo ou diretório para o qual aponta. Ele pode ser reportado como um arquivo ou diretório, e ler ou gravar em um link simbólico afetará o arquivo ou diretório para o qual ele aponta, não o link simbólico propriamente dito. Além disso, no Windows, a propriedade isSymbolicLink de um objeto File que faça referência a um ponto de junção (usado no sistema de arquivos NTFS) é definida como true .

A classe File inclui as propriedades isPackage e isSymbolicLink para verificar se o objeto File faz referência a um pacote ou link simbólico.

O código a seguir percorre o diretório da área de trabalho do usuário, listando subdiretórios que não sejam pacotes:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (desktopNodes[i].isDirectory && !desktopNodes[i].isPackage) 
    { 
        trace(desktopNodes[i].name); 
    } 
} 

O código a seguir percorre o diretório da área de trabalho do usuário, listando arquivos e diretórios que não sejam links simbólicos:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (!desktopNodes[i].isSymbolicLink) 
    { 
        trace(desktopNodes[i].name); 
    } 
} 

O método canonicalize() altera o caminho do link simbólico para apontar para o arquivo ou diretório ao qual o link se refere. O código a seguir percorre o diretório da área de trabalho do usuário e relata os caminhos referenciados pelos arquivos que sejam links simbólicos:

var desktopNodes:Array = File.desktopDirectory.getDirectoryListing(); 
for (var i:uint = 0; i < desktopNodes.length; i++)  
{ 
    if (desktopNodes[i].isSymbolicLink) 
    { 
        var linkNode:File = desktopNodes[i] as File; 
        linkNode.canonicalize(); 
        trace(linkNode.nativePath); 
    } 
} 

A propriedade spaceAvailable do objeto File é o espaço disponível para uso no local do File, em bytes. Por exemplo, o código a seguir verifica o espaço disponível no diretório de armazenamento do aplicativo:

trace(File.applicationStorageDirectory.spaceAvailable); 

Se o objeto File fizer referência a um diretório, a propriedade spaceAvailable indicará o espaço no diretório que os arquivos podem usar. Se o objeto File fizer referência a um arquivo, a propriedade spaceAvailable indicará o espaço no qual o arquivo poderá crescer. Se o local do arquivo não existir, a propriedade spaceAvailable será definida como 0. Se o objeto File fizer referência a um link simbólico, a propriedade spaceAvailable será definida como espaço disponível no local para o qual o link simbólico aponta.

Geralmente o espaço disponível para um diretório ou arquivo é igual ao espaço disponível no volume que contém o diretório ou o arquivo. No entanto, o espaço disponível pode levar em conta limites por cotas e por diretório.

A adição de um arquivo ou diretório a um volume geralmente requer mais espaço que o tamanho real do arquivo ou o tamanho do conteúdo do diretório. Por exemplo, o sistema operacional pode exigir mais espaço para armazenar informações sobre índice. Ou os setores de disco necessários podem usar espaço adicional. Além disso, o espaço disponível muda dinamicamente. Dessa forma, você não poderá alocar todo o espaço informado para o armazenamento de arquivos. Para obter informações sobre como gravar no sistema de arquivos, consulte Leitura e gravação de arquivos .

O método StorageVolumeInfo.getStorageVolumes() fornece informações mais detalhadas sobre os volumes montados de armazenamento (consulte Trabalho com volumes de armazenamento ).

No AIR 2, você pode abrir um arquivo usando o aplicativo registrado pelo sistema operacional para abri-lo. Por exemplo, um aplicativo do AIR pode abrir um arquivo DOC com o aplicativo registrado para abri-lo. Utilize o método openWithDefaultApplication() de um objeto File para abrir o arquivo. Por exemplo, o código a seguir abre um arquivo chamado test.doc no computador do usuário e abre-o com o aplicativo padrão para os arquivos DOC:

var file:File = File.deskopDirectory; 
file = file.resolvePath("test.doc"); 
file.openWithDefaultApplication();

O código a seguir permite que o usuário navegue até um arquivo mp3 e abra-o no aplicativo padrão para reproduzir arquivos mp3:

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

Você não pode usar o método openWithDefaultApplication() com arquivos localizados no diretório do aplicativo.

O AIR impede que você use o método openWithDefaultApplication() para abrir certos arquivos. No Windows, o AIR impede que você abra os arquivos que têm certos tipos de arquivos, como EXE ou BAT. No Mac OS, o AIR impede que você abra arquivos que serão lançados em certos aplicativos. (Incluindo Terminal e AppletLauncher no Mac OS, e csh, bash ou ruby no Linux). Tentar abrir um desses arquivos que usam o método openWithDefaultApplication() resulta em uma exceção. Para ver uma lista completa dos tipos de arquivo impedidos, consulte a entrada de referência de linguagem para o método File.openWithDefaultApplication() .