File  - AS3

La cartella contenente i file installati dell'applicazione.

La proprietà url di questo oggetto utilizza lo schema URL app (non lo schema URL file). Ciò significa che la stringa url viene specificata a partire da "app:" (non da "file:"). Inoltre, se create un oggetto File relativo alla directory File.applicationDirectory (utilizzando il metodo resolvePath()), anche la proprietà url dell'oggetto File utilizzerà lo schema URL app.

Nota: non è possibile scrivere su file o directory con percorsi che utilizzano lo schema URL app:. Non potete inoltre eliminare o creare file o cartelle con percorsi che utilizzano lo schema URL app:. È sconsigliato modificare contenuto nella directory dell'applicazione, per motivi di sicurezza, e tale operazione viene bloccata dal sistema operativo in alcune piattaforme. Se desiderate memorizzare dati specifici dell'applicazione, potete utilizzare la directory di archiviazione dell'applicazione (File.applicationStorageDirectory). Se desiderate che il contenuto nella directory di archiviazione dell'applicazione possa accedere alla funzionalità privilegiata dell'applicazione (API di AIR), potete esporre tale funzionalità mediante un bridge sandbox.

La proprietà applicationDirectory offre un modo che funziona in tutte le piattaforme per fare riferimento alla directory dell'applicazione. Se utilizzate la proprietà nativePath o url per impostare un oggetto File in modo che faccia riferimento alla directory dell'applicazione, la proprietà funzionerà solo sulla piattaforma nella quale quel percorso è valido.

In Android, la proprietà nativePath di un oggetto File che punta alla directory dell'applicazione è una stringa vuota. Utilizzate la proprietà url per accedere ai file dell'applicazione.

Altri esempi

Altre informazioni

Elementi API correlati

La directory di archiviazione privata dell'applicazione.

Ogni applicazione AIR presenta una directory di archiviazione univoca e persistente che viene creata al primo accesso a File.applicationStorageDirectory. Tale directory è unica per ogni applicazione e per ogni utente. Questa directory rappresenta una posizione comoda dove memorizzare dati specifici dell'utente o dell'applicazione.

Quando disinstallate un'applicazione AIR, è la piattaforma che determina se il programma di disinstallazione elimina la cartella di archiviazione dell'applicazione e i relativi file.

