关联数组

在 ActionScript 3.0 中有两种创建关联数组的方式。第一种方式是使用 Object 实例。使用 Object 实例，您可以通过对象文本来初始化数组。Object 类的实例（也称为“通用对象”）在功能上等同于关联数组。通用对象的每个属性名称都用作键，提供对存储的值的访问。

下面的示例创建一个名为 monitorInfo 的关联数组，并使用对象文本初始化具有两个键和值对的数组：

var monitorInfo:Object = {type:"Flat Panel", resolution:"1600 x 1200"}; 
trace(monitorInfo["type"], monitorInfo["resolution"]);  
// output: Flat Panel 1600 x 1200

如果在声明数组时不需要初始化，可以使用 Object 构造函数创建数组，如下所示：

var monitorInfo:Object = new Object();

使用对象文本或 Object 类构造函数创建数组后，可以使用数组访问 ( [] ) 运算符或点运算符 ( . )。以下示例将两个新值添加到 monitorArray 中：

monitorInfo["aspect ratio"] = "16:10"; // bad form, do not use spaces 
monitorInfo.colors = "16.7 million"; 
trace(monitorInfo["aspect ratio"], monitorInfo.colors); 
// output: 16:10 16.7 million

请注意，名为 aspect ratio 的键包含空格字符。可以使用数组访问 ( [] ) 运算符，但是如果尝试使用点运算符，则会生成错误。不建议在键名称中使用空格。

创建关联数组的第二种方式是使用 Array 构造函数（或任何动态类的构造函数），然后使用数组访问 ( [] ) 运算符或点运算符 ( . ) 将键和值对添加到数组中。如果将关联数组声明为数组类型，则将无法使用对象文本初始化该数组。以下示例使用 Array 构造函数创建一个名为 monitorInfo 的关联数组，并添加一个名为 type 的键和一个名为 resolution 的键以及它们的值：

var monitorInfo:Array = new Array(); 
monitorInfo["type"] = "Flat Panel"; 
monitorInfo["resolution"] = "1600 x 1200"; 
trace(monitorInfo["type"], monitorInfo["resolution"]);  
// output: Flat Panel 1600 x 1200

使用 Array 构造函数创建关联数组没有什么优势。即使使用 Array 构造函数或 Array 数据类型，也不能将 Array 类的 Array.length 属性或任何方法用于关联数组。最好将 Array 构造函数用于创建索引数组。

可以使用 Dictionary 类创建使用对象而非字符串作为键的关联数组。这样的数组有时候也称作字典、哈希或映射。例如，考虑这样一个应用程序，它可根据 Sprite 对象与特定容器的关联确定 Sprite 对象的位置。可以使用 Dictionary 对象，将每个 Sprite 对象映射到一个容器。

以下代码创建三个用作 Dictionary 对象的键的 Sprite 对象实例。它为每个键分配了值 GroupA 或 GroupB 。值可以是任意数据类型，但在此示例中， GroupA 和 GroupB 均为 Object 类的实例。然后，可以使用数组访问 ( [] ) 运算符访问与每个键关联的值，如下面的代码所示：

import flash.display.Sprite; 
import flash.utils.Dictionary; 
 
var groupMap:Dictionary = new Dictionary(); 
 
// objects to use as keys 
var spr1:Sprite = new Sprite(); 
var spr2:Sprite = new Sprite(); 
var spr3:Sprite = new Sprite(); 
 
// objects to use as values 
var groupA:Object = new Object(); 
var groupB:Object = new Object(); 
 
// Create new key-value pairs in dictionary. 
groupMap[spr1] = groupA; 
groupMap[spr2] = groupB; 
groupMap[spr3] = groupB; 
 
if (groupMap[spr1] == groupA) 
{ 
    trace("spr1 is in groupA");  
} 
if (groupMap[spr2] == groupB) 
{ 
    trace("spr2 is in groupB");  
} 
if (groupMap[spr3] == groupB) 
{ 
    trace("spr3 is in groupB");  
}

for (var key:Object in groupMap) 
{ 
    trace(key, groupMap[key]); 
} 
/* output: 
[object Sprite] [object Object] 
[object Sprite] [object Object] 
[object Sprite] [object Object] 
*/

for each (var item:Object in groupMap) 
{ 
    trace(item); 
} 
/* output: 
[object Object] 
[object Object] 
[object Object] 
*/

var myObject:Object = new Object();

import flash.utils.Dictionary; 
 
var myObject:Object = new Object(); 
var myMap:Dictionary = new Dictionary(); 
myMap[myObject] = "foo";

myObject = null; 
delete myMap[myObject];

import flash.utils.Dictionary; 
 
var myObject:Object = new Object(); 
var myMap:Dictionary = new Dictionary(true); 
myMap[myObject] = "foo"; 
myObject = null; // Make object eligible for garbage collection.