FileReference  - AS3

La data di creazione del file sul disco locale. Se l'oggetto non è stato compilato, una chiamata per ottenere il valore di questa proprietà restituisce null.

Nota: nei casi in cui un sistema operativo non presenta creationDate come proprietà, CreationDate è uguale a lastModifiedDate.

Elementi API correlati

Il tipo di creatore Macintosh del file, che viene utilizzato solo nelle versioni di Mac OS precedenti a Mac OS X. In Windows o Linux, questa proprietà è null. Se l'oggetto FileReference non è stato compilato, una chiamata per ottenere il valore di questa proprietà restituisce null.

Altre informazioni

Elementi API correlati

L'oggetto ByteArray che rappresenta i dati provenienti dal file caricato dopo una chiamata riuscita al metodo load().

Altre informazioni

Elementi API correlati

L'estensione del nome file.

L'estensione di un file è la parte del nome che segue (senza includerlo) il punto finale ("."). Se il nome file non comprende un punto, l'estensione è null.

Nota: utilizzate la proprietà extension per determinare il tipo di un file; non utilizzate le proprietà creator o type. Le proprietà creator e type vanno considerate obsolete. Valgono per le versioni precedenti di Mac OS.

La data dell'ultima modifica apportata al file sul disco locale. Se l'oggetto FileReference non è stato compilato, una chiamata per ottenere il valore di questa proprietà restituisce null.

Elementi API correlati

Il nome del file sul disco locale. Se l'oggetto FileReference non è stato compilato (da una chiamata valida a FileReference.download() o FileReference.browse()), Flash Player genera un errore quando tentate di ottenere il valore di questa proprietà.

Tutte le proprietà di un oggetto FileReference vengono compilate chiamando il metodo browse(). A differenza di altre proprietà FileReference, se si chiama il metodo download(), la proprietà name viene compilata quando viene inviato l'evento select.

Elementi API correlati

Consente di determinare se l’applicazione ha ottenuto l’autorizzazione di accesso al file system.

Elementi API correlati

Le dimensioni del file sul disco locale, espresse in byte.

Nota: nella versione iniziale di ActionScript 3.0, la proprietà size era definita come oggetto uint, che supportava i file con dimensioni fino a circa 4 GB. Ora viene implementata come oggetto Number per supportare i file di dimensioni superiori.

Elementi API correlati

Il tipo di file.

In Windows o Linux, questa proprietà è l'estensione del file. In Macintosh, questa proprietà è il tipo di file a quattro caratteri che viene utilizzato solo nelle versioni di Mac OS precedenti a Mac OS X. Se l'oggetto FileReference non è stato compilato, una chiamata per ottenere il valore di questa proprietà restituisce null.

Per Windows, Linux e Mac OS X, l'estensione di file, cioè la porzione della proprietà name che segue l'ultima occorrenza del punto (.), identifica il tipo di file.

Elementi API correlati

Crea un nuovo oggetto FileReference. Quando è compilato, l'oggetto FileReference rappresenta un file nel disco locale dell'utente.

Elementi API correlati

Visualizza una finestra di dialogo per l'individuazione dei file che consente all'utente di selezionare un file da caricare. La finestra di dialogo è nativa del sistema operativo dell'utente. L'utente può selezionare un file sul computer locale o da altri sistemi, ad esempio mediante un percorso UNC in Windows.

Nota: la classe File, disponibile in Adobe AIR, include dei metodi per accedere a finestre di dialogo più specifiche per la selezione di file di sistema. Questi metodi sono File.browseForDirectory(), File.browseForOpen(), File.browseForOpenMultiple() e File.browseForSave().

Quando chiamate questo metodo e l'utente seleziona correttamente il file, le proprietà di questo oggetto FileReference vengono compilate con le proprietà di tale file. A ogni chiamata successiva del metodo FileReference.browse(), le proprietà dell'oggetto FileReference vengono ripristinate in base al file selezionato dall'utente nella finestra di dialogo. È possibile eseguire una sola sessione browse() o download() alla volta (poiché è possibile richiamare una sola finestra di dialogo per volta).