La proprietà url di questo oggetto utilizza lo schema URL app-storage (non lo schema URL file). Ciò significa che la stringa url viene specificata a partire da "app-storage:" (non da "file:"). Inoltre, se create un oggetto File relativo alla directory File.applicationStoreDirectory (utilizzando il metodo resolvePath()), anche l'url dell'oggetto File utilizzerà lo schema URL app-storage (come nell'esempio).

La proprietà applicationStorageDirectory offre un modo che funziona in tutte le piattaforme per fare riferimento alla directory di archiviazione dell'applicazione. Se utilizzate la proprietà nativePath o url per impostare un oggetto File in modo che faccia riferimento alla directory di archiviazione dell'applicazione, la proprietà funzionerà solo sulla piattaforma nella quale quel percorso è valido.

Nota (solo per Mac OS): per rispettare i requisiti di Mac App Store, la posizione fisica di questa directory è stata cambiata da AIR 3.2 a AIR 3.3:

• Spazio dei nomi 3.2 e versioni precedenti: ~/Library/Preferences/appid/Local Store/
• Spazio dei nomi 3.3 e versioni successive: path/Library/Application Support/appid/Local Store/, dove path è ~/Library/Containers/bundle-id/Data (ambiente con sandbox) o ~ (al di fuori di un ambiente con sandbox)

Altri esempi

Altre informazioni

import flash.filesystem.File;

var tempFiles:File = File.applicationStorageDirectory;
tempFiles = tempFiles.resolvePath("images/");
trace(tempFiles.url); // app-storage:/images

La directory della cache dell’applicazione.

La proprietà cacheDirectory fornisce un metodo per il riferimento della directory della cache. L’applicazione dovrebbe utilizzare la directory della cache per archiviare i file che sono stati scaricati da un server o che possono essere rigenerati. Gli esempi di file che possono essere archiviati nella directory della cache includono i file della cache del database e i contenuti scaricabili, come quelli utilizzati dalle applicazioni per l’apertura di giornali, quotidiani e mappe.

Se configurate un oggetto File in modo che faccia riferimento alla directory della cache utilizzando la proprietà nativePath o url, esso funzionerà soltanto su piattaforme per le quali tale percorso è valido.

Se un sistema operativo non supporta una directory della cache, cacheDirectory è null

Altre informazioni

La directory del desktop dell'utente.

La proprietà desktopDirectory offre un metodo che funziona in più piattaforme per fare riferimento alla directory del desktop. Se utilizzate la proprietà nativePath o url per impostare un oggetto File in modo che faccia riferimento alla directory desktop, la proprietà funzionerà solo sulla piattaforma nella quale quel percorso è valido.

Se un sistema operativo non supporta una directory desktop, viene utilizzata in alternativa una directory idonea del file system.

I dispositivi AIR per TV non prevedono il concetto di directory desktop dell'utente. Di conseguenza, la proprietà desktopDirectory fa riferimento alla stessa posizione di directory della proprietà File.userDirectory. La directory utente è esclusiva dell'applicazione.

Altri esempi

Altre informazioni

import flash.filesystem.File;
var desktop:File = File.desktopDirectory;

var files:Array = desktop.getDirectoryListing();

for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

La directory Documenti dell'utente.

In Windows, si tratta della directory Documenti (ad esempio, C:\Documents and Settings\nomeUtente\Documenti). In Mac OS, la posizione predefinita è /Users/nomeUtente/Documents. In Linux, la posizione predefinita è /home/nomeUtente/Documents (su un sistema in inglese) e la proprietà segue l'impostazione xdg-user-dirs.

La proprietà documentsDirectory offre un modo che funziona in tutte le piattaforme per fare riferimento alla directory Documenti. Se utilizzate la proprietà nativePath o url per impostare un oggetto File in modo che faccia riferimento alla directory Documenti, la proprietà funzionerà solo sulla piattaforma nella quale quel percorso è valido.

Se un sistema operativo non supporta una directory Documenti, viene utilizzata in alternativa una directory idonea del file system.

I dispositivi AIR per TV non prevedono il concetto di directory Documenti dell'utente. Di conseguenza, la proprietà documentsDirectory fa riferimento alla stessa posizione di directory della proprietà File.userDirectory. La directory utente è esclusiva dell'applicazione.

Altri esempi

Altre informazioni

import flash.filesystem.File;

var directory:File = File.documentsDirectory;
directory = directory.resolvePath("AIR Test");

File.createDirectory(directory);
trace(directory.exists); // true

Indica se il file o la directory di riferimento è stata scaricata o meno (da Internet).

Questa proprietà è significativa solo sui sistemi operativi in cui i file possono essere contrassegnati come scaricati:

• Windows XP Service Pack 2 e versioni successive e Windows Vista
• Mac OS 10.5 e versioni successive

Nei sistemi che non consentono di contrassegnare i file come scaricati, ad esempio Linux, la proprietà non è significativa (e viene impostata su false).

Elementi API correlati

Indica se il file o la directory di riferimento esiste. Il valore è true, se l'oggetto File punta a un file o a una directory esistente; in caso contrario è false.

import flash.filesystem.*;

var temp:File = File.createTempFile();
trace(temp.exists); // true
temp.deleteFile();
trace(temp.exists); // false

Un oggetto Icon contenente le icone definite per il file. Un oggetto Icon è un array di oggetti BitmapData corrispondenti ai vari stati dell'icona. In Linux, l'oggetto Icon non contiene alcuna icona. In Android, la proprietà icon è null.

import flash.filesystem.File;
import flash.display.*;

var directory:File = File.documentsDirectory;
var bitmaps:Array = directory.icon.bitmaps;
var bmpData:BitmapData = new BitmapData(1, 1);
for (var i:uint = 0; i < bitmaps.length; i++) {
    if (bitmaps[i].height > bmpData.height) {
        bmpData = directory.icon.bitmaps[i];
    }
}
var iconBmp:Bitmap = new Bitmap(bmpData);

Indica se il riferimento è a una directory. Il valore è true, se l'oggetto File punta a un file o a una directory, mentre in caso contrario è false.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isDirectory) {
        trace(userDirFiles[i].nativePath);
    }
}    

Indica se il file o la directory di riferimento è nascosta. In caso affermativo, il valore è true; in caso contrario è false.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isHidden) {
        trace(userDirFiles[i].nativePath);
    }
}    

Indica se la directory di riferimento è un pacchetto.

In caso affermativo, il valore è true; in caso contrario è false. Tenete presente che la classe File non consente di creare pacchetti direttamente.

• In Mac OS, le directory possono essere designate come pacchetti e vengono rilevate dalla funzione Finder come singoli file anziché come directory. Questa proprietà è impostata su true se la directory a cui si fa riferimento è un pacchetto e su false se il file non è una directory, non esiste o non è un pacchetto.
• Negli altri sistemi operativi, questa proprietà è sempre impostata su false.

Altri esempi

