PrintJob  - AS3

Indique si une tâche d’impression est en cours. Une tâche d’impression est en cours (la valeur de propriété est true) si l’une des deux conditions suivantes est remplie :

• La boîte de dialogue Mise en page ou Imprimer est affichée.
• La méthode start() ou start2() a été appelée avec une valeur de renvoi de true, et la méthode send() ou terminate() n’a pas été appelée.

Si cette propriété est définie sur true et que vous appelez la méthode showPageSetupDialog(), start() ou start2(), le moteur d’exécution renvoie une exception.

Eléments de l’API associés

Nombre de copies des pages ajoutées ultérieurement à la tâche d’impression, que le système d’impression imprime. Cette valeur correspond au nombre de copies indiqué par l’utilisateur dans la boîte de dialogue Imprimer du système d’exploitation. Si le nombre de copies n’était pas affiché dans la boîte de dialogue Imprimer ou si la boîte de dialogue n’était pas présentée à l’utilisateur, la valeur est 1 (à moins qu’elle ait été modifiée par le code de l’application).

Numéro de la première page de l’étendue de pages indiquée par l’utilisateur dans la boîte de dialogue Imprimer du système d’exploitation. Cette propriété est zéro si l’utilisateur sollicite l’impression de toutes les pages, si l’étendue de pages n’était pas affichée dans la boîte de dialogue Imprimer ou si cette dernière n’a pas été présentée à l’utilisateur.

Indique si l’imprimante sélectionnée avec les paramètres d’impression actuels imprime en couleur (true) ou en nuances de gris (false).

S’il est impossible de déterminer une valeur de couleur ou de nuances de gris, la valeur est true.

Indique si la classe PrintJob est prise en charge sur la plate-forme actuelle (true) ou non (false).

Nom ou titre de la tâche d’impression. En règle générale, le système d’exploitation utilise le nom de la tâche comme titre de la tâche dans la file d’impression ou comme nom par défaut d’une tâche imprimée dans un fichier.

Si vous n’avez pas appelé la méthode start() ou start2() et n’avez pas défini de valeur pour la propriété, la valeur de cette propriété est null.

Pour chaque tâche d’impression que vous exécutez avec une occurrence de PrintJob, définissez cette propriété avant d’appeler la méthode start() ou start2().

La valeur par défaut est null.

Numéro de la dernière page de l’étendue de pages indiquée par l’utilisateur dans la boîte de dialogue Imprimer du système d’exploitation. Cette propriété est zéro si l’utilisateur sollicite l’impression de toutes les pages, si l’étendue de pages n’était pas affichée dans la boîte de dialogue Imprimer ou si cette dernière n’a pas été présentée à l’utilisateur.

Résolution physique de l’imprimante sélectionnée, en pixels par pouce. Cette valeur est calculée selon les paramètres d’impression en cours, comme indiqué par le système d’exploitation.

S’il est impossible de déterminer la résolution, la valeur est une valeur par défaut standard. La valeur par défaut est de 600 ppp sous Linux et de 360 ppp sous Mac OS. Sous Windows, la résolution de l’imprimante est toujours disponible ; par conséquent, aucune valeur par défaut n’est nécessaire.

Orientation de l’image à imprimer. Les valeurs admises sont définies comme constantes dans la classe PrintJobOrientation.

Remarque : à partir d’AIR 2, définissez cette propriété avant de lancer une tâche d’impression pour définir l’orientation par défaut dans les boîtes de dialogue Mise en page et Imprimer. Définissez la propriété lorsqu’une tâche d’impression est en cours (après l’appel de la méthode start() ou start2()) pour définir l’orientation de l’étendue de pages dans la tâche.

Eléments de l’API associés

Hauteur de la zone la plus grande pouvant être centrée dans la zone imprimable réelle de la page, en points. Les marges éventuellement définies par l’utilisateur sont ignorées. Cette propriété n’est disponible qu’après l’exécution d’un appel de la méthode PrintJob.start().

Remarque : à partir d’AIR 2, cette propriété est déconseillée. Utilisez plutôt la propriété printableArea, qui mesure la zone imprimable en fractions de point et décrit avec précision les zones imprimables hors centre.