Il parametro typeFilter consente di determinare quali file vengono visualizzati nella finestra di dialogo.

In Flash Player 10 e in Flash Player 9 Aggiornamento 5, potete chiamare questo metodo solo in seguito a un evento utente (ad esempio, in un gestore di eventi per un clic del mouse o la pressione di un tasto). Altrimenti, quando chiamate questo metodo viene generata un'eccezione Error.

A causa delle nuove funzioni aggiunte a Flash Player, quando si pubblica su Flash Player 10, solo una alla volta delle seguenti operazioni può essere attiva: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Altrimenti, Flash Player genera un errore di runtime (codice 2174). Utilizzate FileReference.cancel() per interrompere un'operazione in corso. Questa limitazione è valida solo per Flash Player 10. Le versioni precedenti di Flash Player non risentono di questa limitazione su operazioni multiple simultanee.

In Adobe AIR, la finestra di dialogo per la ricerca di file non viene sempre visualizzata in primo piano rispetto alle finestre appartenenti a un'altra finestra (le finestre con una proprietà owner non null). Per evitare problemi di ordinamento delle finestre, nascondere quelle appartenenti a un'altra finestra prima di chiamare questo metodo.

Parametri

Altre informazioni

Elementi API correlati

Annulla l'operazione di caricamento o scaricamento in corso su questo oggetto FileReference. La chiamata a questo metodo non invia l'evento cancel; l'evento viene inviato solo quando l'utente annulla l'operazione annullando la finestra di dialogo di caricamento o scaricamento dei file.

Apre una finestra di dialogo che consente all'utente di scaricare un file da un server remoto. Benché Flash Player non preveda limitazioni alle dimensioni dei file che è possibile caricare o scaricare, ufficialmente il lettore supporta caricamenti e scaricamenti con una dimensione massima di 100 MB.

Il metodo download() apre una finestra di dialogo del sistema operativo che richiede all'utente di immettere un nome di file e selezionare un percorso sul disco locale in cui salvare il file. Quando l'utente seleziona un percorso e conferma l'operazione di scaricamento (ad esempio, facendo clic su Salva), ha inizio lo scaricamento dal server remoto. I listener ricevono gli eventi che indicano l'avanzamento, il completamento o l'interruzione dello scaricamento. Per determinare lo stato della finestra di dialogo e l'operazione di scaricamento dopo la chiamata a download(), il codice utilizzato deve ricevere eventi come cancel, open, progress e complete.

Le funzioni FileReference.upload() e FileReference.download() non sono bloccanti. Queste funzioni restituiscono un valore dopo che vengono chiamate, prima che venga completata la trasmissione del file. Inoltre, se l'oggetto FileReference esce dall'area di validità, qualunque caricamento o scaricamento che non è ancora stato completato per l'oggetto viene annullato quando l'area di validità viene abbandonata. Assicuratevi che l'oggetto FileReference rimanga all'interno dell'area di validità per la durata prevista dell'operazione di caricamento o scaricamento.

Una volta scaricato correttamente il file, le proprietà dell'oggetto FileReference vengono compilate con le proprietà del file locale. L'evento complete viene inviato se lo scaricamento è stato completato correttamente.

È possibile eseguire una sola sessione browse() o download() alla volta (poiché è possibile richiamare una sola finestra di dialogo per volta).

Questo metodo supporta lo scaricamento di qualunque tipo di file, mediante il protocollo HTTP o HTTPS.

Non potete collegarvi alle porte comunemente riservate. Per un elenco completo di porte bloccate, vedete "Limitazioni delle API di connettività di rete" nella Guida per gli sviluppatori di ActionScript 3.0.

Nota: sui server che richiedono l'autenticazione dell'utente, solo i file SWF in esecuzione in un browser (ovvero quelli che utilizzano il plug-in per il browser o il controllo ActiveX) possono fornire una finestra di dialogo per richiedere all'utente di immettere un nome utente e una password per l'autenticazione, e solo per gli scaricamenti. Per i caricamenti mediante il plug-in o il controllo ActiveX o per i caricamenti e gli scaricamenti mediante il lettore autonomo o esterno, il trasferimento dei file non riesce.

