瞭解保護的內容工作流程

下列步驟說明使用 DRMContentData 物件預先載入受保護媒體檔之憑證的工作流程。

1. 取得所封裝內容的二進位中繼資料。如果使用 Flash Access Java Reference Packager，則會以副檔名 .metadata 自動產生這個中繼資料檔案。例如，您可以使用 URLLoader 類別來下載此中繼資料。

2. 建立 DRMContentData 物件，將中繼資料傳遞給建構函式：

   var drmData:DRMContentData = new DRMContentData( metadata );

3. 其餘步驟則與瞭解保護的內容工作流程所述的工作流程相同。

下列步驟說明如何使用 preloadEmbeddedMetadata() 預先載入受 DRM 保護媒體檔之憑證的工作流程：

1. 下載並儲存媒體檔 (DRM 中繼資料只能從本機儲存的檔案中預先載入)。

2. 建立 NetConnection 和 NetStream 物件，並實作 NetStream 用戶端物件的 onDRMContentData() 和 onPlayStatus() 回呼函數。

3. 建立一個 NetStreamPlayOptions 物件，並將 stream 屬性設定為本機媒體檔的 URL。

4. 呼叫 NetStream 的 preloadEmbeddedMetadata()，傳遞 NetStreamPlayOptions 物件來找出要剖析的媒體檔。

5. 如果媒體檔含有 DRM 中繼資料，便會叫用 onDRMContentData() 回呼函數。中繼資料會做為 DRMContentData 物件傳遞至此函數。

6. 使用 DRMManager 的 loadVoucher() 方法，透過 DRMContentData 物件來取得憑證。

   如果 DRMContentData 物件的 authenticationMethod 屬性值是 userNameAndPassword，則請先在媒體權限伺服器上驗證使用者，再載入憑證。DRMContentData 物件的 serverURL 和 domain 屬性可以隨著使用者的憑證一同傳遞至 DRMManager 的 authenticate() 方法。

7. 檔案剖析完畢時便會叫用 onPlayStatus() 回呼函數。如果沒有呼叫 onDRMContentData() 函數，檔案不會包含取得憑證所需的中繼資料。缺少這個呼叫也可能表示 Flash Access 未保護此檔案。

AIR 的下列程式碼範例說明如何預先載入本機媒體檔的憑證：

package 
{ 
import flash.display.Sprite; 
import flash.events.DRMAuthenticationCompleteEvent; 
import flash.events.DRMAuthenticationErrorEvent; 
import flash.events.DRMErrorEvent;   
import flash.ev ents.DRMStatusEvent; 
import flash.events.NetStatusEvent; 
import flash.net.NetConnection; 
import flash.net.NetStream; 
import flash.net.NetStreamPlayOptions; 
import flash.net.drm.AuthenticationMethod; 
import flash.net.drm.DRMContentData; 
import flash.net.drm.DRMManager; 
import flash.net.drm.LoadVoucherSetting;   
public class DRMPreloader extends Sprite  
{ 
     private var videoURL:String = "app-storage:/video.flv"; 
    private var userName:String = "user"; 
    private var password:String = "password";  
    private var preloadConnection:NetConnection; 
    private var preloadStream:NetStream; 
    private var drmManager:DRMManager = DRMManager.getDRMManager(); 
    private var drmContentData:DRMContentData; 
    public function DRMPreloader():void { 
        drmManager.addEventListener( 
            DRMAuthenticationCompleteEvent.AUTHENTICATION_COMPLETE, 
            onAuthenticationComplete); 
        drmManager.addEventListener(DRMAuthenticationErrorEvent.AUTHENTICATION_ERROR, 
            onAuthenticationError);             
        drmManager.addEventListener(DRMStatusEvent.DRM_STATUS, onDRMStatus); 
        drmManager.addEventListener(DRMErrorEvent.DRM_ERROR, onDRMError); 
        preloadConnection = new NetConnection(); 
        preloadConnection.addEventListener(NetStatusEvent.NET_STATUS, onConnect); 
        preloadConnection.connect(null);            
    } 
 
    private function onConnect( event:NetStatusEvent ):void 
    { 
        preloadMetadata(); 
    } 
    private function preloadMetadata():void 
    { 
        preloadStream = new NetStream( preloadConnection ); 
        preloadStream.client = this; 
        var options:NetStreamPlayOptions = new NetStreamPlayOptions(); 
        options.streamName = videoURL; 
        preloadStream.preloadEmbeddedData( options );                         
    }     
    public function onDRMContentData( drmMetadata:DRMContentData ):void 
    { 
        drmContentData = drmMetadata; 
        if ( drmMetadata.authenticationMethod == AuthenticationMethod.USERNAME_AND_PASSWORD ) 
        { 
            authenticateUser(); 
        } 
        else 
            { 
                getVoucher(); 
            } 
    } 
    private function getVoucher():void 
    { 
        drmManager.loadVoucher( drmContentData, LoadVoucherSetting.ALLOW_SERVER ); 
    } 
 
    private function authenticateUser():void 
    { 
        drmManager.authenticate( drmContentData.serverURL, drmContentData.domain, userName, password ); 
    } 
    private function onAuthenticationError( event:DRMAuthenticationErrorEvent ):void 
    { 
        trace( "Authentication error: " + event.errorID + ", " + event.subErrorID ); 
    } 
 
    private function onAuthenticationComplete( event:DRMAuthenticationCompleteEvent ):void 
    { 
        trace( "Authenticated to: " + event.serverURL + ", domain: " + event.domain ); 
        getVoucher(); 
    } 
    private function onDRMStatus( event:DRMStatusEvent ):void 
    { 
        trace( "DRM Status: " + event.detail); 
        trace("--Voucher allows offline playback = " + event.isAvailableOffline ); 
        trace("--Voucher already cached          = " + event.isLocal ); 
        trace("--Voucher required authentication = " + !event.isAnonymous ); 
    } 
    private function onDRMError( event:DRMErrorEvent ):void 
    { 
        trace( "DRM error event: " + event.errorID + ", " + event.subErrorID + ", " + event.text ); 
    } 
    public function onPlayStatus( info:Object ):void 
    { 
        preloadStream.close(); 
    } 
} 
}