Indica se il riferimento è a un collegamento simbolico.

Il valore è true, se l'oggetto File è un collegamento simbolico; in caso contrario è false. Tenete presente che la classe File non consente di creare collegamenti simbolici direttamente.

I collegamenti simbolici consentono a un file di puntare a un altro file o directory presente sul disco. Anche se simili, i collegamenti simbolici non corrispondono agli alias di Mac OS e ai collegamenti di Windows. Un alias o un collegamento viene sempre riportato come un file (anziché come una directory) e la lettura o la scrittura su un alias o collegamento non influenza mai il file o directory originale a cui punta. D'altro canto, i collegamenti simbolici si comportano generalmente come il file o la directory a cui puntano. Essi possono essere riportati come file o directory e la lettura di o la scrittura su un collegamento simbolico va a modificare il file o la directory a cui esso punta, ma non il collegamento simbolico stesso. L'eliminazione di un collegamento simbolico, elimina tuttavia il collegamento e non la destinazione del collegamento.

Mac^® OS^®, Linux e Windows^® Vista^® supportano i collegamenti simbolici. Inoltre, in Windows, la proprietà isSymbolicLink di un oggetto File che fa riferimento a un punto di congiunzione (utilizzato nel file system NTFS) è impostata su true.

La sequenza di caratteri di fine riga utilizzata dal sistema operativo host.

In Mac OS e Linux, si tratta del carattere di avanzamento riga (codice carattere 0x0A esadecimale). In Windows, si tratta del carattere di ritorno a capo (codice carattere 0x0D esadecimale) seguito dal carattere di avanzamento riga (codice carattere 0x0A esadecimale).

Altre informazioni

import flash.filesystem.*;

var str:String = "Hello\n" + 
        "World\n";
str = str.replace(/\n/g, File.lineEnding);
var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.WRITE);
fileStream.writeUTF(str);
fileStream.close();

Il percorso completo nella rappresentazione del sistema operativo host. In Mac OS e Linux, il carattere barra (/) è utilizzato come separatore del percorso. Tuttavia, in Windows, potete impostare la proprietà nativePath utilizzando sia il carattere barra che barra rovesciata (\) come separatore del percorso; AIR sostituirà automaticamente le barre con il carattere barra rovesciata appropriato.

Prima di scrivere del codice per impostare direttamente la proprietà nativePath, valutate se tale operazione possa generare codice specifico per una sola piattaforma. Ad esempio, un percorso nativo come "C:\\Documents and Settings\\bob\\Desktop" è valido solo in Windows. È molto meglio usare le seguenti proprietà statiche, che rappresentano le directory utilizzate più frequentemente e sono valide su tutte le piattaforme:

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Potete quindi utilizzare il metodo resolvePath() per ottenere un percorso relativo a queste directory.

Alcune API Flex, ad esempio la proprietà source della classe SWFLoader, utilizzano un URL (la proprietà url di un oggetto File), non un percorso nativo (la proprietà nativePath).

Altri esempi

Altre informazioni

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

La directory che contiene il file o la directory a cui l'oggetto File fa riferimento.

Se il file o directory non esiste, la proprietà parent restituisce comunque l'oggetto File che punta alla directory contenitore, anche se tale directory non esiste.

Questa proprietà è identica al valore restituito da resolvePath(".."), con la sola differenza che la directory principale di una directory principale è null.

import flash.filesystem.File;

var tempFile:File = File.createTempDirectory();
trace(tempFile.parent.nativePath);
tempFile.deleteFile();

Consente di determinare se l’applicazione ha ottenuto l’autorizzazione di accesso al file system.

Elementi API correlati

Indica se il runtime impedisce all’oggetto File di essere sottoposto a backup nel cloud.

Se questa proprietà è impostata su true, di essa non viene automaticamente eseguito un backup sul cloud nelle piattaforme che forniscono questo servizio. Il valore predefinito per questa proprietà è false.

Altre informazioni

Il carattere separatore dei componenti di percorso del sistema operativo host.

In Mac OS e Linux, si tratta del carattere barra (/). In Windows, si tratta del carattere barra rovesciata (\).

Nota: quando utilizzate la barra rovesciata in valori letterali di stringa, ricordate di digitare il carattere due volte (come in "directory\\file.ext"). Ogni coppia di barre rovesciate in un valore letterale di stringa rappresenta una barra rovesciata nella stringa.

Altre informazioni

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Apollo Test");
var file:File = File.documentsDirectory.resolvePath("Apollo Test/employees/bob/test.txt");