Quando utilizzate questo metodo, considerate il modello di sicurezza di Flash Player:

• Le operazioni di caricamento non sono consentite se il file SWF che effettua la chiamata si trova in una sandbox locale non attendibile.
• Per impostazione predefinita, viene negato l'accesso delle sandbox ad altre sandbox. L'accesso a una risorsa su un sito Web è consentito mediante l'aggiunta di un file dei criteri per gli URL.
• Potete impedire che un file SWF utilizzi questo metodo impostando il parametro allowNetworking dei tag object ed embed nella pagina HTML che include il contenuto SWF.
• In Flash Player 10 e in Flash Player 9 Aggiornamento 5, potete chiamare questo metodo solo in seguito a un evento utente (ad esempio, in un gestore di eventi per un clic del mouse o la pressione di un tasto). Altrimenti, quando chiamate questo metodo viene generata un'eccezione Error.

Tuttavia, in Adobe AIR, il contenuto della funzione di sicurezza sandbox dell'applicazione (contenuto installato con l'applicazione AIR) non è interessato da queste limitazioni di sicurezza.

Per ulteriori informazioni sulla sicurezza, vedete l'argomento sulla sicurezza nel Centro per sviluppatori di Flash Player .

Quando scaricate un file tramite questo metodo, viene contrassegnato come scaricato nei sistemi operativi che applicano flag ai file scaricati:

• Windows XP Service Pack 2 e versioni successive e Windows Vista
• Mac OS 10.5 e versioni successive

In alcuni sistemi operativi, come Linux, i file scaricati non vengono contrassegnati.

A causa delle nuove funzioni aggiunte a Flash Player, quando si pubblica su Flash Player 10, solo una alla volta delle seguenti operazioni può essere attiva: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Altrimenti, Flash Player genera un errore di runtime (codice 2174). Utilizzate FileReference.cancel() per interrompere un'operazione in corso. Questa limitazione è valida solo per Flash Player 10. Le versioni precedenti di Flash Player non risentono di questa limitazione su operazioni multiple simultanee.

In Adobe AIR, la finestra di dialogo di scaricamento non viene sempre visualizzata in primo piano rispetto alle finestre appartenenti a un'altra finestra (le finestre con una proprietà owner non null). Per evitare problemi di ordinamento delle finestre, nascondere quelle appartenenti a un'altra finestra prima di chiamare questo metodo.

Parametri

Altre informazioni

Elementi API correlati

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Avvia il caricamento di un file locale selezionato da un utente. Benché Flash Player non preveda limitazioni alle dimensioni dei file che potete caricare, scaricare o salvare, ufficialmente supporta al massimo dimensioni di 100 MB. Per i contenuti in esecuzione in Flash Player, dovete chiamare il metodo FileReference.browse() o FileReferenceList.browse() prima di chiamare il metodo load(). Tuttavia, i contenuti in esecuzione in AIR nella funzione di sicurezza sandbox dell'applicazione possono chiamare il metodo load() di un oggetto File senza prima chiamare il metodo browse(). (La classe File AIR estende la classe FileReference).

I listener ricevono gli eventi che indicano l'avanzamento, il completamento o l'interruzione del caricamento. Benché possiate utilizzare l'oggetto FileReferenceList per consentire agli utenti di selezionare più file da caricare, dovete caricare i file uno per uno. Per caricare i file uno per uno, eseguite iterazioni nell'array FileReferenceList.fileList di oggetti FileReference.

In Adobe AIR è inoltre inclusa la classe FileStream che offre un maggior numero di opzioni per la lettura dei file.

Le funzioni FileReference.upload(), FileReference.download(), FileReference.load() e FileReference.save() non sono bloccanti. Queste funzioni restituiscono un valore dopo che vengono chiamate, prima che venga completata la trasmissione del file. Inoltre, se l'oggetto FileReference esce dall'area di validità, qualunque transazione che non è ancora stata completata per l'oggetto viene annullata quando l'area di validità viene abbandonata. Assicuratevi che l'oggetto FileReference rimanga all'interno dell'area di validità per la durata prevista dell'operazione di caricamento, scaricamento o salvataggio.

