使用 DataGrid 組件

將本機資料提供者與 DataGrid 組件搭配使用：

此範例會建立 DataGrid，顯示壘球隊的名冊。名冊定義於 Array ( aRoster ) 中，然後指定給 DataGrid 的 dataProvider 屬性。

1. 在 Flash 中，選取「檔案 > 新增」，然後選取「Flash 檔案 (ActionScript 3.0)」。

2. 將 DataGrid 組件從「組件」面板拖曳到「舞台」。

3. 在「屬性」檢測器中，輸入實體名稱 aDg 。

4. 開啟「動作」面板，選取主要「時間軸」中的「影格 1」，然後輸入下列 ActionScript 程式碼：

   import fl.data.DataProvider; 
    
   bldRosterGrid(aDg); 
   var aRoster:Array = new Array(); 
   aRoster = [ 
           {Name:"Wilma Carter", Bats:"R", Throws:"R", Year:"So", Home: "Redlands, CA"},  
           {Name:"Sue Pennypacker", Bats:"L", Throws:"R", Year:"Fr", Home: "Athens, GA"}, 
           {Name:"Jill Smithfield", Bats:"R", Throws:"L", Year:"Sr", Home: "Spokane, WA"}, 
           {Name:"Shirley Goth", Bats:"R", Throws:"R", Year:"Sr", Home: "Carson, NV"}, 
           {Name:"Jennifer Dunbar", Bats:"R", Throws:"R", Year:"Fr", Home: "Seaside, CA"}, 
           {Name:"Patty Crawford", Bats:"L", Throws:"L", Year:"Jr", Home: "Whittier, CA"}, 
           {Name:"Angelina Davis", Bats:"R", Throws:"R", Year:"So", Home: "Odessa, TX"}, 
           {Name:"Maria Santiago", Bats:"L", Throws:"L", Year:"Sr", Home: "Tacoma, WA"}, 
           {Name:"Debbie Ferguson", Bats:"R", Throws:"R", Year: "Jr", Home: "Bend, OR"}, 
           {Name:"Karen Bronson", Bats:"R", Throws:"R", Year: "Sr", Home: "Billings, MO"}, 
           {Name:"Sylvia Munson", Bats:"R", Throws:"R", Year: "Jr", Home: "Pasadena, CA"}, 
           {Name:"Carla Gomez", Bats:"R", Throws:"L", Year: "Sr", Home: "Corona, CA"}, 
           {Name:"Betty Kay", Bats:"R", Throws:"R", Year: "Fr", Home: "Palo Alto, CA"}, 
   ]; 
   aDg.dataProvider = new DataProvider(aRoster); 
   aDg.rowCount = aDg.length; 
    
   function bldRosterGrid(dg:DataGrid){ 
       dg.setSize(400, 300); 
       dg.columns = ["Name", "Bats", "Throws", "Year", "Home"]; 
       dg.columns[0].width = 120; 
       dg.columns[1].width = 50; 
       dg.columns[2].width = 50; 
       dg.columns[3].width = 40; 
       dg.columns[4].width = 120; 
       dg.move(50,50); 
   };

   bldRosterGrid() 函數會設定 DataGrid 的大小，並設定欄的順序及大小。

5. 選取「控制 > 測試影片」。

為應用程式中的 DataGrid 組件指定欄並加入排序功能

請注意，您可以按一下任何一個欄標題，根據該欄的值，以遞減的順序來排序 DataGrid 的內容。

下列範例使用 addColumn() 方法，將 DataGridColumn 實體加入至 DataGrid。這些欄代表選手名稱與其得分。此範例也會設定 sortOptions 屬性，以指定各欄的排序選項：Name 欄為 Array.CASEINSENSITIVE ，而 Score 欄則為 Array.NUMERIC 。DataGrid 的長度將設定為列數，且寬度設定為 200，以適當地調整大小。

1. 在 Flash 中，選取「檔案 > 新增」，然後選取「Flash 檔案 (ActionScript 3.0)」。

2. 將 DataGrid 組件從「組件」面板拖曳到「舞台」。

3. 在「屬性」檢測器中，輸入實體名稱 aDg 。