var relativePath:String = directory.getRelativePath(file); // employees/bob/test.txt
relativePath = relativePath.replace(/\//g, File.separator);
trace(relativePath); 

Lo spazio disponibile per l'uso in questa posizione di File, espresso in byte.

Se l'oggetto File fa riferimento a una directory, spaceAvailable indica lo spazio nella directory che può essere utilizzato dai file. Se l'oggetto File fa riferimento a un file, spaceAvailable indica lo spazio fino al quale il file potrebbe aumentare. Se la posizione del file non esiste, spaceAvailable viene impostato su 0. Se l'oggetto File fa riferimento a un collegamento simbolico, spaceAvailable indica lo spazio disponibile nella posizione a cui punta il collegamento simbolico.

In genere, lo spazio disponibile per una directory o un file corrisponde allo spazio disponibile sul volume che contiene la directory o il file. Nel calcolo dello spazio disponibile possono tuttavia essere considerate quote e limiti delle singole directory.

L'aggiunta di un file o una directory a un volume richiede in genere più spazio delle dimensioni effettive del file o del contenuto della directory. Il sistema operativo, ad esempio, può richiedere più spazio per la memorizzazione delle informazioni di indice. In alternativa, i settori del disco necessari potrebbero richiedere spazio aggiuntivo. Lo spazio aggiuntivo cambia inoltre in modo dinamico. Non potete pertanto allocare tutto lo spazio segnalato per l'archiviazione dei file.

Altri esempi

La codifica predefinita utilizzata dal sistema operativo host.

I valori possibili includono "windows-1252" "shift-jis", "cn-gb", "iso-8859-1" e altri. Per un elenco completo, vedete Set di caratteri supportati.

Potete usare questo valore quando utilizzate i metodi readMultiByte() e writeMultiByte() della classe FileStream.

Altre informazioni

Elementi API correlati

import flash.filesystem.File;

var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.READ);
var str:String = fileStream.readMultiByte(file.size, File.systemCharset);
trace(str);    

L'URL per questo percorso di file.

Se si tratta di un riferimento a un percorso nella directory di archiviazione dell'applicazione, lo schema URL è "app-storage"; se si tratta di un riferimento a un percorso nella directory dell'applicazione, lo schema URL è "app"; in caso contrario lo schema è "file".

Potete usare spazi (anziché "%20") per assegnare un valore alla proprietà url; AIR codifica automaticamente le stringhe (ad esempio, convertendo gli spazi in "%20").

Altri esempi

Altre informazioni

Elementi API correlati

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

La directory utente.

In Windows, si tratta della directory principale della cartella Documenti (ad esempio, C:\Documents and Settings\nomeUtente). In Mac OS, si tratta di /Users/nomeUtente. In Linux, si tratta di /home/nomeUtente.

La proprietà userDirectory offre un metodo che funziona in tutte le piattaforme per fare riferimento alla directory utente. Se impostate la proprietà nativePath o url di un oggetto File, essa funzionerà solo sulla piattaforma per la quale il percorso è valido.

Se un sistema operativo non supporta una directory utente, viene utilizzata in alternativa una directory idonea del file system.

Nei dispositivi AIR per TV, la proprietà userDirectory fa riferimento a una directory utente esclusiva dell'applicazione.

Altri esempi

Altre informazioni

import flash.filesystem.File;

var files:Array = File.userDirectory.listDirectory();
for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

La funzione di costruzione per la classe File.

Se passate un argomento path, l'oggetto File punta al percorso specificato e le proprietà nativePath e url sono impostate per riflettere tale percorso.

Benché sia possibile passare un argomento path per specificare un percorso file, valutate se tale operazione possa generare codice specifico per una sola piattaforma. Ad esempio, un percorso nativo come "C:\\Documents and Settings\\bob\\Desktop" o un URL come "file:///C:/Documents%20and%20Settings/bob/Desktop" è valido solo in Windows. È molto meglio usare le seguenti proprietà statiche, che rappresentano le directory utilizzate più frequentemente e sono valide su tutte le piattaforme:

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Potete quindi utilizzare il metodo resolvePath() per ottenere un percorso relativo a queste directory. Ad esempio, il codice seguente imposta un oggetto File che punta al file settings.xml nella directory di archiviazione dell'applicazione:

var file:File = File.applicationStorageDirectory.resolvePath("settings.xml");