Se il caricamento del file viene ultimato correttamente, i relativi contenuti vengono memorizzati sotto forma di array di byte nella proprietà data dell'oggetto FileReference.

Valgono le seguenti considerazioni sulla sicurezza:

• Le operazioni di caricamento non sono consentite se il file SWF che effettua la chiamata si trova in una sandbox locale non attendibile.
• Per impostazione predefinita, viene negato l'accesso delle sandbox ad altre sandbox. L'accesso a una risorsa su un sito Web è consentito mediante l'aggiunta di un file dei criteri per i domini.
• È possibile impedire che un file utilizzi questo metodo impostando il parametro allowNetworking dei tag object ed embed nella pagina HTML che include il contenuto SWF.

Tuttavia, queste limitazioni di sicurezza non valgono per il contenuto AIR presente nella funzione di sicurezza sandbox.

Quando pubblicate in Flash Player 10 o AIR 1.5, può essere attiva solo una delle seguenti operazioni alla volta: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). In caso contrario, l'applicazione genera un errore di runtime (codice 2174). Utilizzate FileReference.cancel() per interrompere un'operazione in corso. Questa limitazione vale solo per Flash Player 10 e AIR 1.5. Le versioni precedenti di Flash Player o AIR non sono interessate da questa limitazione delle operazioni multiple simultanee.

In Adobe AIR, la finestra di dialogo per la ricerca di file non viene sempre visualizzata in primo piano rispetto alle finestre appartenenti a un'altra finestra (le finestre con una proprietà owner non null). Per evitare problemi di ordinamento delle finestre, nascondere quelle appartenenti a un'altra finestra prima di chiamare questo metodo.

Altre informazioni

Elementi API correlati

var buttonShape:Shape = new Shape();
buttonShape.graphics.beginFill(0x336699);
buttonShape.graphics.drawCircle(50, 50, 25);
var button = new SimpleButton(buttonShape, buttonShape, buttonShape, buttonShape);
addChild(button);

var fileRef:FileReference= new FileReference();
button.addEventListener(MouseEvent.CLICK, onButtonClick);

function onButtonClick(e:MouseEvent):void {
fileRef.browse([new FileFilter("Images", "*.jpg;*.gif;*.png")]);
fileRef.addEventListener(Event.SELECT, onFileSelected);
}

function onFileSelected(e:Event):void {
fileRef.addEventListener(Event.COMPLETE, onFileLoaded);
fileRef.load();
}

function onFileLoaded(e:Event):void {
var loader:Loader = new Loader();
loader.loadBytes(e.target.data);
addChild(loader);
}

Richiede l’autorizzazione di accesso al file system.

Apre una finestra di dialogo che consente all'utente di salvare un file nel file system locale. Benché in Flash Player non siano previste limitazioni alle dimensioni dei file che è possibile caricare, scaricare o salvare, ufficialmente il lettore supporta dimensioni massime di 100 MB.

Il metodo save() apre una finestra di dialogo del sistema operativo che richiede all'utente di immettere un nome di file e selezionare un percorso sul disco locale in cui salvare il file. Quando l'utente seleziona un percorso e conferma l'operazione di salvataggio (ad esempio, facendo clic su Salva), ha inizio il processo di salvataggio. I listener ricevono gli eventi che indicano l'avanzamento, il completamento o l'interruzione dell'operazione di salvataggio. Per determinare lo stato della finestra di dialogo e l'operazione di salvataggio dopo la chiamata a save(), il codice utilizzato deve ricevere eventi come cancel, open, progress e complete.

In Adobe AIR è inoltre inclusa la classe FileStream che offre un maggior numero di opzioni per il salvataggio locale dei file.

Le funzioni FileReference.upload(), FileReference.download(), FileReference.load() e FileReference.save() non sono bloccanti. Queste funzioni restituiscono un valore dopo che vengono chiamate, prima che venga completata la trasmissione del file. Inoltre, se l'oggetto FileReference esce dall'area di validità, qualunque transazione che non è ancora stata completata per l'oggetto viene annullata quando l'area di validità viene abbandonata. Assicuratevi che l'oggetto FileReference rimanga all'interno dell'area di validità per la durata prevista dell'operazione di caricamento, scaricamento o salvataggio.