Plus d’exemples

Eléments de l’API associés

Largeur de la zone la plus grande pouvant être centrée dans la zone imprimable réelle de la page, en points. Les marges éventuellement définies par l’utilisateur sont ignorées. Cette propriété n’est disponible qu’après l’exécution d’un appel de la méthode PrintJob.start().

Remarque : à partir d’AIR 2, cette propriété est déconseillée. Utilisez plutôt la propriété printableArea, qui mesure la zone imprimable en fractions de point et décrit avec précision les zones imprimables hors centre.

Plus d’exemples

Eléments de l’API associés

Limites du support d’imprimante, en points. Cette valeur utilise le même système de coordonnées que celui utilisé pour les prochains appels de addPage().

Hauteur totale du papier, en points. Cette propriété n’est disponible qu’après l’exécution d’un appel de la méthode PrintJob.start().

Remarque : à partir d’AIR 2, cette propriété est déconseillée. Utilisez plutôt la propriété paperArea, qui mesure les dimensions de la feuille de papier en fractions de point.

Eléments de l’API associés

Largeur totale du papier, en points. Cette propriété n’est disponible qu’après l’exécution d’un appel de la méthode PrintJob.start().

Remarque : à partir d’AIR 2, cette propriété est déconseillée. Utilisez plutôt la propriété paperArea, qui mesure les dimensions de la feuille de papier en fractions de point.

Eléments de l’API associés

Limites de la zone imprimable du support d’imprimante, en points. Cette valeur utilise le même système de coordonnées que celui utilisé pour les prochains appels de addPage().

Récupère ou définit l’imprimante à utiliser pour la tâche d’impression en cours. La chaîne transmise à l’accesseur Set et renvoyée par l’accesseur Get doit correspondre à l’une des chaînes dans le tableau renvoyé par la méthode printers(). Pour indiquer que l’imprimante par défaut doit être utilisée, définissez la valeur sur null. Sur les systèmes d’exploitation qui ne permettent pas de déterminer l’imprimante par défaut, la valeur de cette propriété est null.

     import flash.printing.PrintJob;
     
     var myPrintJob:PrintJob = new PrintJob();
     myPrintJob.printer = "HP_LaserJet_1";
     myPrintJob.start();
     

Définir la valeur de cette propriété entraîne la sélection immédiate de l’imprimante. Si le choix de l’imprimante échoue, la valeur précédente de cette propriété est rétablie. Pour déterminer si la valeur de l’imprimante a été correctement définie, lisez la valeur après avoir tenté de la définir, puis confirmez qu’elle correspond à la valeur ayant été définie.

La propriété printer d’une tâche d’impression active ne peut pas être modifiée. Essayez de la modifier après que l’appel de la méthode start() ou start2() a abouti et avant que l’appel de la méthode send() ou terminate() n’échoue.

Fournit une liste des imprimantes disponibles en tant que valeurs de noms de chaîne. La liste n’est pas calculée à l’avance. Elle est générée lors de l’appel de la fonction. Si aucune imprimante n’est disponible ou si le système ne prend pas en charge l’impression, la valeur est null(). Si le système prend en charge l’impression, mais ne parvient pas à renvoyer une liste d’imprimantes, la valeur est un vecteur avec un élément unique (sa propriété length est 1). Dans ce cas, l’unique élément correspond au nom de l’imprimante actuelle (ou au nom par défaut s’il s’avère impossible de déterminer le nom de l’imprimante actuelle).

Indique si l’environnement d’exécution de Flash prend en charge une boîte de dialogue Mise en page distincte. Si cette propriété est définie sur true, vous pouvez appeler la méthode showPageSetupDialog() pour afficher la boîte de dialogue Mise en page du système d’exploitation.

Eléments de l’API associés

Crée un objet PrintJob permettant d’imprimer une ou plusieurs pages. Après avoir créé un objet PrintJob, vous devez utiliser (dans l’ordre spécifié) les méthodes PrintJob.start(), PrintJob.addPage() et PrintJob.send() pour envoyer la tâche d’impression à l’imprimante.

