URLLoader  - AS3

로드 작업 중 지금까지 로드한 바이트 수를 나타냅니다.

다운로드한 데이터의 총 바이트 수를 나타냅니다. 이 속성은 로드 작업이 진행 중인 경우에는 0을 포함하고 작업이 완료되면 채워집니다. 또한 Content-Length 머리글이 누락되면 총 바이트 수가 확정되지 않습니다.

로드 작업으로 수신된 데이터입니다. 이 속성은 로드 작업이 완료된 때만 채워집니다. 데이터의 형식은 dataFormat 속성의 설정에 따라 달라집니다.

dataFormat 속성이 URLLoaderDataFormat.TEXT인 경우 수신된 데이터는 로드된 파일의 텍스트가 포함된 문자열입니다.

dataFormat 속성이 URLLoaderDataFormat.BINARY인 경우 수신된 데이터는 원시 이진 데이터가 포함된 ByteArray 객체입니다.

dataFormat 속성이 URLLoaderDataFormat.VARIABLES인 경우 수신된 데이터는 URL 인코딩된 변수가 포함된 URLVariables 객체입니다.

관련 API 요소

//params.txt is a local file that includes: firstName=Tom&lastName=Jones
var lbl:TextField = new TextField();
var urlRequest:URLRequest = new URLRequest("params.txt");
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.VARIABLES;
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    lbl.text = urlLoader.data.lastName + "," + urlLoader.data.firstName;
    addChild(lbl);
}

다운로드하는 데이터를 텍스트(URLLoaderDataFormat.TEXT), 원시 이진 데이터(URLLoaderDataFormat.BINARY) 또는 URL 인코딩된 변수(URLLoaderDataFormat.VARIABLES) 중 어떤 형식으로 수신할 것인지 제어합니다.

dataFormat 속성 값이 URLLoaderDataFormat.TEXT인 경우 수신된 데이터는 로드된 파일의 텍스트가 포함된 문자열입니다.

dataFormat 속성 값이 URLLoaderDataFormat.BINARY인 경우 수신된 데이터는 원시 이진 데이터가 포함된 ByteArray 객체입니다.

dataFormat 속성 값이 URLLoaderDataFormat.VARIABLES인 경우 수신된 데이터는 URL 인코딩된 변수가 포함된 URLVariables 객체입니다.

기본값: URLLoaderDataFormat.TEXT.

관련 API 요소

var PATH:String = "lorem.txt";
var urlRequest:URLRequest = new URLRequest(PATH);
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.TEXT; // default
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    textArea.text = urlLoader.data;
}

URLLoader 객체를 만듭니다.

관련 API 요소

리스너에서 이벤트 알림을 받을 수 있도록 EventDispatcher 객체에 이벤트 리스너 객체를 등록합니다. 표시 목록의 모든 노드에서 특정 유형의 이벤트, 단계, 우선 순위에 대한 이벤트 리스너를 등록할 수 있습니다.

이벤트 리스너의 등록을 마친 뒤에는 addEventListener()를 추가로 호출하여 그 우선 순위를 변경할 수 없습니다. 리스너의 우선 순위를 변경하려면 먼저 removeListener()를 호출해야 합니다. 그런 다음 해당 리스너를 새로운 우선 순위 레벨로 다시 등록할 수 있습니다.

일단 리스너가 등록된 뒤에 type 또는 useCapture 값을 달리하여 addEventListener()를 이어서 호출하면 별도의 리스너 등록이 생성된다는 것에 유의합니다. 예를 들어 useCapture가 true로 설정된 리스너를 등록하면 이 리스너는 캡처 단계 동안에만 수신합니다. 그러나 useCapture를 false로 설정하고 동일한 리스너 객체를 사용하여 addEventListener()를 다시 호출하면 별도로 두 개의 리스너가 등록되어, 한 리스너는 캡처 단계 동안 수신하고 다른 하나는 대상 및 버블링 단계 동안 수신합니다.

대상 단계 또는 버블링 단계 전용의 이벤트 리스너를 등록할 수는 없습니다. 버블링은 대상 노드의 조상에만 적용되기 때문에 이들 단계는 등록 과정에서 하나로 통합됩니다.

사용하지 않는 이벤트 리스너는 removeEventListener()를 호출하여 제거하도록 합니다. 이렇게 하지 않으면 메모리 문제가 발생할 수 있습니다. useWeakReference 매개 변수가 true로 설정되지 않은 경우 전달하는 객체가 있는 한, 가비지 수집기는 이벤트 리스너를 제거하지 않으므로 리스너는 메모리에서 자동으로 제거되지 않습니다.