Una volta salvato correttamente il file, le proprietà dell'oggetto FileReference vengono compilate con le proprietà del file locale. L'evento complete viene inviato se il salvataggio è stato completato correttamente.

È possibile eseguire una sola sessione browse() o save() alla volta (poiché è possibile richiamare una sola finestra di dialogo per volta).

In Flash Player, potete chiamare questo metodo solo in seguito a un evento utente (ad esempio, in un gestore di eventi per un clic del mouse o la pressione di un tasto). Altrimenti, chiamando il metodo si genera un'eccezione Error. Questa limitazione non vale per il contenuto AIR nella funzione di sicurezza sandbox dell'applicazione.

In Adobe AIR, la finestra di dialogo di salvataggio non viene sempre visualizzata in primo piano rispetto alle finestre appartenenti a un'altra finestra (le finestre con una proprietà owner non null). Per evitare problemi di ordinamento delle finestre, nascondere quelle appartenenti a un'altra finestra prima di chiamare questo metodo.

Parametri

Altre informazioni

Elementi API correlati

var MyTextField:TextField = new TextField();
var MyButtonField:TextField = new TextField();
var MyFile:FileReference = new FileReference();

MyTextField.border = true;
MyTextField.type = TextFieldType.INPUT;

MyButtonField.background = true;
MyButtonField.backgroundColor = 0x339933;
MyButtonField.x = 150;
MyButtonField.height = 20;
MyButtonField.text = "Click here to save";

addChild(MyTextField);
addChild(MyButtonField);
MyButtonField.addEventListener(MouseEvent.CLICK, clickhandler);

function clickhandler(e:MouseEvent): void {
    MyFile.save(MyTextField.text);
}

Avvia il caricamento del file su un server remoto. Benché Flash Player non preveda limitazioni alle dimensioni dei file che è possibile caricare o scaricare, ufficialmente il lettore supporta caricamenti e scaricamenti con una dimensione massima di 100 MB. È necessario chiamare il metodo FileReference.browse() o FileReferenceList.browse() prima di chiamare questo metodo.

Per la classe File di Adobe AIR, che estende la classe FileReference, potete utilizzare il metodo upload() per caricare qualsiasi file. Per la classe FileReference (utilizzata in Flash Player), l'utente deve prima selezionare un file.

I listener ricevono gli eventi che indicano l'avanzamento, il completamento o l'interruzione dello scaricamento. Anche se è possibile utilizzare l'oggetto FileReferenceList per consentire agli utenti di selezionare più file per il caricamento, è necessario caricarli uno alla volta; a tale scopo, eseguire un'iterazione sull'array FileReferenceList.fileList di oggetti FileReference.

Le funzioni FileReference.upload() e FileReference.download() non sono bloccanti. Queste funzioni restituiscono un valore dopo che vengono chiamate, prima che venga completata la trasmissione del file. Inoltre, se l'oggetto FileReference esce dall'area di validità, qualunque caricamento o scaricamento che non è ancora stato completato per l'oggetto viene annullato quando l'area di validità viene abbandonata. Assicuratevi che l'oggetto FileReference rimanga all'interno dell'area di validità per la durata prevista dell'operazione di caricamento o scaricamento.

Il file viene caricato nell'URL passato nel parametro url. L'URL deve essere uno script server configurato per accettare i caricamenti. Flash Player carica i file utilizzando il metodo POST HTTP. Lo script server che gestisce il caricamento deve prevedere una richiesta POST con gli elementi seguenti:

• Content-Type di multipart/form-data
• Content-Disposition con un attributo name impostato su "Filedata" per impostazione predefinita e un attributo filename impostato sul nome del file originale
• Il contenuto binario del file

Non potete collegarvi alle porte comunemente riservate. Per un elenco completo di porte bloccate, vedete "Limitazioni delle API di connettività di rete" nella Guida per gli sviluppatori di ActionScript 3.0.

