在 ActionScript 3.0 中处理计时函数的首选方式是使用 Timer 类 (flash.utils.Timer)，可以使用它在每次达到间隔时调度事件。
要启动计时器，请先创建 Timer 类的实例，并告诉它每隔多长时间生成一次计时器事件以及在停止前生成多少次事件。
例如，下列代码创建一个每秒调度一个事件且持续 60 秒的 Timer 实例：
var oneMinuteTimer:Timer = new Timer(1000, 60);
Timer 对象在每次达到指定的间隔时都会调度 TimerEvent 对象。TimerEvent 对象的事件类型是
timer
（由常量
TimerEvent.TIMER
定义）。TimerEvent 对象包含的属性与标准 Event 对象包含的属性相同。
如果将 Timer 实例设置为固定的间隔数，则在达到最后一次间隔时，它还会调度
timerComplete
事件（由常量
TimerEvent.TIMER_COMPLETE
定义）。
以下是一个用来展示 Timer 类实际操作的小示例应用程序：
package
{
import flash.display.Sprite;
import flash.events.TimerEvent;
import flash.utils.Timer;
public class ShortTimer extends Sprite
{
public function ShortTimer()
{
// creates a new five-second Timer
var minuteTimer:Timer = new Timer(1000, 5);
// designates listeners for the interval and completion events
minuteTimer.addEventListener(TimerEvent.TIMER, onTick);
minuteTimer.addEventListener(TimerEvent.TIMER_COMPLETE, onTimerComplete);
// starts the timer ticking
minuteTimer.start();
}
public function onTick(event:TimerEvent):void
{
// displays the tick count so far
// The target of this event is the Timer instance itself.
trace("tick " + event.target.currentCount);
}
public function onTimerComplete(event:TimerEvent):void
{
trace("Time's Up!");
}
}
}
创建 ShortTimer 类时，它会创建一个用于每秒计时一次并持续五秒的 Timer 实例。然后，它将两个侦听器添加到计时器：一个用于侦听每次计时，另一个用于侦听
timerComplete
事件。
接着，它启动计数器计时，并且从此时起以一秒钟的间隔执行
onTick()
方法。
onTick()
方法只显示当前的时间计数。五秒钟后，执行
onTimerComplete()
方法，告诉您时间已到。
运行该示例时，您应会看到下列行以每秒一行的速度显示在控制台或跟踪窗口中：
tick 1
tick 2
tick 3
tick 4
tick 5
Time's Up!
