BlurFilter  - AS3

水平模糊化量。 有效值為 0 到 255 (浮點)。 預設值為 4。 2 的冪次方數值 (如 2、4、8、16 和 32) 是經過最佳化的，以便在顯示時會比其他值更為快速。

垂直模糊化量。 有效值為 0 到 255 (浮點)。 預設值為 4。 2 的冪次方數值 (如 2、4、8、16 和 32) 是經過最佳化的，以便在顯示時會比其他值更為快速。

執行模糊化的次數。 預設值為 BitmapFilterQuality.LOW (相當於套用一次濾鏡)。 BitmapFilterQuality.MEDIUM 值表示套用濾鏡兩次，而 BitmapFilterQuality.HIGH 值表示套用濾鏡三次，呈現的效果接近「高斯」模糊。 設定值較低的濾鏡，其顯示速度較快。

對大部份應用程式而言，將 quality 值設為低、中或高就足夠了。 雖然您可以使用其他數值 (最高可至 15) 來增加套用模糊化效果的次數，但越高的值就代表顯示速度越緩慢。 只要增加 blurX 和 blurY 屬性的值，通常就可以得到類似的效果和較快的顯示速度，而不需要增加 quality 的值。

您可以使用下列 BitmapFilterQuality 常數來指定 quality 屬性值：

• BitmapFilterQuality.LOW
• BitmapFilterQuality.MEDIUM
• BitmapFilterQuality.HIGH

以指定的參數初始化濾鏡。 預設值會建立一個柔和、失焦的影像。

傳回此濾鏡物件的副本。

1. 匯入所需的類別。
2. 宣告三個用於 draw() 函數內的屬性，將物件繪製到套用的斜角濾鏡。
3. 建立 BlurFilterExample() 建構函數，以進行下列動作：
   • 呼叫 draw() 函數 (此函數會在稍後宣告)。
   • 將 filter 變數宣告為 BitmapFilter 物件，並將其指定給呼叫 getBitmapFilter() 的傳回值。
   • 建立新的 Array 物件 myFilters 並將 filter 加入陣列，然後指定 myFilters 給 BlurFilterExample 物件的 filters 屬性。 這樣就會套用 myFilters 中找到的所有濾鏡，而在本範例中只有 filter。
4. 建立 getBitmapFilter() 函數，以建立並設定濾鏡的屬性。
5. 建立 draw() 函數。 此函數會使用 Graphics 類別的方法 (透過 Sprite 類別的 graphics 屬性存取) 來繪製方形。

package {
    import flash.display.Sprite;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BlurFilter;

    public class BlurFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function BlurFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var blurX:Number = 30;
            var blurY:Number = 30;
            return new BlurFilter(blurX, blurY, BitmapFilterQuality.HIGH);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}