Vous pouvez, par exemple, remplacer l’espace réservé [params] associé aux appels de la méthode myPrintJob.addPage() par des paramètres personnalisés, comme indiqué dans le code ci-dessous :

 // create PrintJob object
 var myPrintJob:PrintJob = new PrintJob();
  
 // display Print dialog box, but only initiate the print job
 // if start returns successfully.
 if (myPrintJob.start()) {
  
    // add specified page to print job
    // repeat once for each page to be printed
    try {
      myPrintJob.addPage([params]);
    }
    catch(e:Error) {
      // handle error 
    }
    try {
      myPrintJob.addPage([params]);
    }
    catch(e:Error) {
      // handle error 
    }
 
    // send pages from the spooler to the printer, but only if one or more
    // calls to addPage() was successful. You should always check for successful 
    // calls to start() and addPage() before calling send().
    myPrintJob.send();
 }
 

A partir de AIR 2, vous pouvez créer et utiliser plusieurs occurrences de PrintJob. Les propriétés définies pour l’occurrence de PrintJob sont conservées après l’impression. Cela vous permet de réutiliser une occurrence de PrintJob et de conserver les préférences d’impression d’un utilisateur tout en proposant des préférences d’impression pour d’autres types de contenu dans votre application. Pour le contenu dans Flash Player et dans les versions d’AIR antérieures à 2, vous ne pouvez pas créer un deuxième objet PrintJob si le premier est toujours actif. Si vous créez un deuxième objet PrintJob (en appelant new PrintJob()) tandis que le premier objet PrintJob est toujours actif, le deuxième objet PrintJob ne sera pas créé. Il est donc recommandé de vérifier la valeur de myPrintJob avant de créer un deuxième objet PrintJob.

Eléments de l’API associés

Envoie l’objet Sprite spécifié en tant que page unique au spouleur d’impression. Avant d’utiliser cette méthode, vous devez créer un objet PrintJob, puis utiliser start() ou start2() Ensuite, après avoir appelé une ou plusieurs fois addPage() pour une tâche d’impression, utilisez send() pour envoyer à l’imprimante les pages mises en file d’attente. En d’autres termes, après avoir créé un objet PrintJob, utilisez (dans l’ordre spécifié ci-après) start() ou start2(), addPage(), puis send() pour envoyer la tâche d’impression à l’imprimante. Vous pouvez appeler addPage() plusieurs fois après un unique appel à start() pour imprimer plusieurs pages d’une tâche d’impression.

Si addPage() entraîne le renvoi d’une exception par Flash Player (par exemple, si vous n’avez pas appelé start() ou si l’utilisateur a annulé la tâche d’impression), les appels suivants de addPage() échoueront. Cependant, si les appels précédents de addPage() ont abouti, la commande finale send() envoie les pages correctement mises en file d’attente vers l’imprimante.

Si la tâche d’impression met plus de 15 secondes à exécuter une opération addPage(), Flash Player renvoie une exception au prochain appel de addPage().

Si vous avez transmis une valeur pour le paramètre printArea, les coordonnées x et y du rectangle printArea établissent une correspondance avec le coin supérieur gauche (coordonnées 0, 0) de la zone imprimable sur la page. Les propriétés en lecture seule pageHeight et pageWidth décrivent la zone imprimable définie par start(). Dans la mesure où elle s’aligne sur le coin supérieur gauche de la zone imprimable sur la page, l’impression est recadrée sur la droite et/ou le bas de la zone définie par printArea si la taille de cette zone printArea est supérieure à celle de la zone imprimable sur la page. Dans Flash Professional, si vous ne transmettez aucune valeur pour le paramètre printArea et si la taille de la scène est supérieure à celle de la zone imprimable, le même type de découpage est effectué. Dans Flex ou Flash Builder, si vous ne transmettez aucune valeur pour le paramètre printArea et si la taille de l’écran est supérieure à celle de la zone imprimable, le même type de découpage est effectué.

Si vous souhaitez redimensionner un objet Sprite avant de l’imprimer, définissez ses propriétés d’échelle (voir flash.display.DisplayObject.scaleX et flash.display.DisplayObject.scaleY) avant d’appeler cette méthode, puis restaurez leur valeur d’origine après l’impression. L’échelle d’un objet Sprite ne dépend pas de printArea. Autrement dit, si vous spécifiez une zone d’impression dont la taille est 50 x 50 pixels, 2 500 pixels sont imprimés. Si vous redimensionnez l’objet Sprite, les 2 500 pixels sont imprimés, mais l’objet est imprimé à l’échelle retenue.

