網路作業與通訊的基本概念

您可以使用 NetworkInfo 物件，尋找應用程式可以使用的硬體與軟體網路介面。NetworkInfo 物件是一個 singleton 物件，您不需要建立。請您改用靜態類別屬性 networkInfo，來存取單一 NetworkInfo 物件。當可用的介面之一變更後，NetworkInfo 物件也會傳送 networkChange 事件。

呼叫 findInterfaces() 方法，取得 NetworkInterface 物件清單。清單中的每一個 NetworkInterface 物件會說明可用的介面之一。NetworkInterface 物件提供各種資訊，如 IP 位址、硬體位址、傳輸單位上限以及介面是否作用中。

以下的程式碼範例會追蹤用戶端電腦上每一個介面的 NetworkInterface 屬性：

package { 
import flash.display.Sprite; 
import flash.net.InterfaceAddress; 
import flash.net.NetworkInfo; 
import flash.net.NetworkInterface; 
 
public class NetworkInformationExample extends Sprite 
{ 
    public function NetworkInformationExample() 
    { 
        var networkInfo:NetworkInfo = NetworkInfo.networkInfo; 
        var interfaces:Vector.<NetworkInterface> = networkInfo.findInterfaces(); 
         
        if( interfaces != null ) 
        { 
            trace( "Interface count: " + interfaces.length ); 
            for each ( var interfaceObj:NetworkInterface in interfaces ) 
            { 
                trace( "\nname: "             + interfaceObj.name ); 
                trace( "display name: "     + interfaceObj.displayName ); 
                trace( "mtu: "                 + interfaceObj.mtu ); 
                trace( "active?: "             + interfaceObj.active ); 
                trace( "parent interface: " + interfaceObj.parent ); 
                trace( "hardware address: " + interfaceObj.hardwareAddress ); 
                if( interfaceObj.subInterfaces != null ) 
                { 
                    trace( "# subinterfaces: " + interfaceObj.subInterfaces.length ); 
                } 
                trace("# addresses: "     + interfaceObj.addresses.length ); 
                for each ( var address:InterfaceAddress in interfaceObj.addresses ) 
                { 
                    trace( "  type: "           + address.ipVersion ); 
                    trace( "  address: "         + address.address ); 
                    trace( "  broadcast: "         + address.broadcast ); 
                    trace( "  prefix length: "     + address.prefixLength ); 
                } 
            }             
        } 
    }     
} 
}

如需詳細資訊，請參閱：

• NetworkInfo

• NetworkInterface

• InterfaceAddress

AIR 應用程式可以在不穩定且多變的網路連線環境中執行。為了協助應用程式管理與線上資源之間的連線，Adobe AIR 會在每次網路連線的狀態變更為可用或不可用時，傳送網路變更事件。NetworkInfo 物件與應用程式的 NativeApplication 物件會傳送 networkChange 事件。若要回應這個事件，請加入偵聽程式：

NetworkInfo.networkInfo.addEventListener(Event.NETWORK_CHANGE, onNetworkChange); 

並且定義事件處理常式函數：

function onNetworkChange(event:Event) 
{ 
    //Check resource availability 
} 

networkChange 事件不會指出所有網路活動中的變更，只會指出已經變更的個別網路連線。AIR 不會嘗試解譯網路變更的意義。已經連接上網路的電腦可能具有許多實體與虛擬連線，因此失去某個連線不一定表示失去資源。另一方面，加入新的連線時，也不一定保證能改善資源的可用性。有時，新連線甚至可能會封鎖先前可用之資源的存取權 (例如，連接至 VPN 時)。

一般而言，應用程式若要判斷自己是否能連接遠端資源，唯一的方法就是嘗試連接該資源。服務監視架構提供以事件為基礎的方式，來回應特定主機的網路連線變更。

您可以使用 DNSResolver 類別來查詢 DNS 資源記錄。DNS 資源記錄提供網域名稱的 IP 位址以及 IP 位址的網域名稱之類的資訊。您可以查詢以下類型的 DNS 資源：

• ARecord—主機的 IPv4 位址。

• AAAARecord—主機的 IPv6 位址。

• MXRecord—主機的郵件交換記錄。

• PTRRecord—IP 位址的主機名稱。

• SRVRecord—服務的服務記錄。

若要查詢記錄，可以將查詢字串以及代表記錄類型的類別物件，傳送到 DNSResolver 物件的 lookup() 方法。要使用的查詢字串視記錄類型而定：

以下程式碼範例會查詢主機 "example.com" 的 IP 位址。

package 
{ 
    import flash.display.Sprite; 
    import flash.events.DNSResolverEvent; 
    import flash.events.ErrorEvent; 
    import flash.net.dns.ARecord; 
    import flash.net.dns.DNSResolver; 
 
    public class DNSResolverExample extends Sprite 
    { 
         
        public function DNSResolverExample() 
        { 
            var resolver:DNSResolver = new DNSResolver(); 
            resolver.addEventListener( DNSResolverEvent.LOOKUP, lookupComplete ); 
            resolver.addEventListener( ErrorEvent.ERROR, lookupError ); 
 
            resolver.lookup( "example.com.", ARecord ); 
        } 
         
        private function lookupComplete( event:DNSResolverEvent ):void 
        { 
            trace( "Query string: " + event.host ); 
            trace( "Record count: " + event.resourceRecords.length ); 
            for each( var record:* in event.resourceRecords ) 
            { 
                if( record is ARecord ) trace( record.address ); 
            } 
             
        } 
 
        private function lookupError( error:ErrorEvent ):void 
        { 
            trace("Error: " + error.text ); 
        } 
    } 
}

如需詳細資訊，請參閱：

• DNSResolver

• DNSResolverEvent

• ARecord

• AAAARecord

• MXRecord

• PTRRecord

• SRVRecord