4. 開啟「動作」面板，選取主要「時間軸」中的「影格 1」，然後輸入下列 ActionScript 程式碼：

   import fl.controls.dataGridClasses.DataGridColumn; 
   import fl.events.DataGridEvent; 
   import fl.data.DataProvider; 
   // Create columns to enable sorting of data. 
   var nameDGC:DataGridColumn = new DataGridColumn("name"); 
   nameDGC.sortOptions = Array.CASEINSENSITIVE; 
   var scoreDGC:DataGridColumn = new DataGridColumn("score"); 
   scoreDGC.sortOptions = Array.NUMERIC; 
   aDg.addColumn(nameDGC); 
   aDg.addColumn(scoreDGC); 
   var aDP_array:Array = new Array({name:"clark", score:3135}, {name:"Bruce", score:403}, {name:"Peter", score:25}) 
   aDg.dataProvider = new DataProvider(aDP_array); 
   aDg.rowCount = aDg.length; 
   aDg.width = 200;

5. 選取「控制 > 測試影片」。

使用 ActionScript 建立 DataGrid 組件實體

此範例使用 ActionScript 建立 DataGrid，並在其中填入由選手名稱及得分構成的 Array。

1. 建立新的 Flash (ActionScript 3.0) 文件。

2. 將 DataGrid 組件從「組件」面板拖曳到目前文件的「元件庫」面板。

   此舉會將組件加入元件庫中，但不會使其在應用程式中顯示。

3. 開啟「動作」面板，選取主要「時間軸」中的「影格 1」，然後輸入下列 ActionScript 程式碼：

   import fl.controls.DataGrid; 
   import fl.data.DataProvider; 
    
   var aDg:DataGrid = new DataGrid(); 
   addChild(aDg); 
   aDg.columns = [ "Name", "Score" ]; 
   aDg.setSize(140, 100); 
   aDg.move(10, 40);

   此程式碼會建立 DataGrid 實體，然後調整格線大小及位置。

4. 建立陣列、將資料加入陣列中，並且指定陣列為 DataGrid 的資料提供者：

   var aDP_array:Array = new Array(); 
   aDP_array.push({Name:"Clark", Score:3135}); 
   aDP_array.push({Name:"Bruce", Score:403}); 
   aDP_array.push({Name:"Peter", Score:25}); 
   aDg.dataProvider = new DataProvider(aDP_array); 
   aDg.rowCount = aDg.length;

5. 選取「控制 > 測試影片」。

將 XML 檔載入 DataGrid

下列範例使用 DataGridColumn 類別，建立 DataGrid 的欄。它會傳遞 XML 物件做為 DataProvider() 建構函式的 value 參數，藉以填入 DataGrid。

1. 使用文字編輯器以下列資料建立 XML 檔案，並儲存為 team.xml (儲存的位置為儲存 FLA 檔案相同的資料夾)。

   <team> 
       <player name="Player A" avg="0.293" /> 
       <player name="Player B" avg="0.214" /> 
       <player name="Player C" avg="0.317" /> 
   </team>

2. 建立新的 Flash (ActionScript 3.0) 文件。

3. 在「組件」面板中，按兩下 DataGrid，將組件加入至「舞台」。

4. 在「屬性」檢測器中，輸入實體名稱 aDg 。

5. 開啟「動作」面板，選取主要「時間軸」中的「影格 1」，然後輸入下列 ActionScript 程式碼：

   import fl.controls.dataGridClasses.DataGridColumn; 
   import fl.data.DataProvider; 
   import flash.net.*; 
   import flash.events.*; 
    
   var request:URLRequest = new URLRequest("team.xml"); 
   var loader:URLLoader = new URLLoader; 
    
    
   loader.load(request); 
   loader.addEventListener(Event.COMPLETE, loaderCompleteHandler); 
    
   function loaderCompleteHandler(event:Event):void { 
    
       var teamXML:XML = new XML(loader.data); 
    
       var nameCol:DataGridColumn = new DataGridColumn("name"); 
       nameCol.headerText = "Name"; 
       nameCol.width = 120; 
       var avgCol:DataGridColumn = new DataGridColumn("avg"); 
       avgCol.headerText = "Average"; 
       avgCol.width = 60; 
        
       var myDP:DataProvider = new DataProvider(teamXML); 
        
       aDg.columns = [nameCol, avgCol]; 
       aDg.width = 200; 
       aDg.dataProvider = myDP; 
       aDg.rowCount = aDg.length; 
   }

6. 選取「控制 > 測試影片」。