StorageVolume

套件	flash.filesystem
類別	public class StorageVolume
繼承	StorageVolume Object

語言版本:

ActionScript 3.0

執行階段版本:

AIR 2

StorageVolume 物件包含定義大量儲存空間的屬性。這個類別有兩個使用方法：

StorageVolumeChangeEvent 物件的 storageVolume 屬性是 StorageVolume 物件。這個物件代表已經掛接或解除掛接的儲存空間。
StorageVolumeInfo.storageVolumeInfo.getStorageVolumes() 方法會傳回 StorageVolume 物件的向量。每個 StorageVolume 物件代表一個掛接的儲存空間。

檢視範例

公用屬性

隱藏繼承公用屬性

顯示繼承公用屬性

	屬性		定義自
		constructor : Object 類別物件的參照或是特定物件實體的建構函數。	Object
		drive : String [唯讀] Windows 上的磁碟機代號。	StorageVolume
		fileSystemType : String [唯讀] 在儲存空間上的檔案系統類型 (例如 "FAT"、"NTFS"、"HFS" 或 "UFS")。	StorageVolume
		isRemovable : Boolean [唯讀] 作業系統認定儲存空間為可移除 (true) 或不可移除 (false)。	StorageVolume
		isWritable : Boolean [唯讀] 空間是可寫入 (true) 或不是 (false)。	StorageVolume
		name : String [唯讀] 磁碟的名稱。	StorageVolume
		rootDirectory : File [唯讀] 對應至磁碟根目錄的 File 物件。	StorageVolume

公用方法

隱藏繼承公用方法

顯示繼承公用方法

	方法		定義自
		StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String) 建構函數。	StorageVolume
		hasOwnProperty(name:String):Boolean 指出物件是否有已定義的指定屬性。	Object
		isPrototypeOf(theClass:Object):Boolean 指出 Object 類別的實體是否位於指定為參數的物件原型鏈中。	Object
		propertyIsEnumerable(name:String):Boolean 指出指定的屬性是否存在，以及是否可列舉。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 為迴圈作業設定動態屬性的可用性。	Object
		toLocaleString():String 傳回代表此物件的字串，根據地區特定慣例進行格式化。	Object
		toString():String 會傳回指定之物件的字串形式。	Object
		valueOf():Object 會傳回指定之物件的基本值。	Object

屬性詳細資訊

drive

屬性

drive:String [唯讀]

語言版本:

ActionScript 3.0

執行階段版本:

AIR 2

Windows 上的磁碟機代號。在其他平台上，這個屬性設定為 null。

實作
public function get drive():String

fileSystemType

屬性

fileSystemType:String [唯讀]

語言版本:

ActionScript 3.0

執行階段版本:

AIR 2

在儲存空間上的檔案系統類型 (例如 "FAT"、"NTFS"、"HFS" 或 "UFS")。

實作
public function get fileSystemType():String

範例 ( 如何使用本範例 )

下列程式碼可列出每個掛接儲存空間的根目錄原生路徑及檔案系統類型：

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath, "(" + volumes[i].fileSystemType + ")");
}

isRemovable

屬性

isRemovable:Boolean [唯讀]

語言版本:

ActionScript 3.0

執行階段版本:

AIR 2

作業系統認定儲存空間為可移除 (true) 或不可移除 (false)。

下表列出各種裝置類型的 StorageVolume.isRemovable 值：

裝置的類型	Mac OS	Windows	Linux
CD/DVD (固定式)	true	true	true
USB 快閃磁碟機	true	true	true
USB 硬碟機	false	false	true
FireWire 硬碟機	false	false	true
共用磁碟區	true	false	- ¹
網路磁碟機	false	false	false
儲存體讀卡機 (空)	- ²	false	- ²
儲存體讀卡機 (內有 SD/CF 卡)	true	true	true

¹ Linux 沒有共用磁碟區的概念。

² 在 Windows 上，空白讀卡機會列示為不可卸除的裝置。在 Mac OS 和 Linux 上，空白讀卡機不會列示為儲存體磁碟區。

實作
public function get isRemovable():Boolean

範例 ( 如何使用本範例 )

下列程式碼會輸出非卸除式儲存空間的清單，後面接著卸除式儲存空間的清單：

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();