EventDispatcher 인스턴스를 복사해도 연결된 이벤트 리스너는 복사되지 않습니다. 새로 만든 노드에 이벤트 리스너가 필요한 경우, 노드를 만든 후 리스너를 연결해야 합니다. 그러나 EventDispatcher 인스턴스를 이동할 때에는 연결된 이벤트 리스너도 함께 이동됩니다.

이벤트를 처리 중인 노드에서 이벤트 리스너를 등록하는 경우, 그 이벤트 리스너는 현재 단계 동안에는 트리거되지 않지만 이벤트 흐름에서 이후 단계(예: 버블링 단계) 동안에는 트리거될 수 있습니다.

이벤트를 처리 중인 노드에서 이벤트 리스너를 제거하는 경우, 그 리스너는 현재 액션에 의해 트리거됩니다. 일단 제거된 이벤트 리스너는 이후의 처리를 위해 재등록하지 않는 한 다시는 호출되지 않습니다.

매개 변수

function(evt:Event):void

진행 중인 로드 작업을 닫습니다. 진행 중인 모든 로드 작업이 즉시 종료됩니다. 현재 스트리밍될 URL이 없으면 잘못된 스트림 오류가 발생합니다.

지정된 URL에서 데이터를 보내거나 로드합니다. 데이터는 dataFormat 속성에 지정한 값에 따라 텍스트, 원시 이진 데이터 또는 URL 인코딩된 변수로 수신할 수 있습니다. dataFormat 속성의 기본값은 텍스트입니다. 지정된 URL로 데이터를 보내려는 경우 URLRequest 객체의 data 속성을 지정할 수 있습니다.

참고: 로드되는 파일에 ASCII가 아닌 문자(영어가 아닌 다른 언어에서 사용)가 포함되어 있는 경우 UTF-8 또는 UTF-16과 같은 유니코드 인코딩을 사용하여 파일을 저장하는 것이 좋습니다. ASCII는 유니코드 형식이 아닙니다.

local-with-filesystem 샌드박스에 있는 SWF 파일은 network 샌드박스에 있는 리소스에서 데이터를 로드하거나 이러한 리소스에 데이터를 제공할 수 없습니다.

기본적으로 호출하는 SWF 파일과 로드하는 URL은 같은 도메인에 있어야 합니다. 예를 들어 www.adobe.com에 있는 SWF 파일은 같은 도메인인 www.adobe.com에 있는 소스에서만 데이터를 로드할 수 있습니다. 다른 도메인에서 데이터를 로드하려면 해당 데이터를 호스팅하는 서버에 URL 정책 파일을 배치합니다.

일반적으로 예약된 포트에 연결할 수 없습니다. 차단된 포트의 전체 목록은 ActionScript 3.0 개발자 안내서의 "제한적 네트워킹 API"를 참조하십시오.

Flash Player 10 이상에서는 multipart Content-Type(예: "multipart/form-data")을 사용하고 POST 본문 내 "content-disposition" 헤더에 "filename" 매개 변수를 지정하여 업로드를 처리하는 경우 POST 작업이 업로드에 적용되는 보안 규칙의 영향을 받을 수 있습니다.

• POST 작업은 마우스 클릭이나 키 누르기 같은 사용자 동작에 대한 응답으로 수행됩니다.
• POST 작업이 크로스 도메인인 경우, 즉 POST 대상이 POST 요청을 보내는 SWF 파일과 같은 서버에 없는 경우 대상 서버는 크로스 도메인 액세스를 허용하는 URL 정책 파일을 제공해야 합니다.

또한 multipart Content-Type의 경우 구문이 RFC2046 표준에 따라 유효해야 합니다. 구문이 유효하지 않은 경우 POST 작업은 업로드에 적용되는 보안 규칙의 영향을 받을 수 있습니다.

보안에 대한 자세한 내용은 Flash Player 개발자 센터 항목: 보안을 참조하십시오.

매개 변수