Per un esempio di richieste POST, vedete la descrizione del parametro uploadDataFieldName. È possibile inviare parametri POST o GET al server con il metodo upload(); vedete la descrizione del parametro request.

Se il parametro testUpload è true e il file da caricare ha una dimensione superiore a circa 10 KB, Flash Player su Windows invia un'operazione POST di caricamento di prova priva di contenuto prima di caricare il file vero e proprio per verificare la probabilità di riuscita della trasmissione. Quindi, Flash Player invia una seconda operazione POST che contiene il contenuto effettivo del file. Per i file con dimensioni inferiori a 10 KB, Flash Player esegue una sola operazione POST di caricamento con il contenuto effettivo da caricare. Flash Player su Macintosh non esegue operazioni POST di caricamento di prova.

Nota: sui server che richiedono l'autenticazione dell'utente, solo i file SWF in esecuzione in un browser (ovvero quelli che utilizzano il plug-in per il browser o il controllo ActiveX) possono fornire una finestra di dialogo per richiedere all'utente di immettere un nome utente e una password per l'autenticazione, e solo per gli scaricamenti. Per i caricamenti mediante il plug-in o il controllo ActiveX o per i caricamenti e gli scaricamenti mediante il lettore autonomo o esterno, il trasferimento dei file non riesce.

Quando utilizzate questo metodo, considerate il modello di sicurezza di Flash Player:

• Le operazioni di caricamento non sono consentite se il file SWF che effettua la chiamata si trova in una sandbox locale non attendibile.
• Per impostazione predefinita, viene negato l'accesso delle sandbox ad altre sandbox. L'accesso a una risorsa su un sito Web è consentito mediante l'aggiunta di un file dei criteri per gli URL.
• Potete impedire che un file SWF utilizzi questo metodo impostando il parametro allowNetworking dei tag object ed embed nella pagina HTML che include il contenuto SWF.

Tuttavia, in Adobe AIR, il contenuto della funzione di sicurezza sandbox dell'applicazione (contenuto installato con l'applicazione AIR) non è interessato da queste limitazioni di sicurezza.

Per ulteriori informazioni sulla sicurezza, vedete l'argomento sulla sicurezza nel Centro per sviluppatori di Flash Player .

A causa delle nuove funzioni aggiunte a Flash Player, quando si pubblica su Flash Player 10, solo una alla volta delle seguenti operazioni può essere attiva: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Altrimenti, Flash Player genera un errore di runtime (codice 2174). Utilizzate FileReference.cancel() per interrompere un'operazione in corso. Questa limitazione è valida solo per Flash Player 10. Le versioni precedenti di Flash Player non risentono di questa limitazione su operazioni multiple simultanee.

Parametri

    Content-Type: multipart/form-data; boundary=AaB03x
    --AaB03x 
    Content-Disposition: form-data; name="Filedata"; filename="example.jpg" 
    Content-Type: application/octet-stream
    ... contents of example.jpg ... 
    --AaB03x-- 
    

Altre informazioni

Elementi API correlati

Avviate il caricamento di un file in un URL senza alcuna codifica. Mentre il metodo upload() codifica il file in un involucro form-data, il metodo uploadUnencoded() passa il contenuto del file così com'è nel corpo della richiesta HTTP. Utilizzate il metodo uploadUnencoded() se i dati da inviare sono già codificati in un formato che il server di ricezione è in grado di interpretare. Di solito, si utilizza il metodo uploadeUnencoded() con il metodo HTTP/WebDAV PUT.

Parametri

Elementi API correlati

Inviato quando un caricamento o uno scaricamento file viene annullato dall'utente mediante la finestra di dialogo di selezione file. Flash Player non invia questo evento se l'utente annulla un caricamento o uno scaricamento in altro modo (chiudendo il browser o interrompendo l'applicazione corrente).

Questo evento ha le seguenti proprietà:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_cancel extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_cancel() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(Event.CANCEL, cancelHandler);
            file.download(downloadURL, fileName);
        }
        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }
    }
}