Importante: se passate una stringa URL nel parametro path, l'URL viene decodificato per risolvere il percorso di file. Ad esempio, l'istruzione new File("file:///c:/test/demo%20file%201%2e0.txt") crea un oggetto File con il percorso nativo "c:\test\demo file 1.0.txt". (Un URL utilizza i prefissi di schema file:, app: o app-storage:.) Tuttavia, se i prefissi URL validi vengono omessi, la stringa del percorso viene trattata come un percorso nativo e non viene eseguita alcuna decodifica. Dovete valutare questa possibilità quando eseguite la convalida di percorsi che derivano da fonti potenzialmente inattendibili. Se vi limitate a convalidare la stringa di input, la decodifica dell'URL potrebbe consentire a un hacker di bypassare i vostri controlli di convalida. Convalidate sempre il percorso finale dell'oggetto File di cui viene creata un'istanza:

     var file:File = new File( taintedString );
     validate( file.nativePath ); //where validate() is your path validation function
     

Altri esempi

Elementi API correlati

Visualizza una finestra di dialogo per la scelta di una directory, in cui l'utente può selezionare una directory. Quando l'utente seleziona la directory, viene inviato l'evento select. La proprietà target dell'evento select è l'oggetto File che punta alla directory selezionata.

La finestra di dialogo di selezione directory non viene sempre visualizzata in primo piano rispetto alle finestre appartenenti a un'altra finestra (le finestre con una proprietà owner non null). Per evitare problemi di ordinamento delle finestre, nascondere quelle appartenenti a un'altra finestra prima di chiamare questo metodo.

Nota: nei dispositivi Android, browseForDirectory() non è supportato. L'oggetto File invia immediatamente un evento cancel.

Parametri

Altri esempi

Elementi API correlati

import flash.filesystem.File;
import flash.events.Event;

var directory:File = File.documentsDirectory;