La fonction d’impression de Flash Player prend en charge les imprimantes PostScript et non PostScript. Les imprimantes non PostScript convertissent les vecteurs en bitmaps.

Paramètres

Plus d’exemples

Eléments de l’API associés

Définit le format de papier. Les valeurs admises pour le paramètre paperSize sont des constantes dans la classe PaperSize. L’appel de cette méthode a une incidence sur les paramètres d’impression, comme si l’utilisateur choisissait un format de papier dans la boîte de dialogue Mise en page ou Imprimer.

Vous pouvez appeler cette méthode à tout moment. Appelez cette méthode avant de lancer une tâche d’impression afin de définir le format de papier par défaut dans la boîte de dialogue Mise en page ou Imprimer. Appelez cette méthode lorsqu’une tâche d’impression est en cours afin de définir le format de papier d’une étendue de pages dans la tâche.

     import flash.printing.PrintJob;
     import flash.printing.PaperSize;
     
     var myPrintJob:PrintJob = new PrintJob();
     myPrintJob.selectPaperSize(PaperSize.ENV_10);
     

Paramètres

Eléments de l’API associés

Envoie les pages mises en file d’attente à l’imprimante après l’aboutissement de l’appel des méthodes start()ou start2() et addPage().

Cette méthode n’aboutit pas si l’appel à la méthode start() ou start2() échoue ou si un appel à la méthode addPage() renvoie une exception. Pour éviter une erreur, vérifiez que la méthode start() ou start2() renvoie true et repérez les exceptions de addPage() avant d’appeler cette méthode. L’exemple suivant explique comment vérifier correctement les erreurs avant d’appeler cette méthode :

     var myPrintJob:PrintJob = new PrintJob();
     if (myPrintJob.start()) {
       try {
         myPrintJob.addPage([params]);
       }
       catch(e:Error) {
          // handle error 
       }
     
       myPrintJob.send();
     }
     

Plus d’exemples

Eléments de l’API associés

Affiche la boîte de dialogue Mise en page du système d’exploitation si l’environnement actuel le permet. Utilisez la propriété supportsPageSetupDialog afin de déterminer si l’affichage de la boîte de dialogue Mise en page est pris en charge.

     import flash.printing.PrintJob;
     
     var myPrintJob:PrintJob = new PrintJob();
     if (myPrintJob.supportsPageSetupDialog)
     {
         myPrintJob.showPageSetupDialog();
     }
     

Eléments de l’API associés

Affiche la boîte de dialogue d’impression du système d’exploitation et démarre la mise en file d’attente. La boîte de dialogue Imprimer permet à l’utilisateur de modifier les paramètres d’impression. Lorsque la méthode PrintJob.start() est correctement renvoyée (l’utilisateur clique sur OK dans la boîte de dialogue Imprimer), les propriétés suivantes, qui représentent les paramètres d’impression en cours de l’utilisateur, sont renseignées :

Remarque : si l’utilisateur annule la boîte de dialogue d’impression, les propriétés ne sont pas renseignées.

Une fois que l’utilisateur a cliqué sur OK dans la boîte de dialogue d’impression, le lecteur démarre le processus de mise en attente d’une tâche d’impression dans le système d’exploitation. Dans la mesure où le système d’exploitation commence alors à afficher des informations sur le déroulement de l’impression, il est conseillé d’appeler PrintJob.addPage() et PrintJob.send() dès que possible pour envoyer les pages au spouleur. Vous pouvez utiliser les propriétés en lecture seule height, width et orientation qui sont renseignées par cette méthode pour mettre en forme l’impression.

Vérifiez que cette méthode renvoie la valeur true (lorsque l’utilisateur clique sur OK dans la boîte de dialogue d’impression du système d’exploitation) avant d’appeler à nouveau PrintJob.addPage() et PrintJob.send() :

     var myPrintJob:PrintJob = new PrintJob();
        if(myPrintJob.start()) {
          // addPage() and send() statements here
        }
     