관련 API 요소

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.xml.*;
    import flash.events.IOErrorEvent;
  
    public class URLLoader_loadExample extends Sprite {
        private var xmlTextField:TextField = new TextField();
        private var externalXML:XML;    
        private var loader:URLLoader;

        public function URLLoader_loadExample() {
            var request:URLRequest = new URLRequest("xmlFile.xml");

            loader = new URLLoader();
            
            try {
                loader.load(request);
            }
            catch (error:SecurityError)
            {
                trace("A SecurityError has occurred.");
            }

             loader.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            loader.addEventListener(Event.COMPLETE, loaderCompleteHandler);

            xmlTextField.x = 10;
            xmlTextField.y = 10;
            xmlTextField.background = true;
            xmlTextField.autoSize = TextFieldAutoSize.LEFT;

            addChild(xmlTextField);
        }

        private function loaderCompleteHandler(event:Event):void {

                try {
                    externalXML = new XML(loader.data);
                    readNodes(externalXML);    
                } catch (e:TypeError) {
                    trace("Could not parse the XML file.");
                }
        }

        private function readNodes(node:XML):void {

                for each (var element:XML in node.elements()) {
                    xmlTextField.appendText(element.attributes()[0] + "\n");

                    readNodes(element);
                }    
        }

        private function errorHandler(e:IOErrorEvent):void {
            xmlTextField.text = "Had problem loading the XML File.";
        }
    }
}

수신된 모든 데이터가 디코딩된 후 URLLoader 객체의 data 속성에 배치되면 전달됩니다. 수신된 데이터는 이 이벤트가 전달되면 액세스할 수 있습니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

관련 API 요소

load() 메서드 호출로 HTTP를 통해 데이터 액세스를 시도하고 Adobe AIR에서 요청에 대한 상태 코드를 감지 및 반환할 수 있을 때 전달됩니다.

HTTPStatusEvent.HTTP_RESPONSE_STATUS 상수는 httpResponseStatus 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

관련 API 요소

URLLoader.load() 호출로 HTTP를 통해 데이터 액세스를 시도할 때 전달됩니다. Flash Player에서 실행 중인 내용의 경우 이 이벤트는 현재의 Flash Player 환경에서 요청에 대한 상태 코드를 감지 및 반환할 수 있을 때만 전달됩니다. 일부 브라우저 환경에서는 이 정보를 제공할 수 없습니다. httpStatus 이벤트는 complete 또는 error 이벤트 발생 전에 추가로 전송됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

관련 API 요소

URLLoader.load() 호출로 치명적인 오류가 발생하여 다운로드가 중단되면 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

관련 API 요소

URLLoader.load() 메서드 호출에 이어 다운로드 작업이 시작될 때 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

관련 API 요소

다운로드 작업이 진행되어 데이터가 수신될 때 전달됩니다.

데이터가 완전히 수신되기 전에는 URLLoader 객체로 데이터를 액세스할 수 없습니다. 따라서 progress 이벤트는 다운로드 진행 상황을 알리는 역할만을 합니다. 데이터가 완전히 다운로드되기 전에 액세스하려면 URLStream 객체를 사용합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

관련 API 요소

URLLoader.load() 호출로 보안 샌드박스 외부의 서버에서 데이터 로드를 시도하면 전달됩니다. 또한 URLLoader.load() 호출로 SWZ 파일 로드를 시도하지만 인증서가 유효하지 않거나 다이제스트 문자열이 구성 요소와 일치하지 않는 경우에도 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

관련 API 요소

참고: 이 예제를 실행하려면 urlLoaderExample.txt라는 이름의 파일을 SWF 파일과 같은 디렉토리에 넣어야 합니다. 이 파일에는 다음과 같은 내용의 텍스트만 포함되어 있어야 합니다. answer=42&question=unknown

이 예제 코드는 다음 작업을 수행합니다.

1. 생성자 함수는 loader라는 이름의 URLLoader 인스턴스와 request라는 이름의 URLRequest 인스턴스를 만들며, 이것은 로드할 파일의 위치와 이름을 포함합니다.
2. loader 객체는 configureListeners() 메서드에 전달되고, 이 메서드는 지원되는 각 URLLoader 이벤트에 대해 리스너를 추가합니다.
3. 그런 다음 request 객체가 loader.load()에 전달되고, 이 메서드는 해당 텍스트 파일을 로드합니다.
4. URLLoader가 텍스트 파일 로드를 완료하면 Event.COMPLETE 이벤트가 발생하여 completeHandler() 메서드가 트리거됩니다. completeHandler() 메서드는 파일에서 로드된 텍스트에서 URLVariables 객체를 만듭니다. URLVariables 객체는 URL 인코딩된 이름/값 쌍을 ActionScript 속성으로 변환하여 로드된 데이터를 조작하기 쉽게 만듭니다.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLLoaderExample extends Sprite {
        
        private loader:URLoader;
        public function URLLoaderExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("urlLoaderExample.txt");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
    
            var vars:URLVariables = new URLVariables(loader.data);
            trace("The answer is " + vars.answer);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}