Inviato quando lo scaricamento è completato o quando il caricamento genera il codice di stato HTTP 200. Per lo scaricamento dei file, questo evento viene inviato quando Flash Player o Adobe AIR termina lo scaricamento sul disco dell'intero file. Per il caricamento dei file, questo evento viene inviato dopo che Flash Player o Adobe AIR ha ricevuto il codice di stato HTTP 200 dal server che riceve la trasmissione.

Questo evento ha le seguenti proprietà:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_complete extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_complete() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Elementi API correlati

Inviato se una chiamata al metodo upload() o uploadUnencoded() tenta di accedere ai dati via HTTP e Adobe AIR è in grado di rilevare e restituire il codice di stato della richiesta.

La costante HTTPStatusEvent.HTTP_RESPONSE_STATUS definisce il valore della proprietà type di un oggetto evento httpResponseStatus.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Inviato quando un caricamento non riesce ed è disponibile un codice di stato HTTP che descrive l'errore. Viene inviato l'evento httpStatus, seguito da un evento ioError.

L'evento httpStatus viene inviato solo per i mancati caricamenti. Per il contenuto in esecuzione in Flash Player, questo evento non è applicabile nel caso degli errori di scaricamento. Se uno scaricamento non riesce a causa di un errore HTTP, l'errore viene segnalato come errore di I/O.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Inviato quando il caricamento o lo scaricamento non riesce. Un trasferimento di file può dare esito negativo per uno dei motivi seguenti:

• Si verifica un errore di input/output durante la lettura, la scrittura o la trasmissione del file da parte del lettore.
• Il file SWF tenta di caricare un file in un server che richiede l'autenticazione (ad esempio nome utente e password). Durante il caricamento, Flash Player o Adobe AIR non fornisce all'utente un modo per immettere una password. Se un file SWF tenta di caricare un file in un server che richiede l'autenticazione, il caricamento non riesce.
• Il file SWF tenta di scaricare un file da un server che richiede l'autenticazione, all'interno del lettore autonomo o esterno. Durante lo scaricamento, i lettori autonomi ed esterni non forniscono all'utente un modo per immettere le password. Se un file SWF in questi lettori tenta di scaricare un file da un server che richiede l'autenticazione, lo scaricamento non riesce. Lo scaricamento dei file riesce solo nel controllo ActiveX, nei lettori plug-in per il browser e nel runtime di Adobe AIR.
• Il valore passato al parametro url nel metodo upload() contiene un protocollo non valido. I protocolli validi sono HTTP e HTTPS.

Importante: solo le applicazioni in esecuzione in un browser (ovvero quelle che usano il plug-in per il browser o il controllo ActiveX) e il contenuto in esecuzione in Adobe AIR possono fornire una finestra di dialogo per richiedere all'utente di immettere un nome utente e una password per l'autenticazione, e solo per gli scaricamenti. Per i caricamenti mediante il plug-in o la versione del controllo ActiveX di Flash Player o per i caricamenti e gli scaricamenti mediante il lettore autonomo o esterno, il trasferimento dei file non è possibile.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Inviato quando viene avviata l'operazione di caricamento o scaricamento.

Questo evento ha le seguenti proprietà:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Elementi API correlati

Inviato quando l’applicazione richiede l’autorizzazione di accesso al file system. Controllando il valore della proprietà status, è possibile verificare se l’autorizzazione è stata concessa o negata.

Elementi API correlati

Inviato periodicamente durante l'operazione di caricamento o scaricamento del file. L'evento progress viene inviato mentre Flash Player trasmette dei byte a un server e viene inviato periodicamente durante la trasmissione, anche se quest'ultima alla fine non riesce. Per determinare se e quando la trasmissione del file viene effettuata e completata correttamente, intercettate l'evento complete.

In determinati casi, gli eventi progress non vengono ricevuti. Ad esempio, quando un file trasmesso ha dimensioni molto ridotte o il processo di caricamento o scaricamento si verifica molto rapidamente, è possibile che un evento progress non venga inviato.

L'avanzamento del caricamento di un file non può essere determinato sulle piattaforme Macintosh precedenti a OS X 10.3. L'evento progress viene chiamato durante l'operazione di caricamento, ma il valore della proprietà bytesLoaded dell'evento progress è -1, che indica che l'avanzamento non può essere determinato.