Si l’un des intervalles suivants dure plus de 15 secondes pour l’occurrence de la tâche d’impression spécifiée, le prochain appel de PrintJob.start() renvoie false :

• PrintJob.start() et le premier appel de PrintJob.addPage()
• Un appel de PrintJob.addPage() et le prochain appel de PrintJob.addPage()
• Le dernier appel de PrintJob.addPage() et PrintJob.send()

Plus d’exemples

Eléments de l’API associés

Affiche éventuellement la boîte de dialogue Imprimer du système d’exploitation, démarre la mise en file d’attente et, le cas échéant, modifie les valeurs des propriétés en lecture seule de l’objet PrintJob.

Le paramètre uiOptions permet à l’appelant de contrôler les options qui s’affichent dans la boîte de dialogue Imprimer. Voir la classe PrintUIOptions. Ce paramètre est ignoré si showPrintDialog est false.

Même lorsque le paramètre showPrintDialogest défini sur true, le comportement de cette méthode peut différer de celui de la méthode start(). Sur certains systèmes d’exploitation, start() affiche la boîte de dialogue Mise en page, suivie de la boîte de dialogue Imprimer. En revanche, start2() n’affiche jamais la boîte de dialogue Mise en page.

Dans l’exemple suivant, le nombre maximal et le nombre minimal de pages de la boîte de dialogue d’impression sont définis avant que l’utilisateur ne voie s’afficher la boîte de dialogue :

     import flash.printing.PrintJob;
     import flash.printing.PrintUIOptions;
     
     var myPrintJob:PrintJob = new PrintJob();
     var uiOpt:PrintUIOptions = new PrintUIOptions();
     uiOpt.minPage = 1;
     uiOpt.maxPage = 3;
     var accepted:Boolean = myPrintJob.start2(uiOpt);
     

Paramètres

Eléments de l’API associés

Signale que la tâche d’impression doit être fermée sans être envoyée. Utilisez cette méthode lorsqu’une tâche d’impression a déjà été lancée par un appel de la méthode start() ou start2(), mais qu’il n’est pas opportun d’envoyer les pages à l’imprimante. En règle générale, la méthode terminate() est utilisée uniquement pour purger les erreurs.

Après l’appel de cette méthode, il est possible de réutiliser l’occurrence de PrintJob. Dans la mesure du possible, les paramètres d’impression de la tâche sont conservés.

1. Deux variables de type Sprite, nommées sheet1 et sheet2, sont déclarées.
2. init() est appelé pour attribuer une nouvelle occurrence de Sprite à sheet1 et sheet2, et pour appeler ensuite createSheet() au moyen de différents arguments.
3. createSheet() produit le résultat suivant :
   1. L’objet Sprite transmis est utilisé pour dessiner un rectangle d’une largeur de 100 pixels pour une hauteur de 200 pixels (x = 0 et y = 0), avec un arrière-plan de couleur gris clair et une bordure noire d’un pixel d’épaisseur.
   2. Un nouvel objet TextField, nommé txt, est créé en utilisant les dimensions du Sprite ; la propriété wordWrap est définie sur true et la propriété text est définie sur le Sprite transmis comme argument à createSheet().
   3. Si la valeur de l’argument Object transmis n’est pas null, créez une nouvelle occurrence du Sprite nommée img et utilisée pour dessiner un rectangle blanc à l’aide des propriétés de dimension et de coordonnée de l’objet transmis. Le rectangle blanc est ajouté à la liste d’affichage de l’objet Sprite par le biais de addChild().
   4. L’objet TextField txt est ajouté à la liste d’affichage de l’objet Sprite au moyen de addChild().
4. Au niveau du constructeur, la méthode d’impression qui est activée (pas commentée) est appelée. En raison de la similitude des méthodes, seule printOnePerPage() est décrite ci-dessous.
5. printOnePerPage() produit le résultat suivant :
   1. Déclaration d’un nouvel objet PrintJob, nommé pj, et de pagesToPrint en tant que uint.
   2. Ouverture de la boîte de dialogue d’impression native du système d’exploitation et attente que l’utilisateur clique sur OK.
   3. Vérification de l’orientation et si l’option Paysage est sélectionnée, renvoi d’une erreur et fermeture.
   4. Définition de la hauteur et de la largeur de la page pour sheet1 et sheet2.
   5. Envoi de sheet1 et sheet2 au spouleur d’impression par le biais de addPage().
   6. Si le nombre de pages à imprimer est > 0, impression de toutes les pages spoulées.
