Utilisation des instructions SQL

Créez une occurrence de SQLStatement.

L’objet SQLStatement représente l’instruction SQL dans votre application.

var selectData:SQLStatement = new SQLStatement(); 

Spécifiez sur quelle base de données la requête doit s’exécuter.

Pour ce faire, définissez la propriété sqlConnection de l’objet SQLStatement sur l’occurrence de SQLConnection connectée à la base de données désirée.

// A SQLConnection named "conn" has been created previously 
selectData.sqlConnection = conn;

Définissez la véritable instruction SQL.

Créez le texte de l’instruction sous forme d’occurrence de String et affectez-la à la propriété text de l’occurrence de SQLStatement.

selectData.text = "SELECT col1, col2 FROM my_table WHERE col1 = :param1";

Définissez les fonctions gérant le résultat de l’exécution (mode d’exécution asynchrone uniquement).

Utilisez la méthode addEventListener() pour enregistrer les fonctions en tant qu’écouteurs des événements result et error de l’occurrence de SQLStatement.

// using listener methods and addEventListener() 
     
selectData.addEventListener(SQLEvent.RESULT, resultHandler); 
selectData.addEventListener(SQLErrorEvent.ERROR, errorHandler); 
     
function resultHandler(event:SQLEvent):void 
{ 
    // do something after the statement execution succeeds 
} 
     
function errorHandler(event:SQLErrorEvent):void 
{ 
    // do something after the statement execution fails 
} 

Vous pouvez également spécifier des méthodes d’écouteur d’événements à l’aide d’un objet Responder . Dans ce cas, créez l’occurrence de Responder et associez-la aux méthodes d’écouteur d’événement.

// using a Responder (flash.net.Responder) 
     
var selectResponder = new Responder(onResult, onError); 
     
function onResult(result:SQLResult):void 
{ 
    // do something after the statement execution succeeds 
} 
     
function onError(error:SQLError):void 
{ 
    // do something after the statement execution fails 
} 

Si le texte de l’instruction comprend des définitions de paramètres, donnez les valeurs de ces paramètres.

Pour affecter les valeurs des paramètres, utilisez la propriété de tableau associatif parameters de l’occurrence de SQLStatement.

selectData.parameters[":param1"] = 25;

Exécutez l’instruction SQL.

Appelez la méthode execute() de l’occurrence de SQLStatement.

// using synchronous execution mode 
// or listener methods in asynchronous execution mode 
selectData.execute();

En outre, si vous utilisez une occurrence de Responder à la place des écouteurs d’événement en mode d’exécution asynchrone, transmettez cette occurrence à la méthode execute() .

// using a Responder in asynchronous execution mode 
selectData.execute(-1, selectResponder);

Vous trouverez des exemples spécifiques de ces procédures aux rubriques suivantes :

Récupération de données dans une base de données

Insertion de données

Modification ou suppression de données