trace("Non-removeable volumes:");
for (var i:int = 0; i < volumes.length; i++)
{
    if (!volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

trace("\nRemoveable volumes:");
for (i = 0; i < volumes.length; i++)
{
    if (volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

isWritable

屬性

isWritable:Boolean [唯讀]

語言版本:

ActionScript 3.0

執行階段版本:

AIR 2

空間是可寫入 (true) 或不是 (false)。

注意：您可以呼叫 StorageVolume 物件的 rootDirectory.spaceAvailble 屬性，判斷磁碟上的可用空間大小。

實作
public function get isWritable():Boolean

相關 API 元素

flash.fileSystem.File.spaceAvailable

範例 ( 如何使用本範例 )

下列程式碼會輸出可寫入儲存空間及每個儲存空間之可用空間的清單：

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();

for (var i:int = 0; i < volumes.length; i++)
{
    if(volumes[i].isWritable)
    {         
        trace(volumes[i].rootDirectory.nativePath, volumes[i].rootDirectory.spaceAvailable);
    }
}

name

屬性

name:String [唯讀]

語言版本:

ActionScript 3.0

執行階段版本:

AIR 2

磁碟的名稱。如果沒有名稱，這個屬性設定為 null。

實作
public function get name():String

範例 ( 如何使用本範例 )

下列程式碼可列出每個掛接儲存空間的根目錄原生路徑及檔案系統名稱 (如果有的話)：

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    var name:String = new String();
    if (volumes[i].name)
    {
        name = "(" + volumes[i].name + ")";
    }
    trace(volumes[i].rootDirectory.nativePath, name);
}

rootDirectory

屬性

rootDirectory:File [唯讀]

語言版本:

ActionScript 3.0

執行階段版本:

AIR 2

對應至磁碟根目錄的 File 物件。

實作
public function get rootDirectory():File

範例 ( 如何使用本範例 )

下列程式碼可列出每個掛接儲存空間根目錄的原生路徑：

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath);
}

建構函式詳細資料

()

建構函式

public function StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String)

語言版本:

ActionScript 3.0

執行階段版本:

AIR 2

建構函數。一般而言，您不會直接呼叫這個建構函數 (以建立新的 StorageVolume 物件)。相反地，您會存取 StorageVolumeChangeEvent 物件的 storageVolume 屬性或是呼叫 StorageVolumeInfo.storageVolumeInfo.getStorageVolumes() 來參考 StorageVolume 物件。

參數

	`rootDirPath:File`

	`name:String`

	`writable:Boolean`

	`removable:Boolean`

	`fileSysType:String`

	`drive:String`

範例如何使用本範例

StorageVolumeExample.as

下列程式碼會列出每個掛接儲存空間的屬性：

package
{
    import flash.display.Sprite;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeExample extends Sprite
    {
        public function StorageVolumeExample()
        {
            var volumes:Vector.<StorageVolume> = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
            for (var i:int = 0; i < volumes.length; i++)
            {
                var volume:StorageVolume = volumes[i];
                trace("nativePath:", volume.rootDirectory.nativePath);
                trace("fileSystemType:", volume.fileSystemType);
                trace("isRemovable:", volume.isRemovable);
                trace("isWritable:", volume.isWritable);
                trace("drive:", volume.drive);
                trace("name:", volume.name);
                trace("________________________________________________________");
            }
        }
    }
}

StorageVolumeChangeEventExample.as

下列程式碼會列出每個已經掛接或解除掛接的儲存空間屬性。注意，StorageVolumeChangeEvent 的 storageVolume 屬性只針對 storageVolumeMount 事件設定；針對 storageVolumeUnmount 事件是 null：

package
{
    import flash.display.Sprite;
    import flash.events.StorageVolumeChangeEvent;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeChangeEventExample extends Sprite
    {
        public function StorageVolumeChangeEventExample()
        {
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_MOUNT, mountEventHandler);
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_UNMOUNT, unmountEventHandler);
        }
        public function mountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            var volume:StorageVolume = event.storageVolume;
            trace("VOLUME MOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace("fileSystemType:", volume.fileSystemType);
            trace("isRemovable:", volume.isRemovable);
            trace("isWritable:", volume.isWritable);
            trace("drive:", volume.drive);
            trace("name:", volume.name);
            trace();
        }
        public function unmountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            trace("VOLUME UNMOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace();
        }        
    }
}

法律聲明 | 線上隱私權政策

StorageVolume - AS3

類別 x

drive

fileSystemType

isRemovable

isWritable

name

rootDirectory

StorageVolume