6. La méthode draw() est appelée, redimensionnement des deux propriétés Sprite pour les intégrer à la scène avec un repositionnement de sheet2 pour qu’elle se situe juste à droite de sheet1.

Remarque : le constructeur est configuré de telle manière que l’une des trois méthodes d’impression (une feuille par page, deux feuilles par page ou impression dans la moitié supérieure de la page) peut être sélectionnée en fonction d’une préférence. Cet exemple ne s’exécutera pas correctement à moins que précisément deux des méthodes d’impression ne soient désactivées au moyen de commentaires de code. L’exemple est conçu pour que printOnePerPage() soit appelée.

package {
    import flash.printing.PrintJob;
    import flash.printing.PrintJobOrientation;
    import flash.display.Stage;
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.geom.Rectangle;
       
    public class PrintJobExample extends Sprite {
        private var sheet1:Sprite;
        private var sheet2:Sprite;
           
        public function PrintJobExample() {
            init();
            printOnePerPage();
//            printTwoPerPage();
//            printTopHalf();
            draw();
        }
        
        private function init():void {
            sheet1 = new Sprite();
            createSheet(sheet1, "Once upon a time...", {x:10, y:50, width:80, height:130});

            sheet2 = new Sprite();
            createSheet(sheet2, "There was a great story to tell, and it ended quickly.\n\nThe end.", null);
        }
        
        private function createSheet(sheet:Sprite, str:String, imgValue:Object):void {
            sheet.graphics.beginFill(0xEEEEEE);
            sheet.graphics.lineStyle(1, 0x000000);
            sheet.graphics.drawRect(0, 0, 100, 200);
            sheet.graphics.endFill();
            
            var txt:TextField = new TextField();
            txt.height = 200;
            txt.width = 100;
            txt.wordWrap = true;
            txt.text = str;
            
            if(imgValue != null) {
                var img:Sprite = new Sprite();
                img.graphics.beginFill(0xFFFFFF);
                img.graphics.drawRect(imgValue.x, imgValue.y, imgValue.width, imgValue.height);
                img.graphics.endFill();
                sheet.addChild(img);
            }
            sheet.addChild(txt);
        }
        
        private function printOnePerPage():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.LANDSCAPE) {    
                    throw new Error("Without embedding fonts you must print one sheet per page with an orientation of portrait.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth;

                try {
                    pj.addPage(sheet1);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                try {
                    pj.addPage(sheet2);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }
        
        private function printTwoPerPage():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.PORTRAIT) {
                    throw new Error("Without embedding fonts you must print two sheets per page with an orientation of landscape.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth/2;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth/2;

                var sheets:Sprite = new Sprite();
                sheets.addChild(sheet1);
                sheets.addChild(sheet2);
                sheets.getChildAt(1).x = sheets.getChildAt(0).width;
                try {
                    pj.addPage(sheets);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }

        private function printTopHalf():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.PORTRAIT) {
                    throw new Error("Without embedding fonts you must print the top half with an orientation of landscape.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth/2;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth/2;

                var sheets:Sprite = new Sprite();
                sheets.addChild(sheet1);
                sheets.addChild(sheet2);
                sheets.getChildAt(1).x = sheets.getChildAt(0).width;
                try {
                    pj.addPage(sheets, new Rectangle(0, 0, sheets.width, sheets.height/2));
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }


        private function draw():void {
            var sheetWidth:Number = this.stage.stageWidth/2;
            var sheetHeight:Number = this.stage.stageHeight;
            
            addChild(sheet1);
            sheet1.width = sheetWidth;
            sheet1.height = sheetHeight;
            
            addChild(sheet2);
            sheet2.width = sheetWidth;
            sheet2.height = sheetHeight;
            sheet2.x = sheet1.width;
        }        
    }
}