WorkerDomain  - AS3

程式碼目前執行所在的 WorkerDomain 實體。這是應用程式中的唯一 WorkerDomain。

指出目前的執行階段內容是否支援 WorkerDomain 和 Worker 物件以便同時執行程式碼。

如果可以使用並行，則這個屬性的值為 true。

從 SWF 的位元組建立新的 Worker 實體。

每個 Worker 的建立和執行方式都是透過隔離的 SWF 應用程式。若要建立 Worker 實體，請取得 SWF 檔案的位元組做為 ByteArray 實體並傳遞至這個方法。有三個常用方法可存取 SWF 的位元組用於此用途：

• 使用 [Embed] 中繼標籤，可將 .swf 檔案當做 ByteArray 內嵌於應用程式中：

      // Embed the SWF file
      [Embed(source="../swfs/BgWorker.swf", mimeType="application/octet-stream")]
      private static var BgWorker_ByteClass:Class;
      
      private function createWorker():void
      {
        // create the background worker
        var workerBytes:ByteArray = new BgWorker_ByteClass();
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• 使用 URLLoader 載入外部 SWF 檔案：

      // load the SWF file
      var workerLoader:URLLoader = new URLLoader();
      workerLoader.dataFormat = URLLoaderDataFormat.BINARY;
      workerLoader.addEventListener(Event.COMPLETE, loadComplete);
      workerLoader.load(new URLRequest("BgWorker.swf"));
      
      private function loadComplete(event:Event):void
      {
        // create the background worker
        var workerBytes:ByteArray = event.target.data as ByteArray;
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• 將單一 SWF 當做原始 Worker 和背景 Worker 之用：

      // The primordial worker's main class constructor
      public function PrimordialWorkerClass()
      {
        init();
      }
      
      private function init():void
      {
        var swfBytes:ByteArray = this.loaderInfo.bytes;
        
        // Check to see if this is the primordial worker
        if (Worker.current.isPrimordial)    
        {
          // create a background worker
          var bgWorker:Worker = WorkerDomain.current.createWorker(swfBytes);
          
          // listen for worker state changes to know when the worker is running
          bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
          
          // set up communication between workers using 
          // setSharedProperty(), createMessageChannel(), etc.
          // ... (not shown)
          
          bgWorker.start();
        }
        else // entry point for the background worker
        {
          // set up communication between workers using getSharedProperty()
          // ... (not shown)
          
          // start the background work
        }

使用 createWorker() 建立 Worker 物件並不會開始執行 Worker。若要開始執行 Worker 的程式碼，請呼叫 Worker 物件的 start() 方法。

Worker 很實用，因為它降低了影格速率因主要顯示執行緒遭到其他程式碼封鎖而丟棄的可能性。不過，Worker 需要額外的系統記憶體和 CPU 使用量，這會讓整體應用程式效能付出不少代價。由於每個 Worker 都會使用專屬的執行階段虛擬機器實體，因此，即使是簡單的 Worker，工作負荷也會很大。在使用 Worker 時，請在所有目標平台間測試您的程式碼，以確保系統上的需求不會太大。Adobe 建議在一般情況下，不要使用超過一個或兩個背景 Worker。

參數

提供存取 WorkerDomain 中目前正在執行的 Worker 集 (Worker 實體的 state 屬性為 WorkerState.RUNNING)。