try
{
    directory.browseForDirectory("Select Directory");
    directory.addEventListener(Event.SELECT, directorySelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function directorySelected(event:Event):void 
{
    directory = event.target as File;
    var files:Array = directory.getDirectoryListing();
    for(var i:uint = 0; i < files.length; i++)
    {
        trace(files[i].name);
    }
}

Visualizza una finestra di dialogo Apri file, in cui l'utente può selezionare un file da aprire.

Quando l'utente seleziona il file, viene inviato l'evento select. La proprietà target dell'evento select è l'oggetto File che punta al file selezionato.

La finestra di dialogo Apri file non viene sempre visualizzata in primo piano rispetto alle finestre appartenenti a un'altra finestra (le finestre con una proprietà owner non null). Per evitare problemi di ordinamento delle finestre, nascondere quelle appartenenti a un'altra finestra prima di chiamare questo metodo.

Nota: nei dispositivi Android, non è possibile impostare il titolo della finestra di dialogo File. Il parametro title viene ignorato.

Parametri

Altri esempi

Elementi API correlati

import flash.filesystem.*;
import flash.events.Event;
import flash.net.FileFilter;

var fileToOpen:File = new File();
var txtFilter:FileFilter = new FileFilter("Text", "*.as;*.css;*.html;*.txt;*.xml");

try 
{
    fileToOpen.browseForOpen("Open", [txtFilter]);
    fileToOpen.addEventListener(Event.SELECT, fileSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function fileSelected(event:Event):void 
{
    var stream:FileStream = new FileStream();
    stream.open(event.target, FileMode.READ);
    var fileData:String = stream.readUTFBytes(stream.bytesAvailable);
    trace(fileData);
}

Visualizza la finestra di dialogo Apri file, in cui l'utente può selezionare uno o più file da aprire.

Quando l'utente seleziona più file, viene inviato l'evento selectMultiple. La proprietà target dell'evento select corrisponde a questo oggetto File. A differenza di browseForOpen(), con il metodo browseForOpenMultiple(), questo oggetto File non viene aggiornato per fare riferimento ad alcuno dei file selezionati. Invece l'evento selectMultiple risultante contiene un array dei file selezionati.

La finestra di dialogo Apri file non viene sempre visualizzata in primo piano rispetto alle finestre appartenenti a un'altra finestra (le finestre con una proprietà owner non null). Per evitare problemi di ordinamento delle finestre, nascondere quelle appartenenti a un'altra finestra prima di chiamare questo metodo.

Nota: nei dispositivi Android, non è possibile impostare il titolo della finestra di dialogo File. Il parametro title viene ignorato.

Parametri

Altri esempi

Elementi API correlati

import flash.filesystem.*;
import flash.events.FileListEvent;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForOpenMultiple("Select Files");
    docsDir.addEventListener(FileListEvent.SELECT_MULTIPLE, filesSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function filesSelected(event:FileListEvent):void 
{
    for (var i:uint = 0; i < event.files.length; i++) 
    {
        trace(event.files[i].nativePath);
    }
}

Visualizza la finestra di dialogo Apri file, in cui l'utente può selezionare la destinazione di un file.

Quando l'utente seleziona il file, viene inviato l'evento select. La proprietà target dell'evento select è l'oggetto File che punta alla destinazione di salvataggio selezionata.

La finestra di dialogo Salva file non viene sempre visualizzata in primo piano rispetto alle finestre appartenenti a un'altra finestra (le finestre con una proprietà owner non null). Per evitare problemi di ordinamento delle finestre, nascondere quelle appartenenti a un'altra finestra prima di chiamare questo metodo.

Nota: nei dispositivi Android, non è possibile impostare il titolo della finestra di dialogo File. Il parametro title viene ignorato.

Parametri

Altri esempi

Elementi API correlati

import flash.filesystem.*;
import flash.events.Event;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForSave("Save As");
    docsDir.addEventListener(Event.SELECT, saveData);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function saveData(event:Event):void 
{
    var newFile:File = event.target as File;
    var str:String = "Hello.";
    if (!newFile.exists)
    {
        var stream:FileStream = new FileStream();
        stream.open(newFile, FileMode.WRITE);
        stream.writeUTFBytes(str);
        stream.close();
    }
}

Annulla eventuali operazioni asincrone in attesa.

Rende convenzionale il percorso File.

Se l'oggetto File rappresenta un file o una directory esistente, la convenzionalizzazione regola il percorso in modo che lettere maiuscole e minuscole corrispondano a quelle utilizzate nel nome del file o della directory. Se l'oggetto File è un collegamento simbolico, la convenzionalizzazione regola il percorso in modo che corrisponda al file o alla directory al quale il collegamento punta, a prescindere dal fatto che tale file o directory esista. Nei file system che fanno distinzione tra maiuscole e minuscole (ad esempio, Linux), quando sono presenti più file con nomi diversi solo per la maiuscola, il metodo canonicalize() corregge il percorso in modo che corrisponda al primo file trovato (secondo un ordine determinato dal file system).

Inoltre, la canonicalizzazione converte i nomi file brevi in nomi file lunghi in Windows.

Altri esempi

import flash.filesystem.*;

var path:File = File.desktopDirectory.resolvePath("air test");
trace(path.nativePath); 
path.canonicalize();
trace(path.nativePath); // ...\AIR Test

import flash.filesystem.*;

var path:File = new File();
path.nativePath = "C:\\AIR~1";
path.canonicalize();
trace(path.nativePath); // C:\AIR Test

Restituisce una copia dell'oggetto File. Le registrazioni eventi non vengono copiate.

Nota: questo metodo non copia il file stesso, ma si limita a eseguire una copia dell'istanza dell'oggetto File ActionScript. Per copiare un file, dovete utilizzare il metodo copyTo().

Copia il file o la directory dalla posizione specificata dall'oggetto File alla posizione specificata dal parametro newLocation. Il processo di copia crea eventuali directory principali necessarie (se possibile). Con la sovrascrittura dei file mediante il comando copyTo(), gli attributi dei file vengono sovrascritti.

Parametri

Altri esempi

Elementi API correlati

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:FileReference = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:FileReference = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

if (sourceFile.copyTo(destination, true)) {
    trace("Done.");
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

try 
{
    sourceFile.copyTo(destination, true);
}
catch (error:Error)
{
    trace("Error:", error.message);
}

Inizia a copiare il file o la directory dalla posizione specificata dall'oggetto File alla posizione specificata dal parametro destination.

Al termine, viene inviato un evento complete (operazione riuscita) o ioError (operazione non riuscita). Il processo di copia crea eventuali directory principali necessarie (se possibile).

Parametri

Altri esempi

Elementi API correlati

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

sourceFile.copyToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileCopiedHandler);

function fileCopiedHandler(event:Event):void {
    trace("Done.");
}

Crea la directory specificata e le directory principali necessarie. Se la directory esiste già, non viene intrapresa alcuna azione.

Altri esempi

import flash.filesystem.*;

var source:File = File.desktopDirectory.resolvePath("test.txt");
var target:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var targetParent:File = target.parent;
targetParent.createDirectory();
source.moveTo(target, true);

Restituisce un riferimento a una nuova directory temporanea. Si tratta di una nuova directory nel percorso di directory temporaneo del sistema.

Questo metodo vi consente di identificare una nuova directory univoca, senza interrogare il sistema per verificare se la directory è nuova e univoca.

Potreste dover cancellare la directory temporanea prima di chiudere l'applicazione, in quanto essa non viene cancellata automaticamente su alcuni dispositivi.

Altri esempi

Elementi API correlati

import flash.File;

var temp:File = File.createTempDirectory();
trace(temp.nativePath);

Restituisce un riferimento a un nuovo file temporaneo. Si tratta di un nuovo file nel percorso di directory temporaneo del sistema.

Questo metodo vi consente di identificare un nuovo file univoco, senza interrogare il sistema per verificare se il file è nuovo e univoco.

Potreste dover cancellare il file temporaneo prima di chiudere l'applicazione, in quanto esso non viene cancellato automaticamente.

Altri esempi

Elementi API correlati

import flash.File;

var temp:File = File.createTempFile();
trace(temp.nativePath);

Elimina la directory. Se questo oggetto File è in realtà un collegamento simbolico a una directory, viene rimosso il collegamento, non la directory.

Parametri

Altri esempi

Elementi API correlati

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Empty Junk Directory/");
File.createDirectory(directory);
trace(directory.exists); // true
directory.deleteDirectory();
trace(directory.exists); // false

Elimina la directory in modo asincrono. Se questo oggetto File è in realtà un collegamento simbolico a una directory, viene rimosso il collegamento, non la directory.

Parametri

Elementi API correlati

Elimina il file. Se questo oggetto File è in realtà un collegamento simbolico, viene rimosso il collegamento, non il file di destinazione.

Altri esempi

Elementi API correlati

import flash.filesystem.*;

var file:File = File.createTempFile();
trace(file.exists); // true
file.deleteFile();
trace(file.exists); // false

Elimina il file in modo asincrono. Se questo oggetto File è in realtà un collegamento simbolico, viene rimosso il collegamento, non il file di destinazione.

Elementi API correlati

Restituisce un array di oggetti File corrispondenti ai file e alle directory della directory rappresentata dall'oggetto File. Questo metodo non esplora il contenuto delle sottodirectory.

Altri esempi

Elementi API correlati

import flash.filesystem.File;

var directory:File = File.userDirectory;
var list:Array = directory.getDirectoryListing();
for (var i:uint = 0; i < list.length; i++) {
    trace(list[i].nativePath);
}

Recupera in modo asincrono un array di oggetti File corrispondenti al contenuto della directory rappresentata dall'oggetto File.

Elementi API correlati

import flash.filesystem.File;
import flash.events.FileListEvent;

var directory:File = File.userDirectory;
directory.getDirectoryListingAsync();
directory.addEventListener(FileListEvent.DIRECTORY_LISTING, directoryListingHandler);

function directoryListingHandler(event:FileListEvent):void {
    var list:Array = event.files;
    for (var i:uint = 0; i < list.length; i++) {
        trace(list[i].nativePath);
    }
}

Trova il percorso relativo tra due percorsi File.

Il percorso relativo è l'elenco dei componenti che possono essere aggiunti a (risolti rispetto a) questo riferimento per trovare il secondo riferimento (parametro). Il percorso relativo viene restituito utilizzando il carattere separatore "/".

Facoltativamente, i percorsi relativi possono includere anche riferimenti "..", tuttavia questi percorsi non oltrepassano limiti di volume cospicui.

Parametri

Altri esempi

Restituisce un array di oggetti File che elenca le directory principali del sistema.

Ad esempio, in Windows, si tratta di un elenco di volumi, quali l'unità C: e l'unità D:. Eventuali unità vuote, quali unità CD o DVD in cui non è inserito alcun disco, non sono incluse in questo array. In Mac e Linux, questo metodo restituisce sempre l'unica directory principale della macchina (la directory "/").

Nei file system nei quali la root non è leggibile, come quello di Android, le proprietà dell'oggetto File restituito non riflettono sempre il valore effettivo. Ad esempio, in Android, la proprietà spaceAvailable restituisce 0.

Altre informazioni

import flash.filesystem.File;
var rootDirs:Array = File.getRootDirectories();

for (var i:uint = 0; i < rootDirs.length; i++) {
    trace(rootDirs[i].nativePath);
}

Sposta il file o la directory dalla posizione specificata dall'oggetto File alla posizione specificata dal parametro destination.

Per rinominare un file, impostate il parametro destination in modo che punti a un percorso che si trova nella directory del file, ma con un nome file differente.

Il processo di spostamento crea eventuali directory principali necessarie (se possibile).

Parametri

Altri esempi

Elementi API correlati

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

try  
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/Results/test1.txt");

try 
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

Inizia a spostare il file o la directory dalla posizione specificata dall'oggetto File alla posizione specificata dal parametro newLocation.

Per rinominare un file, impostate il parametro destination in modo che punti a un percorso che si trova nella directory del file, ma con un nome file differente.

Il processo di spostamento crea eventuali directory principali necessarie (se possibile).

Parametri

Altri esempi

Elementi API correlati

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("Apollo Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

sourceFile.moveToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileMoveCompleteHandler);

function fileMoveCompleteHandler(event:Event):void 
{
    trace("Done.")
}

Sposta un file o una directory nel cestino.

Nota: nei sistemi operativi che non prevedono la possibilità di ripristinare i file dalla cartella del cestino, i file vengono rimossi immediatamente.

Altri esempi

Elementi API correlati

Sposta un file o una directory nel cestino in modo asincrono.

Nota: nei sistemi operativi che non prevedono la possibilità di ripristinare i file dalla cartella del cestino, i file vengono rimossi immediatamente.

Elementi API correlati

Apre il file nell'applicazione registrata dal sistema operativo per l'apertura di questo tipo di file.

AIR impedisce l'utilizzo del metodo File.openWithDefaultApplication() per l'apertura di determinati file. In Windows, AIR impedisce l'apertura di determinati tipi di file (file con estensioni specifiche elencate di seguito). In Mac OS e Linux, AIR impedisce l'apertura di file che vengono avviati in applicazioni specifiche, indicate di seguito. Il tentativo di aprire uno di questi file tramite il metodo openWithDefaultApplication() genera un'eccezione. Queste limitazioni non sono tuttavia applicabili alle applicazioni AIR installate con un programma di installazione nativo (applicazioni nel profilo desktop esteso), che possono aprire file di qualsiasi tipo.

Non potete aprire documenti dalla directory dell'applicazione.

Nelle tabelle riportate di seguito sono elencate le estensioni di file non consentiti in Windows, oltre alle applicazioni limitate in Mac OS e Linux:

Altri esempi

Elementi API correlati

import flash.filesystem.File;
import flash.net.FileFilter;

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

Richiede l’autorizzazione di accesso al file system.

Crea un nuovo oggetto File con un percorso relativo al percorso dell'oggetto File basato sul parametro path (una stringa).

Potete utilizzare un percorso relativo o assoluto come parametro path.

Se specificate un percorso relativo, il parametro path specificato viene "aggiunto" al percorso dell'oggetto File. Tuttavia, l'utilizzo di ".." nel path può restituire un percorso che non è un elemento secondario dell'oggetto File. Il riferimento risultante non deve necessariamente fare riferimento a una posizione di sistema effettiva.

Se specificate un riferimento di file assoluto, il metodo restituisce l'oggetto File che punta a quel percorso. Nel riferimento di file assoluto deve essere utilizzata la sintassi di path nativa valida per il sistema operativo dell'utente (ad esempio "C:\\test" in Windows). Non utilizzate un URL (ad esempio "file:///c:/test") come parametro path.

Tutti i percorsi risultanti vengono normalizzati come segue:

• Tutti gli elementi "." vengono ignorati.
• Tutti gli elementi ".." consumano (sono listener di) la propria voce principale.
• Nessun riferimento ".." che raggiunge la directory principale di sistema o la directory principale di archiviazione persistente nell'applicazione passa tale nodo; esso verrà ignorato.

È importante utilizzare sempre il carattere della barra (/) come separatore nel percorso. In Windows, potete inoltre utilizzare il carattere barra rovesciata (\), anche se non è consigliabile. L'uso del carattere barra rovesciata potrebbe comportare la creazione di applicazioni che non funzionano su altre piattaforme.

Per i nomi di file e directory viene fatta distinzione tra maiuscole e minuscole in ambiente Linux.

Parametri

Altri esempi

Inviato quando un'operazione asincrona in attesa viene annullata.

Questo evento ha le seguenti proprietà:

Inviato quando un'operazione asincrona viene completata.

Questo evento ha le seguenti proprietà:

Inviato quando un elenco di directory è disponibile come risultato di una chiamata al metodo getDirectoryListingAsync().

Questo evento ha le seguenti proprietà:

Elementi API correlati

Inviato quando si verifica un errore durante un'operazione file asincrona.

Questo evento ha le seguenti proprietà:

Inviato quando l’applicazione richiede l’autorizzazione di accesso al file system. Controllando il valore della proprietà status, è possibile verificare se l’autorizzazione è stata concessa o negata.

Elementi API correlati

Inviato quando un'operazione viola una limitazione di sicurezza.

Questo evento ha le seguenti proprietà:

Inviato quando l'utente seleziona un file o una directory da una finestra di dialogo di ricerca file o directory.

Questo evento ha le seguenti proprietà:

Inviato quando l'utente seleziona un file nella finestra di dialogo aperta da una chiamata al metodo browseForOpenMultiple().

Elementi API correlati