Questo evento ha le seguenti proprietà:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_progress extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_progress() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.download(downloadURL, fileName);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
        
        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Elementi API correlati

Inviato quando una chiamata al metodo FileReference.upload() o FileReference.download() tenta di caricare un file su un server o di ottenere un file da un server che si trova al di fuori della funzione di sicurezza sandbox del chiamante. Il valore della proprietà text che descrive lo specifico errore che si è verificato è solitamente "securitySandboxError". È possibile che il file SWF chiamante abbia tentato di accedere a un file SWF fuori del proprio dominio e che non disponga delle autorizzazioni per tale accesso. Potete tentare di risolvere questo errore utilizzando un file dei criteri degli URL.

In Adobe AIR, queste limitazioni di sicurezza non valgono per il contenuto presente nella funzione di sicurezza sandbox.

In Adobe AIR, queste limitazioni di sicurezza non valgono per il contenuto presente nella funzione di sicurezza sandbox.

Questo evento ha le seguenti proprietà:

Elementi API correlati

Inviato quando l'utente seleziona un file da caricare o scaricare dalla finestra di dialogo per l'individuazione dei file. (Questa finestra di dialogo viene visualizzata quando si chiama il metodo FileReference.browse(), FileReferenceList.browse() o FileReference.download().) Quando l'utente seleziona un file e conferma l'operazione (ad esempio, facendo clic su OK), le proprietà dell'oggetto FileReference vengono compilate.

Per il contenuto in esecuzione in Flash Player o al di fuori della funzione di sicurezza sandbox dell'applicazione nel runtime di Adobe AIR , l'evento select si comporta in modo leggermente diverso a seconda dell'evento che lo richiama. Quando l'evento select viene inviato dopo una chiamata a browse(), Flash Player o l'applicazione AIR è in grado di leggere tutte le proprietà dell'oggetto FileReference, poiché il file selezionato dall'utente si trova nel file system locale. Quando l'evento select si verifica dopo una chiamata a download(), Flash Player o l'applicazione AIR è in grado di leggere solo la proprietà name, poiché al momento dell'invio dell'evento select il file non è stato ancora scaricato nel file system locale. Dopo che il file è stato scaricato e l'evento complete inviato, Flash Player o l'applicazione AIR può leggere tutte le altre proprietà dell'oggetto FileReference.

Questo evento ha le seguenti proprietà:

 
package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_select extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReference_event_select() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            file.addEventListener(Event.SELECT, selectHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.browse();
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Inviato dopo la ricezione di dati dal server a seguito di un caricamento riuscito. Questo evento non viene inviato se i dati non vengono restituiti dal server.

Questo evento ha le seguenti proprietà:

Nota: per provare questo esempio, modificate la proprietà uploadURL.url in modo che punti a un URL reale, anziché a quello fittizio specificato nell'esempio. L'URL deve puntare a un file di nome yourUploadHandlerScript.cfm nella directory Web principale dell'URL specificato. A seconda della vostra configurazione, è possibile che sia anche necessario compilare il file SWF con l'opzione Sicurezza riproduzione locale impostata su Accedi solo alla rete o aggiornare le impostazioni di sicurezza di Flash Player per consentire al file l'accesso alla rete.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileFilter;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReferenceExample extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReferenceExample() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            configureListeners(file);
            file.browse(getTypes());
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
            dispatcher.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA,uploadCompleteDataHandler);
        }

        private function getTypes():Array {
            var allTypes:Array = new Array(getImageTypeFilter(), getTextTypeFilter());
            return allTypes;
        }

        private function getImageTypeFilter():FileFilter {
            return new FileFilter("Images (*.jpg, *.jpeg, *.gif, *.png)", "*.jpg;*.jpeg;*.gif;*.png");
        }

        private function getTextTypeFilter():FileFilter {
            return new FileFilter("Text Files (*.txt, *.rtf)", "*.txt;*.rtf");
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function uploadCompleteDataHandler(event:DataEvent):void {
            trace("uploadCompleteData: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }
    }
}